中国DOS联盟

windows经常出一些更新补丁,而很多补丁一个一个去安装很繁琐,我想用批处理的方法实现自动安装补丁目录下的所有文件且不显示安装界面,于是编了这样一个批处理,但没有达到我想要的结果,如下:

@echo off
setlocal enabledelayedexpansion
for /f %%a in ('dir /b^|find /c ".exe"') do set /a SUM=%%a //计算目录下有多多少个更新补丁
set N=0
for /f "delims=" %%i in ('dir /b *.exe') do (
set /a N+=1
echo 正在更新,请稍后 (%N%/%SUM%^)...
"%%i" /quiet /norestart
cls
)

pause

问题:for中的 set /a N+=1没启到作用,%N%的值一直都是0

有人说 FOR里面要用到SET，就要在FOR前加setlocal
enabledelayedexpansion ，然后SET的参数要用!X!引用值
但是我试了仍然不成功,不知哪里出错了?

把你试的!X!的完整代码贴出来看看

@echo off
setlocal enabledelayedexpansion
for /f %%a in ('dir /b^|find /c ".exe"') do set /a SUM=%%a
应该写成find /c /i ".exe"，使用/i来忽略exe字符的大小写
应该写成set SUM=%%a，/a是用来运算的，直接赋值时不需要
set N=0
这个set N=0可以不用，在运算时，set会为不存在的变量自动赋值为0。
for /f "delims=" %%i in ('dir /b *.exe') do (
set /a N+=1
echo 正在更新,请稍后 (%N%/%SUM%^)...
"%%i" /quiet /norestart
cls
)
%N%应该写成!N!，否则N的值将不被扩展
pause
你的代码可以写成这样：

@echo off
for /f %%a in ('dir /b^|find /i /c ".exe"') do for /f "delims=" %%i in ('dir /b *.exe') do (
set /a N+=1&call echo 正在更新,请稍后 (%%N%%/%%a^)...
"%%i" /quiet /norestart
cls)
pause

Last edited by Hanyeguxing on 2010-3-19 at 21:21 ]

多谢指点！又学到了几个新的技巧