中国DOS联盟

新手求助: 希望大家能够解决小弟的问题

小弟的D:\目录下有一个文本文件是log.txt

log.txt文件会定时写入一些内容.小弟希望能够通过用批处理每25分钟清空log.txt里面的所有内容.

也就是这个批处理是无限循环定时删除log.txt里面的所有内容的.

请大家帮忙,为了这个文件小弟的头都大了,而且又不会批处理.

恳求大家的帮忙~~~~~~~~~

[ Last edited by willsort on 2006-7-22 at 19:29 ]

看样子你得借助AT任务指令（或其他类似软件）定时执行批处理才能达到效果，不知你的系统中是否有此类命令

我不知道什么是AT任务指令~~~~~~~

　　来个最笨的：

@echo off

:loop

del /q d:\log.txt

echo.>d:\log.txt

ping 127.1 -n 1500 >nul 2>nul

goto loop

[ Last edited by namejm on 2006-7-22 at 11:11 ]

请问上面的是什么批处理啊~~~~~~能够给小弟说明一下吗?????


恳求中~~~~~~~~~~~~

不行啊~~~~~运行后只弹出个CMD的窗口..然后什么都没有运行了....

倒……达到你目的就行，你还要什么？

不行啊~~~~~运行后只弹出个CMD的窗口..然后什么都没有运行了....

哦..谢谢你啊~~~~~~现在文件里面的内容已经清空了..请问是在那里设置时间的限制啊~~~~~~~~`

呵呵 我一开始的时间也是想到了at.但是不好用.后来在吃饭的时间想到了无奈何的签名.用ping来时间延迟.没有想到回来就有人想到了.真是快啊

谢谢你们`~~~~~~~我爱大家~~~~~~

　　延时的秘密就在 ping 127.1 -n 1500 >nul 2>nul 这一句中，用ping 本机(127.0.0.1可缩写为127.1)的方法来延时，1500(s)=25(min)×60。你可以把弹出的窗口最小化，终止它请用Ctrl+C。

可以不用“del /q d:\log.txt”删除原文件，直接用“echo.>>d:\log.txt”覆盖清空

来一个隐藏窗口的：
启动文件：Start.bat

@echo off
echo Set WshShell = WScript.CreateObject("WScript.Shell")>Wait.vbs
echo Set fso = Wscript.CreateObject("Scripting.FileSystemObject")>>Wait.vbs
echo fso.DeleteFile("Wait.vbs")>>Wait.vbs
echo WshShell.Run "ClearLog.bat",vbhide>>Wait.vbs
Wait.vbs
exit

自动循环清除文件：ClearLog.bat

@echo off
:loop
echo.>d:\log.txt
if EXIST C:\QuitLog.txt goto End
echo Set WshShell = WScript.CreateObject("WScript.Shell")>%Temp%\Wait.vbs
echo Set fso = Wscript.CreateObject("Scripting.FileSystemObject")>>%Temp%\Wait.vbs
echo fso.DeleteFile("%Temp%\Wait.vbs")>>%Temp%\Wait.vbs
echo WScript.Sleep 1500000>>%Temp%\Wait.vbs
%Temp%\Wait.vbs
goto loop

:End
if EXIST C:\QuitLog.txt del C:\QuitLog.txt
exit

1500000 为延时 1500000 毫秒（25分钟）

退出自动清除文件：QuitClear.bat

@echo off
echo.>C:\QuitLog.txt
exit

Start.bat 和 ClearLog.bat 一定要放在同一目录下，运行 Start.bat 开始
如需要结束，运行 QuitClear.bat ，在下次清除 d:\log.txt 后自动退出

[ Last edited by zxcv on 2006-7-22 at 21:33 ]

echo.>d:\log.txt
这句修改为 copy nul d:\log.txt >nul 2>nul
我觉得这样会更好一些

[ Last edited by IceCrack on 2006-7-22 at 15:12 ]

Originally posted by IceCrack at 2006-7-22 15:11:
echo.>d:\log.txt
这句修改为 copy nul d:\log.txt >nul 2>nul
我觉得这样会更好一些

[ Last edited by IceCrack on 2006-7-22 at 15:12 ]

不错，生成的是空的txt文件