一个抛弃路径尾部指定层次的批处理 - 中国DOS联盟论坛

　　纯属无聊，发一个出来耍：


@echo off
:: 目的：
:: 　　抛弃路径尾部指定层次的字符串
:: 思路：
:: 　　先反序读取路径字符串，然后从头开始截去指定层次
:: 　　最后再反序读取剩余字符串

set num=0
set times=2
set "route=c:\a&bc\!dx\test dos\123.txt"
call :antitone "%route%"
call :intercept "%str%"
call :antitone "%route%"
echo "%str%"
pause
goto :eof

:antitone
set str=
set "var=%~1"
:loop1
if not "%var:~0,1%"=="" set "str=%str%%var:~-1%"
set "var=%var:~0,-1%"
if not "%var%"=="" goto loop1
goto :eof

:intercept
set "route=%~1"
:loop2
set "route=%route:*\=%"
set /a num+=1
if %num% lss %times% goto loop2
goto :eof

　　增加一个更加高效的代码：


@echo off
:: 思路：
::     通过for语句扩展，截取文件所在的目录路径
::　　 当要抛弃的层数超过实际层数时，保留根目录层次
set "route=c:\a&bc\!dx\test dos\123.txt\"
set layers_discard=3
if "%route:~-1%"=="\" set "route=%route:~0,-1%"
for /l %%i in (1,1,%layers_discard%) do call :intercept "%%route%%"
:end
echo "%route%"
pause
goto :eof

:intercept
for /f "delims=" %%i in (%1) do set "route=%%~dpi"
if "%route:~-2,1%"==":" (goto end) else set "route=%route:~0,-1%"
goto :eof

[ Last edited by namejm on 2007-1-19 at 03:04 PM ]

第1楼　namejm	发表于 2006-12-30 08:52
荣誉版主　发帖 1,737　积分 5,226　来自成都
一个抛弃路径尾部指定层次的批处理　　纯属无聊，发一个出来耍： @echo off :: 目的： :: 　　抛弃路径尾部指定层次的字符串 :: 思路： :: 　　先反序读取路径字符串，然后从头开始截去指定层次 :: 　　最后再反序读取剩余字符串 set num=0 set times=2 set "route=c:\a&bc\!dx\test dos\123.txt" call :antitone "%route%" call :intercept "%str%" call :antitone "%route%" echo "%str%" pause goto :eof :antitone set str= set "var=%~1" :loop1 if not "%var:~0,1%"=="" set "str=%str%%var:~-1%" set "var=%var:~0,-1%" if not "%var%"=="" goto loop1 goto :eof :intercept set "route=%~1" :loop2 set "route=%route:\=%" set /a num+=1 if %num% lss %times% goto loop2 goto :eof 　　增加一个更加高效的代码： @echo off :: 思路： :: 通过for语句扩展，截取文件所在的目录路径 ::　　当要抛弃的层数超过实际层数时，保留根目录层次 set "route=c:\a&bc\!dx\test dos\123.txt\" set layers_discard=3 if "%route:~-1%"=="\" set "route=%route:~0,-1%" for /l %%i in (1,1,%layers_discard%) do call :intercept "%%route%%" :end echo "%route%" pause goto :eof :intercept for /f "delims=" %%i in (%1) do set "route=%%~dpi" if "%route:~-2,1%"==":" (goto end) else set "route=%route:~0,-1%" goto :eof [ Last edited by namejm on 2007-1-19 at 03:04 PM* ]

第2楼　redtek	发表于 2006-12-30 09:34
金牌会员　发帖 1,147　积分 2,902
很有魅力的一段代码～～～狂顶＋珍藏学习～：）））

第3楼　hxuan999	发表于 2006-12-30 10:56
中级用户　发帖 161　积分 337
代码值得用功学习,顶下~

第4楼　electronixtar	发表于 2006-12-30 13:14
铂金会员　发帖 2,672　积分 7,493
学习

第5楼　qpmgljf	发表于 2007-01-06 05:35
初级用户　发帖 49　积分 125
很好.正需要.谢谢