中国DOS联盟

请教大家，批处理如何调用一个文本随机行并分别定义变量？


文本内容如：
——————————
WKS001 1 abcdefg
WKS002 2 abcdefg
WKS003 3 abcdefg
WKS004 4 abcdefg
WKS005 5 abcdefg
WKS006 6 abcdefg
WKS006 6 abcdefg
...
——————————
如此，行数不固定，每行3段字符分别用空格隔开，要求在批处理中随机调入某行，然后定义该行的3段字符为变量a b c

调试好以后，本人会给作者充值10Q币作为回报，谢谢大家

[ Last edited by adslcool on 2010-11-18 at 16:15 ]

我QQ 165306921

这Q币好像不难得到…… 上面的接标了?

::如果每行中间的那个数字是序号的话，可以用 Findstr 随机找出。



@echo off & Title 变量随机定义

Setlocal EnableDelayedExpansion



::查找文件里的有效数据有多少行：

For /f %%a in ('findstr  "^WKS"  File.txt  ') do (set /a N+=1)

Echo File.txt 文件共有 !N! 行有效数据！



::设置随机数，并用 Findstr 找出 行中间有对应数的那一行。

set /a Line=%Random% %% !N! +1

For /f "tokens=1-3" %%a in ('findstr " %Line% " File.txt ') do (

set "One=%%a"

set "Two=%%b"

set "Thr=%%c"

)

echo %One%

echo %Two%

echo %Thr%

Endlocal

Pause

[ Last edited by wewebb on 2010-11-18 at 18:30 ]

::如果每行中间的那个数字不是序号，而是个不定数的话。



@echo off & Title 变量随机定义

Setlocal EnableDelayedExpansion



::查找文件里的有效数据有多少行，并为每行加上行号：

(For /f "delims=" %%a in ('findstr  "^WKS"  File.txt  ') do (set /a N+=1 & echo !N! %%a) ) > NewFile.txt



Echo NewFile.txt 文件共有 !N! 行有效数据！



::设置随机行数，并用 Findstr 找出对应行。

set /a Line=%Random% %% !N! +1



For /f "tokens=2-4" %%a in ('findstr "^%Line% " NewFile.txt ') do (

set "One=%%a"

set "Two=%%b"

set "Thr=%%c"

)

echo %One%

echo %Two%

echo %Thr%

Endlocal

Pause

[ Last edited by wewebb on 2010-11-18 at 18:29 ]

::如果文件内容都是纺一格式（没有多余信息行），每行中间的数是不定数的话。



@echo off & Title 变量随机定义

Setlocal EnableDelayedExpansion



::查找文件里有多少行

For /f "delims=" %%a in (File.txt) do set /a N+=1



Echo File.txt 文件共有 !N! 行！



::设置随机行数

set /a Line=%Random% %% !N! +1



For /f "tokens=1-3" %%a in (File.txt) do (

set /a num+=1

if !num! == !Line! (set "One=%%a" & set "Two=%%b" & set "Thr=%%c")

)

echo %One%

echo %Two%

echo %Thr%

Endlocal

Pause

[ Last edited by wewebb on 2010-11-18 at 18:49 ]

多谢各位，我先测试一下，上面大侠的