中国DOS联盟

批处理问题！！！急急急急急，求高手看看帮帮忙小弟我先谢谢了！！！！：
我要在批处理文件AUTOEXEC.BAT中先后执行C:\EMUL目录内的disk.exe和sgag.exe两个文件，我不知道怎么写。
这是我的AUTOEXEC.BAT文件中的语句：

@ECHO OFF
KPUSH 27 27
KPUSH>NUL
REM Made by Wengier. China DOS Union.
REM All rights reserved. 2002-2003.
TM /F
LH KILLER
LH DOSKEY
LH CTMOUSE
::Note: The following line is for the compatibility on some systems:
LH CTMOUSE>NUL
IF %CONFIG%#==M6# GOTO SHUT
IF NOT %CONFIG%#==M5# GOTO BOOT
ECHO.
ECHO Now preparing to open README with Chinese support...
XMSDSK 80 /Y>NUL
FINDRAMD>NUL
IF %RAMDRIVE%#==# ECHO Can't create RAM disk!
IF %RAMDRIVE%#==# GOTO SHUT
EXTRACT /E /L %RAMDRIVE%\ DOSET.CAB EDIT.COM>NUL
XZL
%RAMDRIVE%\EDIT README.TXT
CLS
XZL /Q
:SHUT
CLS
WBAT BOX "Please enter your choice:",Shutdown the computer,Restart the computer
IF NOT ERRORLEVEL 3 GOTO ANS
WBAT BOX (RED ON YELLOW) "Note: Please make a choice!",OK
GOTO SHUT
:ANS
IF ERRORLEVEL 2 GOTO RES
ECHO Now trying to shutdown the computer..
ECHO.
SHUTDOWN S
ECHO.
ECHO Shutdown failed. Your computer may not have an ATX power.
:RES
ECHO Now restart the computer..
ECHO.
SHUTDOWN R
GOTO END
:BOOT
SET SM=
DREADY C:
IF ERRORLEVEL 1 ECHO Warning: Can't find any valid hard drives!
IF ERRORLEVEL 1 GOTO NOHD
ECHO Y|LOCK C:>NUL
ECHO.
ECHO Now trying to load the hard disk cache to speed the drives up...
WBAT BOX "Please choose the hard disk cache you like in 5 seconds:",PC-CACHE,SMARTDRV,Cancel #1,5
IF ERRORLEVEL 3 ECHO Cancelled.
IF NOT ERRORLEVEL 2 LH PCCACHE /SIZEXT:4096 /WRITE:OFF /WIN /MINI
IF ERRORLEVEL 2 IF NOT ERRORLEVEL 3 SET SM=Y
:NOHD
ECHO.
LH MSCDEX /D:IDE-CD /D:SCSI-CD /D:USB-CD /S /K
XMSDSK 4096 /Y
ECHO Setting up the RAM disk...
FINDRAMD>NUL
IF %RAMDRIVE%#==# GOTO NORAM
IF NOT EXIST %RAMDRIVE%\SYSTEM\NUL MD %RAMDRIVE%\SYSTEM
COPY COMMAND.COM %RAMDRIVE%\SYSTEM>NUL
EXTRACT /E /L %RAMDRIVE%\SYSTEM DOSET.CAB>NUL
EXTRACT /E /L %RAMDRIVE%\SYSTEM VC.CAB>NUL
ECHO The necessary tools have been successfully loaded to drive %RAMDRIVE%.
MD %RAMDRIVE%\TEMP
SET COMSPEC=%RAMDRIVE%\SYSTEM\COMMAND.COM
SET TMP=%RAMDRIVE%\TEMP
SET TEMP=%RAMDRIVE%\TEMP
PATH=%RAMDRIVE%.;%RAMDRIVE%\SYSTEM
IF %SM%#==Y# LH SMARTDRV 4096 2048 /X
GOTO NEXT
:NORAM
ECHO Warning: Can't create RAM disk!
IF %SM%#==Y# ECHO Can't load SMARTDRV!
SET COMSPEC=A:\COMMAND.COM
:NEXT
SET SM=
SET DIRCMD=/OGN /4
SET PROMPT=$P$G
PATH=%PATH%;C:.;A:.;..
LH SHARE
LH ZENO /Q
LH MOUSCLIP /M
LH DOSLFN /C- /Z:CP936UNI.TBL
IF %CONFIG%#==M3# IF %RAMDRIVE%#==# ECHO Warning: Can't load NTFS drives support!
IF %CONFIG%#==M4# IF %RAMDRIVE%#==# ECHO Warning: Can't load NTFS drives support!
IF %CONFIG%#==M3# IF NOT %RAMDRIVE%#==# NTFSDOS /U
IF %CONFIG%#==M4# IF NOT %RAMDRIVE%#==# NTFSDOS /U
LH ESCAPE
FINDCD /Q
CLS
WRITEXT 1 1 -f15 Note:
ECHO.
IF NOT %CDROM%#==# ECHO For accessing CD/DVD drive, use the drive letter %CDROM%(1st).
IF NOT %RAMDRIVE%#==# ECHO For accessing RAM drive, use the drive letter %RAMDRIVE%.
IF NOT %CONFIG%#==M3# IF NOT %CONFIG%#==M4# ECHO For accessing NTFS drives(if any), type NTFSDOS at the command line.
ECHO At any time, you can press F12 key to return to DOS, or use the mouse.
BREAK ON
LFNFOR ON
IF %RAMDRIVE%#==# GOTO END
ECHO.
ECHO Press ENTER in 2 seconds if you want to start Volkov Commander..
WAIT 2
SET VC=
IF ERRORLEVEL 13 IF NOT ERRORLEVEL 14 SET VC=1
IF %VC%#==# ECHO Skipped.
ECHO.
ECHO Now you're in MS-DOS 7.10 prompt.
ECHO.
ECHO For more information, please look at README.TXT (in Chinese).
ECHO To start Chinese system for Chinese, type XZL at the command line.
WRITEXT 0+ 1 "Any comments, please come to the forum at: " -f15 http://dosbbs.2ya.com/ -f7
ECHO.
IF %VC%#==# GOTO END
SET VC=
ECHO.
ECHO Starting Volkov Commander...
ECHO.
SET DIF=
STRINGS UMB=UMBLARGE >NUL
STRINGS DIF=SUB %UMB%,30720 >NUL
SET UMB=
IF NOT %DIF%#==# GOTO LH
VC
GOTO END
:LH
SET DIF=
LH VC
:END
ECHO.

[ Last edited by willsort on 2006-4-14 at 18:39 ]

本来想说这个问题太容易了，不过看你的autoexec.bat，好高深啊。不知是你写的，还是别人的？
如果只是想先后启动，你可以这样写：
C:\EMUL\disk.exe
c:\emul\sgag.exe
不过我不知你是什么意思。算帮你顶一下吧。

看需要在哪个选单下执行了.

谢谢！！！！！我笨不知道，谢谢各位兄弟了