请教通过批处理如何生成N天以内的目录列表! - 中国DOS联盟论坛

@echo off&setlocal enabledelayedexpansion
::设置几天内
set n=150
::设置路径
set "p=D:\rec"
for /f "tokens=1-3 delims=-:/ " %%a in ("%date%") do (
set Y=%%a&set M=%%b&set D=%%c
if "!M:~0,1!"=="0" set M=!M:~1!
if "!D:~0,1!"=="0" set D=!D:~1!
)
set/a D-=n
if %D% leq 0 goto:han
:ye
echo.筛选时间点为:%Y%年%M%月%D%日到今天
set M=0%M%&set D=0%D%&set n=%Y%!M:~-2!!D:~-2!
(for /f "delims=" %%a in ('dir /s/b/ad "%p%"') do (
set t=%%~ta&set t=!t:-=!
if !t:~0^,8! gtr %n% echo.%%a
))>c:\输出_%n%.txt
pause&exit
:han
set/a M-=1
if !M!==0 set/a Y-=1,M=12
set/a "T=^!(M-2)","R=(^!(Y%%4)&^!^!(Y%%100))|^!(Y%%400)","C=^!(M-4)|^!(M-6)|^!(M-9)|^!(M-11)","D=T*(28+R)+C*30+(^!T&^!C)*31+D"
if %D% leq 0 (goto:han) else goto:ye

第1楼　sonorous	发表于 2010-05-28 16:20
新手上路　发帖 1　积分 1
请教通过批处理如何生成N天以内的目录列表! 按最近修改时间查找出N天以内的目录并生成列表，请问代码如何写？用forfiles只能查找N天以前的，不是N天以内的，而且forfiles好像不能只显示目录这个需求在unix/linux里就是一条find命令，在dos下怎么实现呢？linux系统里如下： find / -type d -mtime -XXX -print > /tmp/list.txt

第2楼　Hanyeguxing	发表于 2010-05-28 22:05
银牌会员　发帖 897　积分 1,039　来自在地狱中仰望天堂
@echo off&setlocal enabledelayedexpansion ::设置几天内 set n=150 ::设置路径 set "p=D:\rec" for /f "tokens=1-3 delims=-:/ " %%a in ("%date%") do ( set Y=%%a&set M=%%b&set D=%%c if "!M:~0,1!"=="0" set M=!M:~1! if "!D:~0,1!"=="0" set D=!D:~1! ) set/a D-=n if %D% leq 0 goto:han :ye echo.筛选时间点为:%Y%年%M%月%D%日到今天 set M=0%M%&set D=0%D%&set n=%Y%!M:~-2!!D:~-2! (for /f "delims=" %%a in ('dir /s/b/ad "%p%"') do ( set t=%%~ta&set t=!t:-=! if !t:~0^,8! gtr %n% echo.%%a ))>c:\输出_%n%.txt pause&exit :han set/a M-=1 if !M!==0 set/a Y-=1,M=12 set/a "T=^!(M-2)","R=(^!(Y%%4)&^!^!(Y%%100))\|^!(Y%%400)","C=^!(M-4)\|^!(M-6)\|^!(M-9)\|^!(M-11)","D=T(28+R)+C30+(^!T&^!C)*31+D" if %D% leq 0 (goto:han) else goto:ye