中国DOS联盟

echo off
for /f "skip=4 tokens=1,2 delims=:" %%a in ('reg query HKEY_LOCAL_MACHINE\SOFTWARE\Tencent\QQ2009 /v Install') do (
set QQPathL=%%a
set QQPathR=%%b
)
set QQPath=%QQPathL:~-1%:%QQPathR%
echo %QQPath%
pause

上面代码是显示QQ的安装路径，问一下怎么显示（默认）里的数值？

Last edited by pan542 on 2010-4-6 at 22:44 ]

比如下面的注册表信息
Windows Registry Editor Version 5.00

[HKEY_LOCAL_MACHINE\SOFTWARE\信息\路径]
@="C:\\Program Files\\信息"

如何用批处理显示"C:\\Program Files\\信息"的信息?

@echo off
for /F "skip=4 tokens=2,*" %%a in ('reg query "HKLM\SOFTWARE\信息\路径" /ve') do echo %%b
pause

或

@echo off
for /F "skip=4 tokens=2,*" %%a in ('reg query "HKLM\SOFTWARE\信息\路径" /v ""') do echo %%b
pause

好像显示没效果啊？

运行这个进行测试：

@echo off
echo 添加注册表>d:\179.txt
reg add "HKLM\SOFTWARE\信息\路径" /ve /d "C:\Program Files\信息" /f>>d:\179.txt
echo 返回注册表>>d:\179.txt
for /F "skip=4 tokens=2,*" %%a in ('reg query "HKLM\SOFTWARE\信息\路径" /ve') do echo %%b>>d:\179.txt
echo 删除注册表>>d:\179.txt
reg delete "HKLM\SOFTWARE\信息" /f>>d:\179.txt
pause

查看d:\179.txt

非常感谢Hanyeguxing的细心解答。
不过我主要想显示"C:\Program Files\信息"这部分内容

5楼的代码是供你测试的，你运行3楼的代码没有正确显示吗？
那你把运行3楼代码后的结果贴上来
最好也运行5楼的代码，把179.txt的内容贴出来

一开始运行3楼的2个代码都只显示“请按任意键继续。。。”

再运行5楼的代码也只显示“请按任意键继续。。。”

179.txt显示的内容如下：
“添加注册表

操作成功返回注册表
删除注册表

操作成功”


再运行3楼的代码就显示：
错误: 系统找不到指定的注册表项或值
请按任意键继续. . .

如果只要显示：

@echo off
for /f "skip=4 tokens=1,2 delims=:" %%a in ('reg query "HKLM\SOFTWARE\信息\路径" /ve') do set c=%%a&echo|echo %%c:~-1%%:%%b
pause

Last edited by Hanyeguxing on 2010-4-6 at 17:18 ]

如果要使用这个路径做变量：

@echo off
for /f "skip=4 tokens=1,2 delims=:" %%a in ('reg query "HKLM\SOFTWARE\信息\路径" /ve') do set c=%%a&call set c=%%c:~-1%%:%%b
echo %c%
pause

Last edited by Hanyeguxing on 2010-4-6 at 17:18 ]

在家测试成功~
十分感谢！！！