中国DOS联盟

我已经通过IF知道 boot.ini文件到底是在哪个盘（因为系统不一定在C盘），但怎样使用bootcfg \timeout 修改它的启动时间？ boot.ini的路径怎样添加？ 谢谢.....

改启动等待时间直接命令bootcfg /timeout 10 不需要boot.ini路径

给boot.ini的路径添加变量
FOR %%B IN (C D E F G H I J K L M N O P Q R S T U V W) DO (
VOL %%B: >NUL 2>NUL
IF NOT ERRORLEVEL 1 IF EXIST %%B:\boot.ini SET BOOTDIR=%%B
)
echo %BOOTDIR%:\BOOT.ini

这命令我明白，但我把boot.ini剪切到D盘后，直接用bootcfg /timeout 10后，boot里面的启动时间没有改变.....

bootcfg /timeout 10肯定指向当前boot.ini的，剪切到D盘后用替换字符串的方法修改
参考：
http://www.cn-dos.net/forum/viewthread.php?tid=23121&fpage=1&highlight=%E4%BF%AE%E6%94%B9boot.ini

偷个懒的方法，复制一份原BOOT。INI，用 BOOTCFG 修改一下，拿走用，再恢复原来的BOOT。INI。

哈哈...偷梁换柱

老兄，我把命令贴出来，你帮我改下.....恩，要求就是无论boot.ini在哪个盘，都能修改启动时间

@echo off
SET BOOTDIR=BOOTDIR
CLS
FOR %%B IN (C D E F G H I J K L M N O P Q R S T U V W) DO (
VOL %%B: >NUL 2>NUL
IF NOT ERRORLEVEL 1 IF EXIST %%B:\boot.ini SET BOOTDIR=%%B
)
IF "%BOOTDIR%"=="BOOTDIR" GOTO 退出
echo %BOOTDIR%:\boot.ini
@ECHO OFF
ATTRIB -S -H -R %BOOTDIR%:\BOOT.INI
IF EXIST %BOOTDIR%:\BOOT.BAK (
ATTRIB -S -H -R %BOOTDIR%:\BOOT.BAK
DEL %BOOTDIR%:\BOOT.BAK /Q
)
COPY %BOOTDIR%:\BOOT.INI %BOOTDIR%:\BOOT.BAK>NUL
TYPE %BOOTDIR%:\BOOT.BAK|FIND /I /V "grldr">%BOOTDIR%:\BOOT.INI
ECHO %BOOTDIR%:\grldr="什么什么">>%BOOTDIR%:\BOOT.INI
ATTRIB +R +S +H %BOOTDIR%:\BOOT.INI
ATTRIB +R +S +H %BOOTDIR%:\BOOT.BAK

添加在哪里 ？怎样添加啊 ？

谢谢了

晕这段代码就是我WinPE+卡巴里的代码，我就喜欢用（GOTO 退出）的表达方式
也不是秘密全部贴出来给你看吧

@echo off
COLOR 0b
ECHO.
ECHO.
ECHO 按任意键开始安装......
PAUSE >NUL
SET 系统要求=此程序必须在Windows NT或2000以上操作系统上运行
FOR %%A IN (2000 XP 2003) DO VER|FIND /I "%%A">NUL && SET 系统要求=Windows 2000以上操作系统验证已通过>NUL
IF NOT "%系统要求%"=="Windows 2000以上操作系统验证已通过" GOTO 退出
SET BOOTDIR=BOOTDIR
FOR %%A IN (C D E F G H I J K L M N O P Q R S T U V W) DO (
VOL %%A: >NUL 2>NUL
IF NOT ERRORLEVEL 1 IF EXIST %%A:\BOOT.INI SET BOOTDIR=%%A
)
IF "%BOOTDIR%"=="BOOTDIR" GOTO 退出
FIND /I "AVLDR.XPE" %BOOTDIR%:\BOOT.INI >NUL
IF NOT ERRORLEVEL 1 GOTO 判断

:安装
cls
COLOR 0a
IF EXIST %BOOTDIR%:\AVLDR.XPE ATTRIB -S -H -R %BOOTDIR%:\AVLDR.XPE
IF EXIST %BOOTDIR%:\XPELDR ATTRIB -S -H -R %BOOTDIR%:\XPELDR
IF EXIST %BOOTDIR%:\WINNT.XPE ATTRIB -S -H -R %BOOTDIR%:\WINNT.XPE
IF EXIST %BOOTDIR%:\MSPE\* ATTRIB -S -H -R %BOOTDIR%:\MSPE
ECHO.
ECHO.
ECHO 正在复制文件，请稍候......
COPY /Y AVLDR.XPE %BOOTDIR%:\>NUL
COPY /Y ..\MSPE\SETUPLDR.BIN %BOOTDIR%:\XPELDR>NUL
COPY /Y ..\MSPE\WINNT.XPE %BOOTDIR%:\>NUL
XCOPY /E /Y /R ..\MSPE %BOOTDIR%:\MSPE\>NUL
IF EXIST %BOOTDIR%:\XPEMENU.INI ATTRIB -S -H -R %BOOTDIR%:\XPEMENU.INI
TYPE ..\XPEMENU.INI|FIND /I /V "安装WinPE硬盘启动.EXE">%BOOTDIR%:\XPEMENU.INI
ATTRIB -S -H -R %BOOTDIR%:\BOOT.INI
IF EXIST %BOOTDIR%:\BOOT.BAK (
ATTRIB -S -H -R %BOOTDIR%:\BOOT.BAK
DEL %BOOTDIR%:\BOOT.BAK /Q
)
COPY %BOOTDIR%:\BOOT.INI %BOOTDIR%:\BOOT.BAK>NUL
TYPE %BOOTDIR%:\BOOT.BAK|FIND /I /V "AVLDR.XPE">%BOOTDIR%:\BOOT.INI
ECHO C:\AVLDR.XPE="微型 Windows PE 嵌入式系统">>%BOOTDIR%:\BOOT.INI
ATTRIB +S +H %BOOTDIR%:\AVLDR.XPE
ATTRIB +S +H %BOOTDIR%:\XPELDR
ATTRIB +S +H %BOOTDIR%:\WINNT.XPE
IF NOT EXIST %BOOTDIR%:\MSPE\此文件夹已设防删除..\NUL MD %BOOTDIR%:\MSPE\此文件夹已设防删除..\
ATTRIB +S +H %BOOTDIR%:\MSPE
ATTRIB +S +H %BOOTDIR%:\BOOT.INI
ATTRIB +S +H %BOOTDIR%:\BOOT.BAK
ATTRIB +S +H %BOOTDIR%:\XPEMENU.INI
GOTO 成功

