中国DOS联盟

另外，FOR 变量参照的替换已被增强。您现在可以使用下列
选项语法:

~I - 删除任何引号(")，扩充 %I
%~fI - 将 %I 扩充到一个完全合格的路径名
%~dI - 仅将 %I 扩充到一个驱动器号
%~pI - 仅将 %I 扩充到一个路径
%~nI - 仅将 %I 扩充到一个文件名
%~xI - 仅将 %I 扩充到一个文件扩展名
%~sI - 扩充的路径只含有短名
%~aI - 将 %I 扩充到文件的文件属性
%~tI - 将 %I 扩充到文件的日期/时间
%~zI - 将 %I 扩充到文件的大小
%~$PATH:I - 查找列在路径环境变量的目录，并将 %I 扩充
到找到的第一个完全合格的名称。如果环境变量名
未被定义，或者没有找到文件，此组合键会扩充到
空字符串

可以组合修饰符来得到多重结果:

%~dpI - 仅将 %I 扩充到一个驱动器号和路径
%~nxI - 仅将 %I 扩充到一个文件名和扩展名
%~fsI - 仅将 %I 扩充到一个带有短名的完整路径名
%~dp$PATH:i - 查找列在路径环境变量的目录，并将 %I 扩充
到找到的第一个驱动器号和路径。
%~ftzaI - 将 %I 扩充到类似输出线路的 DIR

在以上例子中，%I 和 PATH 可用其他有效数值代替。%~ 语法
用一个有效的 FOR 变量名终止。选取类似 %I 的大写变量名
比较易读，而且避免与不分大小写的组合键混淆。

上面是for中解释，不知说的是什么东西，
有人可以举个例子，指点一下吗，
谢谢了！





———————————————————————
转移自 DOS学习入门 & 精彩文章 （教学室）

——管理员
———————————————————————

你可以用for来获取一个文件的路径、大小、扩展名等信息

把我发在下面的代码保存成一个bat，运行一下，你就会清楚了。

echo off & cls
set abc=%temp%\abc
echo.　先在系统盘下建立一个abc文件夹
if not exist "%abc%". md "%abc%" || (
echo.　建立失败！按任意键退出！
pause >nul
exit
)
pushd %abc%
echo.　在abc中建立5个文本文件
echo.>1.txt
echo.>2.txt
echo.>3.txt
echo.>4.txt
echo.>5.txt
echo.　现在使用for语句列出abc中的文件：
echo.　打印时用的是：echo.%%I
for /f "tokens=* delims=" %%I in ('dir/b/a *.*') do (
echo.%%I
)
echo.　可以看到列出的只是文件名。
echo.　如果想看到完全的文件路径，
echo.　就可以用所谓的“for 中变量参照的替换已被增强”
echo.　把打印时的echo.%%I改成echo.%%~fI
for /f "tokens=* delims=" %%I in ('dir/b/a *.*') do (
echo.%%~fI
)
echo.　可以看到，列出来的就是完整的文件路径了。
echo.　其他的for变量参照替换都可以在for /?中找到！
echo.
echo.===================
echo.　按任意键删除abc文件夹并退出！
pause >nul
popd
echo.　删除abc文件夹
if exist "%abc%". rd/q/s "%abc%"
exit

[ Last edited by MantisLin on 2010-12-17 at 18:09 ]

本身if就有if ... else ... ，所以就不要用
if not exist "%abc%". md "%abc%" || (
echo.　建立失败！按任意键退出！
)

你没明白我用||的用意，我用||的用意是防止建立abc文件夹失败！
比如%temp%里正好有一个名为abc，并且没有后缀名的文件，那么||就有作用了。

[ Last edited by MantisLin on 2010-12-17 at 18:10 ]

那 if not exist "%abc%". 还有什么意义了？

意义在于：如果abc文件夹已经存在，就不需要创建！
不需要创建和防止创建失败是两码事

[ Last edited by MantisLin on 2010-12-17 at 20:20 ]