中国DOS联盟

各位好！
偶的机子是XP，有CDEFGH几个盘，现在由于机子中了毒，格式化C盘后重新安装了系统，但其它盘的各个子目录和子文件夹下均有_desktop.ini文件(这是个病毒)，文件本身具有《隐藏，只读，系统》属性，直接删除不掉，偶不可能一个个的在命令行模式下手动删除，所以请教如何写个批处理来通杀掉硬盘上的所有这个_desktop.ini (偶这里要请教的是批处理的语法，专杀病毒工具软件不在讨论之列， 另外请版主不要删贴，因为偶已经搜索了相关贴子，均不能彻底解决这个问题，所以才发新贴请教，请原谅！)
@echo off
for %%i ('_desktop.ini') --------- do attrib -r -a -h -s _desktop.ini & del _desktop.ini
pause
exit

思路是先查找硬盘上所有分区子目录下的各个文件夹内的_desktop.ini文件，找到后用ATTRIB来改变它们的属性，紧接着用DEL删除掉这个文件，这样在硬盘上就不会再有这个病毒了，请各位赐教---------谢谢！
值得注意的是路径中肯定会有中文路径或带有空格的路径的，诚候指教-------
另外想问的是，如果系统是WIN2000，这个批处理是否同样适用？

[ Last edited by flying008 on 2006-9-20 at 20:27 ]

虽然WINDWOS下的FIND查找功能或许可以实现同类功能，但偶是诚心求教批处理的语法并学习，请各位不吝赐教------

　　以下代码可以在全盘删除所有文件夹下的_desktop.ini，而不管它具备何种属性。

@echo off

setlocal enabledelayedexpansion

for /f "delims=\" %%i in ('fsutil fsinfo drives^|find /v ""') do (

    set var=%%i

    set drive=!var:~-2!

    fsutil fsinfo drivetype !drive!|find "固定">nul && del /a /f /s !drive!\_desktop.ini

)

pause

Namejm的代码太强悍了，都fsutil fsinfo drivetype !drive!|find "固定"，呵呵

　　抄袭某个毒王的代码，呵呵。

强!!! 先列出所有硬盘盘符, 再删指定文件.

[ Last edited by pengfei on 2006-10-14 at 09:30 ]

用这寸代码搞搞其他文件也不错哦!呵呵!

提示下：个人经验认为：没有纯文件病毒。一般都还感染注册表的

恩病毒不感染注册表也不成病毒了。楼主的此类病毒一般是靠光盘U盘传播的，所以组策略里关闭自动播放相当重要的！

已经解决了！！！
1、首先在这里真诚感谢namejm! 是你的代码和帮助让偶成功实现杀毒和学习语法。
2、同时也感谢所有看贴和回贴指教的大大以及DOS联盟的会员！
3、to electronixtar :偶已经恢复系统了，所以系统盘的注册表不存在这类感染问题，谢谢你的提醒。
　to fastslz : 偶已经在组策略里禁止了autorun,谢谢你！在偶初来论坛的时候，就有你和electronixtar及BagPipe等高手的帮助，谢谢你们！　

　　3742668版主一句话就搞定了，厉害。什么时候能给我们讲解一下wmic的用法就好了。

　　顺便指出一下版主的疏忽之处：楼主需要把_desktop.ini删掉，而不是desktop.ini，呵呵，一个符号的差异。

3742668版主和namejm兄的代码太强悍了, 怎么也看不懂, 呵呵~ 向你们学习.

我就贴一段大家都看的懂的代码吧! 也是全盘强制删除_desktop.ini文件:

@echo off
if exist "%tmp%\note.txt" del /a "%tmp%\note.txt" >nul 2>nul
set num=0
setlocal enabledelayedexpansion
for %%i in (c d e f g h i j k l m n o p q r s t u v w x y z) do (
if exist %%i: (
cd\
for /f "tokens=*" %%a in ('dir /s /a-d /b %%i:\_desktop.ini') do (
echo %%a>>"%tmp%\note.txt"
set /a num=!num!+1
del /q /a /f "%%a"
)
)
)
cls
echo 共删除文件: %num%个
pause
if not "%num%"=="0" start "" "%tmp%\note.txt"

[ Last edited by pengfei on 2006-9-23 at 08:27 ]

为什么不在盘符下 del /s/a _desktop.ini ? del /?

wmic 还没有用过