:判断
color 0e
CLS
ECHO.
ECHO.
ECHO   你似乎已经安装了WinPE了，请选择以下操作选项。
ECHO.
ECHO 　  按键1. 重新安装
ECHO 　  按键2. 完全卸载
ECHO 　  按键3. 退出安装
ECHO.
SET CHOICE=
SET /P CHOICE=请选择要进行的操作选项，然后按回车：
IF NOT "%CHOICE%"=="" SET CHOICE=%CHOICE:~0,1%
IF /I "%CHOICE%"=="1" GOTO 安装
IF /I "%CHOICE%"=="2" GOTO 卸载
IF /I "%CHOICE%"=="3" EXIT
GOTO 判断
EXIT

:退出
CLS
COLOR 4E
IF "%BOOTDIR%"=="BOOTDIR" 系统要求=%系统要求%，但未找到BOOT.ini文件
ECHO.
ECHO.
ECHO   %系统要求%，安装不能继续！
ECHO.
ECHO 按任意键退出......
PAUSE >NUL
EXIT

:成功
CLS
COLOR 0b
ECHO.
ECHO.
ECHO 已将《微型 Windows PE 嵌入式系统》安装到你的%BOOTDIR%:盘。＾_＾
ECHO.　
ECHO （已将原BOOT.INI备份为BOOT.BAK）
ECHO.
ECHO 按任意键退出......
PAUSE >NUL
EXIT

:卸载
COLOR 0a
CLS
ECHO.
ECHO.
ECHO 正在卸载WinPE请稍候......
ECHO.
IF EXIST %BOOTDIR%:\AVLDR.XPE DEL /AR /AS /AH %BOOTDIR%:\AVLDR.XPE
IF EXIST %BOOTDIR%:\XPELDR DEL /AR /AS /AH %BOOTDIR%:\XPELDR
IF EXIST %BOOTDIR%:\WINNT.XPE DEL /AR /AS /AH %BOOTDIR%:\WINNT.XPE
IF EXIST %BOOTDIR%:\XPEMENU.INI DEL /AR /AS /AH %BOOTDIR%:\XPEMENU.INI
IF EXIST %BOOTDIR%:\MSPE\此文件夹已设防删除..\NUL RD /S /Q %BOOTDIR%:\MSPE\此文件夹已设防删除..\
IF EXIST %BOOTDIR%:\MSPE RD /S /Q %BOOTDIR%:\MSPE
ATTRIB  -S -H -R %BOOTDIR%:\BOOT.INI
IF EXIST %BOOTDIR%:\BOOT.BAK (
ATTRIB  -S -H -R %BOOTDIR%:\BOOT.BAK
FIND /I "AVLDR.XPE" %BOOTDIR%:\BOOT.BAK >NUL
IF %ERRORLEVEL%==0 (
TYPE %BOOTDIR%:\BOOT.BAK|FIND /I /V "AVLDR.XPE">%BOOTDIR%:\BOOT.INI
) ELSE (
COPY /Y %BOOTDIR%:\BOOT.BAK %BOOTDIR%:\BOOT.INI>NUL
)
) ELSE (
COPY /Y %BOOTDIR%:\BOOT.INI %BOOTDIR%:\BOOT.BAK>NUL
TYPE %BOOTDIR%:\BOOT.BAK|FIND /I /V "AVLDR.XPE">%BOOTDIR%:\BOOT.INI
)
ATTRIB +S +H %BOOTDIR%:\BOOT.INI
COLOR 0b
CLS
ECHO.
ECHO.
ECHO 已经成功卸载 ＾_＾
ECHO.
ECHO 按任意键退出 ......
PAUSE >NUL
EXIT

兄弟啊，我看得头大了.......你直接说在哪里改就行了.....

不要怕麻烦，一行一行地慢慢看，不懂的地方多问问，不用多久就会懂了。

@echo off
FOR %%B IN (C D E F G H I J K L M N O P Q R S T U V W) DO IF EXIST %%B:\boot.ini (%%B: 
goto xiugai
) else （echo 没有找到BOOT.INI
PAUSE
GOTO :EOF）
:xiugai
for /f "delims=" %%l in (boot.ini) do (
echo.%%l | find/i "timeout=">nul && echo timeout=10||echo %%l
)>>boot.new
attrib -s -h -r boot.ini
copy boot.new boot.ini>nul
attrib +s +h +r boot.ini
del boot.new