中国DOS联盟

具体情况如下：
因为要写一个注册某软件的批处理，需要将序列号（纯数字）转换为对应的16进制，经过系列换算后再将新的16进制数据再转回10进制
比如：

2319692668
转换成16进制后应该是
8a43b37c

反过来16进制的
8a43b37c
转换成10进制应该是
2319692668

但是我在CMD中用set /a 0x8a43b37c得到的结果却是
-1975274628

这是怎么回事？

Last edited by suntb on 2009-10-8 at 21:22 ]

因为批处理或cmd下，只能精确到32位，这个32位是指二进制32位，其中最高位为符号位（0为正，1为负），低位31位为数值。
31个1换成十进制为2147483647，所以cmd下计算的有效值范围是 -2147483648 至 2147483647 。
你的数字大于这个数值范围，溢出了。。。。。。

Last edited by Hanyeguxing on 2009-10-8 at 17:56 ]

Originally posted by Hanyeguxing at 2009-10-8 17:48:
因为批处理或cmd下，只能精确到32位，这个32位是指二进制32位，其中最高位为符号位（0为正，1为负），低位31位为数值。
31个1换成十进制为2147483647， ...

谢谢　怎么解决？

给个10转多进制的 支持大数
你逆算一下

@echo off&setlocal enabledelayedexpansion

set/p s=请输入十进制数:

set/p x=请输入转换进制:

set "str=0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ_@"

:lp

set /a "n=8189,m=0,r=0"

for /l %%a in (1,1,14) do (

     set /a "u=(n+m)/2"

     for %%i in (!u!) do if "!s:~%%i!" equ "" (set /a n=u) else set /a m=u

)

for /l %%i in (0,1,%u%) do (

   set/a "n=!s:~%%i,1!+(r*10),r=n%%x,n/=x"

   set v=!v!!n!

)

   set b=!str:~%r%,1!!b!

   for /f "tokens=* delims=0" %%i in ("0!v!") do set "s=%%i"

   if defined s set v=&goto lp

   echo "!b!"

pause

Originally posted by terse at 2009-10-8 20:14:
给个10转多进制的 支持大数
你逆算一下

@echo off&setlocal enabledelayedexpansion

set/p s=请输入十进制数:

set/p x=请输入转换进制:

set "str=01234567 ... 


非常感谢terse

经测试10进制转16进制没问题了

至于16进制转10进制我自己再琢磨一下

如果大家有好用的代码也可以贴上来帮忙下

自己逆算一下 应该可以了吧

这不是件易事哦！
关键是溢出，要分段来做加法和乘法

16制（后7位+7位前的*268435456）

建议还是用三方吧

Last edited by netbenton on 2009-10-9 at 06:22 ]

发现变量int为空 最后显示空 修正下
另把补位的去掉 直接加

@echo off&setlocal enabledelayedexpansion

set s=8a43b37c

    set /a "x=8189,m=0"

    for /l %%a in (1,1,14) do (

    set /a "l=(x+m)/2"

    for %%i in (!l!) do if "!s:~%%i!" equ "" (set /a x=%%i) else set /a "m=%%i"

    )

    for /l %%i in (!l! -1 0) do (

        set/a "i=0x!s:~%%i,1!,n=l-%%i"

        if !n! lss 2 (

        if defined in (set/a in+=16*i&if !in! gtr 99 (set rl=2)else set "rl=1"

        for /l %%j in (0 1 !rl!) do set "ins=!in:~%%j,1!!ins!"

      ) else set/a "in=i"

      ) else (

           set /a "i*=16"

           if !i! gtr 99 (set lr=2)else set "lr=1"

           for /l %%j in (0 1 !lr!) do set "inx=!i:~%%j,1!!inx!"

           for /l %%a in (2 1 !n!) do (

               for /l %%i in (0 1 !lr!) do (

                   set /a "m=6*!inx:~%%i,1!+r"

                   if !m! gtr 9 (set r=!m:~,1!) else set "r="

                   set "ni=!ni!!m:~-1!"

                   )

                   set ni=!ni!!r!&set in=!ni:~1!&set nj=!nj!!ni:~,1!&set "r="

                   for /l %%i in (0 1 !lr!) do (

                   set/a "m=!in:~%%i,1!+!inx:~%%i,1!+r"

                   if !m! gtr 9 (set r=1) else set "r="

                   set "nx=!nx!!m:~-1!"

          )

          set inx=!nj!!nx!!r!&set nj=&set ni=&set "nx="

          if !m! lss 10 (set /a lr+=1)else set r=&set /a lr+=2

       )

          if !rl! lss !lr! set/a "rl=lr"

          for /l %%i in (0 1 !rl!) do (

              set/a "m=!inx:~%%i,1!+!ins:~%%i,1!+r"

              if !m! gtr 9 (set r=1) else set "r="

              set "ni=!ni!!m:~-1!"

              )

             if defined r set/a rl+=1&set ni=!ni!!r!&set "r="

             set ins=!ni!&set ni=&set "inx="

           )

        )

           if defined ins set in=&for /l %%i in (0 1 !rl!) do set "in=!ins:~%%i,1!!in!"

           echo !in!&pause

Last edited by terse on 2009-10-10 at 23:02 ]

Originally posted by terse at 2009-10-9 23:14:

@echo off&setlocal enabledelayedexpansion

set s=8a43b37c

set /a ix=16

    set /a "x=8189,m=0"

    for /l %%a in (1,1,14) do (

    set /a "l=(x+m)/2"

    for %% ... 



非常感谢 测试通过