依次横向显示文档中的字符 - 中国DOS联盟论坛

　　试试下面的代码：

　　版本一：


@echo off
:: 如果有半角双引号，将不能继续处理下去，但是可以兼容除等号外的其他特殊字符
:: 如果有等号，将在等号出现的地方报错，但可以继续处理下一个字符
:: 忽略以引号打头的行，忽略空行
:: 不能处理unicode格式文本
for /f "delims=" %%i in (test.txt) do (
    set "str=%%i"
    call :pickup
)
pause
goto :eof

:pickup
ping -n 1 127.1>nul
set /p "var=%str:~0,1%"<nul
set "str=%str:~1%"
if not "%str%"=="" goto pickup
echo.
goto :eof

　　版本二：


@echo off
:: 把半角双引号换成空格，把等号换成〓，兼容其他特殊字符
:: 能处理以分号打头的行，但是会忽略空行；
:: 能兼容unicode格式的文本
:: 每行之间空一行显示
for /f "delims= eol=" %%i in ('type test.txt') do (
    set "str=%%i"
    call set "str=%%str:"= %%"
    call :pickup
)
pause
goto :eof

:pickup
ping -n 1 127.1>nul
if "%str:~0,1%"=="=" set "str=〓%str:~1%"
set /p "var=%str:~0,1%"<nul
set "str=%str:~1%"
if defined str goto pickup
echo.&echo.
goto :eof

　　版本三：


@echo off
:: 与版本二的几点区别：
::　　 1、不能处理unicode文本
:: 　　2、每行之间不再强行加上空行，并且能原样显示空行
for /f "delims= eol=" %%i in ('findstr /n .* test.txt') do (
    set "str=%%i"
    call set "str=%%str:"= %%"
    call set "str=%%str:*:=%%"
    call :pickup
)
pause
goto :eof

:pickup
if not defined str echo.&goto :eof
ping -n 1 127.1>nul
if "%str:~0,1%"=="=" set "str=〓%str:~1%"
set /p "var=%str:~0,1%"<nul
set "str=%str:~1%"
if defined str goto pickup
echo.
goto :eof

[ Last edited by namejm on 2007-2-2 at 01:42 PM ]

第1楼　26933062	发表于 2007-02-02 14:41
银牌会员　发帖 879　积分 2,268
依次横向显示文档中的字符 a.txt内容如下 abcefg 1234567 yuhgrte 问题:我运行以下批处理后,显示完第一排字符后就停了,有什么办法能继续显示后面的字符? @echo off set s=0 for /f "delims=" %%i in (a.txt) do call :xs %%i goto :eof :xs set a=%1 :top echo.\|call set /p b=%%a:~%s%,1%% set /a s+=1 goto top

第2楼　PPdos	发表于 2007-02-02 17:38
高级用户　发帖 268　积分 783
学习楼主程序在下愚见认为:xs没有定义退出循环的条件从而不能进入第二行的显示

第3楼　anqing	发表于 2007-02-02 22:08
高级用户　发帖 413　积分 859
xs set a=%1 :top echo.\|call set /p b=%%a:~%s%,1%% set /a s+=1 goto top 这些地方看不懂？

第4楼　namejm	发表于 2007-02-02 22:32
荣誉版主　发帖 1,737　积分 5,226　来自成都
试试下面的代码：　　版本一： @echo off :: 如果有半角双引号，将不能继续处理下去，但是可以兼容除等号外的其他特殊字符 :: 如果有等号，将在等号出现的地方报错，但可以继续处理下一个字符 :: 忽略以引号打头的行，忽略空行 :: 不能处理unicode格式文本 for /f "delims=" %%i in (test.txt) do ( set "str=%%i" call :pickup ) pause goto :eof :pickup ping -n 1 127.1>nul set /p "var=%str:~0,1%"<nul set "str=%str:~1%" if not "%str%"=="" goto pickup echo. goto :eof 　　版本二： @echo off :: 把半角双引号换成空格，把等号换成〓，兼容其他特殊字符 :: 能处理以分号打头的行，但是会忽略空行； :: 能兼容unicode格式的文本 :: 每行之间空一行显示 for /f "delims= eol=" %%i in ('type test.txt') do ( set "str=%%i" call set "str=%%str:"= %%" call :pickup ) pause goto :eof :pickup ping -n 1 127.1>nul if "%str:~0,1%"=="=" set "str=〓%str:~1%" set /p "var=%str:~0,1%"<nul set "str=%str:~1%" if defined str goto pickup echo.&echo. goto :eof 　　版本三： @echo off :: 与版本二的几点区别： ::　　 1、不能处理unicode文本 :: 　　2、每行之间不再强行加上空行，并且能原样显示空行 for /f "delims= eol=" %%i in ('findstr /n .* test.txt') do ( set "str=%%i" call set "str=%%str:"= %%" call set "str=%%str::=%%" call :pickup ) pause goto :eof :pickup if not defined str echo.&goto :eof ping -n 1 127.1>nul if "%str:~0,1%"=="=" set "str=〓%str:~1%" set /p "var=%str:~0,1%"<nul set "str=%str:~1%" if defined str goto pickup echo. goto :eof [ Last edited by namejm on 2007-2-2 at 01:42 PM* ]

第5楼　anqing	发表于 2007-02-02 23:10
高级用户　发帖 413　积分 859
版主的可行，这么显示，挺有意思的

第6楼　26933062	发表于 2007-02-03 02:07
银牌会员　发帖 879　积分 2,268
学习了谢谢版主!!!!!!!! 不过我还是没搞明白,我的为什么会停住,set /p 以后只要没了字符就停了, 还有你的 <nul 是什么意识?

第7楼　namejm	发表于 2007-02-03 02:53
荣誉版主　发帖 1,737　积分 5,226　来自成都
你的代码因为在goto top的时候，没有判断某一行的字符是否取尽，从而造成了死循环，所以会一直在处理第一行而不能处理下一行。　　<nul 在set/p中的作用是：在同一行上显示每次获取到的内容。

第8楼　minmin888	发表于 2007-05-08 10:22
初级用户　发帖 62　积分 127
学到东西! 多谢版主!