纯批处理版贪吃蛇 - 中国DOS联盟论坛 - 中国DOS联盟之联合DOS论坛

在bathome发的帖子：
http://bbs.bathome.cn/viewthread.php?tid=2038&extra=page%3D1&frombbs=1有待完善,直接打开open.bat
运行时直接打开open.bat
控制说明：wasd分别为方向，一开始是默认暂停(p)，按任意键开始游戏
当按p暂停的时候也是按任意键开始游戏的。

对思路进行了分析见23楼
----------------open.bat--------------


@echo off
start direction.bat
title made by 523066680
:action
setlocal enabledelayedexpansion
mode con cols=65 lines=35
for /l %%a in (1,1,60) do (set space= !space!)
for /l %%a in (1,1,30) do (set L%%a=%space%)
set /a line=15,col=29,i=0,long=9
:loop
 :::::::::::::::控制蛇长，判断是否建立食物部分
 if %i% lss %long% (set /a i+=1) else (set i=1)
 if defined cut%i% (
     if not defined dot (call :dot)
     !cut%i%:"=!
     set "L%a%=!L%a%:~0,%b%! !L%a%:~%c%!"
     set "%a%_%b%="
 )
    :::::::显示
    cls
    echo, %space: =_%__
    for /l %%a in (1,1,30) do echo,│!L%%a!│
    echo, %space: =-%--
    echo,- 分数:%fen%00 
    for /l %%a in (1,1,3) do (ping -n 1 127.0>nul)
 ::::::::::::::::读取数据，分析部分
 :typex
 set /p way=<x
 if %way%==r (endlocal &goto :action)
 if %way%==q (exit)
 if %way%==p (ping -n 2 127.0>nul&goto :loop)
 if %way%==w (set /a line-=1)
 if %way%==s (set /a line+=1)
 if %way%==a (set /a col-=1)
 if %way%==d (set /a col+=1)
    if defined %line%_%col% (goto :gameover)
    if %line% equ 31 (goto :gameover) 
    if %line% equ 0 (goto :gameover) 
    if %col% equ -1 (goto :gameover) 
    if %col% equ 60 (goto :gameover)
 :::::::::::::::设置部分,描点,记录点坐标。
 set /a C2=col+1
 set "L%line%=!L%line%:~0,%col%!*!L%line%:~%C2%!"
 set cut%i%="set /a a=%line%,b=%col%,c=%C2%"
 set "%line%_%col%=exist"
 if "%line%_%col%"=="%dotl%_%dotc%" (set /a long+=1,fen+=1 &set dot=)
goto :loop
  ::::::::::::建立食物O的调用部分
  :dot
  set /a dotl=%random%%%28+2,dotc=%random%%%58+1
  if defined %dotl%_%dotc% (goto :dot)
  set dot=%dotl%_%dotc%
  set /a dotc2=dotc+1
  set "L%dotl%=!L%dotl%:~0,%dotc%!O!L%dotl%:~%dotc2%!"
  goto :eof
:gameover
color 0a
ping -n 2 127.0>nul
cls
echo,game over 在控制台按q结束游戏,r再玩一次
ping -n 3 127.0>nul
echo,p>x
endlocal
goto :action

--------------------------direction.bat------------------


@echo off &mode con cols=35 lines=8
setlocal enabledelayedexpansion
echo,p>x
for %%a in (w a s d p q) do (set de%%a=defined)
set _w=s
set _s=w
set _a=d
set _d=a
set notequ=have
:a
cls
set /p input="w a s d q(退出) r(重来) p(暂停):"
if "%input%"=="q" (
  echo,q>x
  exit
)
if "%input%"=="r" (
  echo,r>x
)
if "%input%"=="%notequ%" (goto :a)
if not defined de%input% (goto :a)
set notequ=!_%input%!
echo %input%>x
goto :a

[ Last edited by 523066680 on 2009-1-10 at 11:22 ]

第1楼　523066680	发表于 2008-10-02 09:40
银牌会员　发帖 1,133　积分 2,362
[原创]纯批处理版贪吃蛇在bathome发的帖子： http://bbs.bathome.cn/viewthread.php?tid=2038&extra=page%3D1&frombbs=1有待完善,直接打开open.bat 运行时直接打开open.bat 控制说明：wasd分别为方向，一开始是默认暂停(p)，按任意键开始游戏当按p暂停的时候也是按任意键开始游戏的。对思路进行了分析见23楼 ----------------open.bat-------------- @echo off start direction.bat title made by 523066680 :action setlocal enabledelayedexpansion mode con cols=65 lines=35 for /l %%a in (1,1,60) do (set space= !space!) for /l %%a in (1,1,30) do (set L%%a=%space%) set /a line=15,col=29,i=0,long=9 :loop :::::::::::::::控制蛇长，判断是否建立食物部分 if %i% lss %long% (set /a i+=1) else (set i=1) if defined cut%i% ( if not defined dot (call :dot) !cut%i%:"=! set "L%a%=!L%a%:~0,%b%! !L%a%:~%c%!" set "%a%_%b%=" ) :::::::显示 cls echo, %space: =_%__ for /l %%a in (1,1,30) do echo,│!L%%a!│ echo, %space: =-%-- echo,- 分数:%fen%00 for /l %%a in (1,1,3) do (ping -n 1 127.0>nul) ::::::::::::::::读取数据，分析部分 :typex set /p way=<x if %way%==r (endlocal &goto :action) if %way%==q (exit) if %way%==p (ping -n 2 127.0>nul&goto :loop) if %way%==w (set /a line-=1) if %way%==s (set /a line+=1) if %way%==a (set /a col-=1) if %way%==d (set /a col+=1) if defined %line%_%col% (goto :gameover) if %line% equ 31 (goto :gameover) if %line% equ 0 (goto :gameover) if %col% equ -1 (goto :gameover) if %col% equ 60 (goto :gameover) :::::::::::::::设置部分,描点,记录点坐标。 set /a C2=col+1 set "L%line%=!L%line%:~0,%col%!!L%line%:~%C2%!" set cut%i%="set /a a=%line%,b=%col%,c=%C2%" set "%line%_%col%=exist" if "%line%_%col%"=="%dotl%_%dotc%" (set /a long+=1,fen+=1 &set dot=) goto :loop ::::::::::::建立食物O的调用部分 :dot set /a dotl=%random%%%28+2,dotc=%random%%%58+1 if defined %dotl%_%dotc% (goto :dot) set dot=%dotl%_%dotc% set /a dotc2=dotc+1 set "L%dotl%=!L%dotl%:~0,%dotc%!O!L%dotl%:~%dotc2%!" goto :eof :gameover color 0a ping -n 2 127.0>nul cls echo,game over 在控制台按q结束游戏,r再玩一次 ping -n 3 127.0>nul echo,p>x endlocal goto :action --------------------------direction.bat------------------ @echo off &mode con cols=35 lines=8 setlocal enabledelayedexpansion echo,p>x for %%a in (w a s d p q) do (set de%%a=defined) set _w=s set _s=w set _a=d set _d=a set notequ=have :a cls set /p input="w a s d q(退出) r(重来) p(暂停):" if "%input%"=="q" ( echo,q>x exit ) if "%input%"=="r" ( echo,r>x ) if "%input%"=="%notequ%" (goto :a) if not defined de%input% (goto :a) set notequ=!_%input%! echo %input%>x goto :a [ Last edited by 523066680 on 2009-1-10 at 11:22* ] 附件 GreedSnake.rar (1.46 KiB)

第2楼　BC	发表于 2008-10-02 09:43
中级用户　发帖 175　积分 338
SF.... 真强大，有点回到红白机的感觉了...一个控制台，一个演示，要是能将wasd做到通过键盘的上下左右来实时控制就好了. [ Last edited by BC on 2008-10-2 at 09:46 ]

第3楼　BC	发表于 2008-10-02 09:50
中级用户　发帖 175　积分 338
好像有点问题，如果初始化的时候食物在蛇的正明就会直接game over...

第4楼　slore	发表于 2008-10-02 11:31
铂金会员　发帖 2,478　积分 5,212
创意不错～ choice能识别字符麽？不能的话的那段DEBUG了

第5楼　luowei14	发表于 2008-10-02 16:16
初级用户　发帖 98　积分 193
嘿嘿..有意思..学习了

第6楼　40szb	发表于 2008-10-02 17:06
初级用户　发帖 21　积分 46　来自西安
强贴

第7楼　523066680	发表于 2008-10-03 12:35
银牌会员　发帖 1,133　积分 2,362
哈我再多十分就餐1000分了

第8楼　slore	发表于 2008-10-03 12:56
铂金会员　发帖 2,478　积分 5,212
高兴的……1000还早呢

第9楼　523066680	发表于 2008-10-03 13:01
银牌会员　发帖 1,133　积分 2,362
嘿嘿灌水不就可以拉哦对了 1楼的代码有更新。关于提出的问题暂时解决。控制速度部分查找这句 for /l %%a in (1,1,3) do (ping -n 1 127.0>nul)可自己调试速度 [ Last edited by 523066680 on 2008-10-3 at 13:26 ]

第10楼　chenall	发表于 2008-10-03 15:23
银牌会员　发帖 469　积分 1,276　来自福建泉州
用SET /P反应速度慢了些不好玩. 用choice玩起来更爽 @echo off &mode con cols=35 lines=8 setlocal enabledelayedexpansion echo,p>x for %%a in (w a s d p q) do (set de%%a=defined) set _w=s set _s=w set _a=d set _d=a set notequ=have :a cls choice /c wasdqr /n /m "w a s d q(退出) r(重来):" if errorlevel 1 set input=w if errorlevel 2 set input=a if errorlevel 3 set input=s if errorlevel 4 set input=d if errorlevel 5 set input=q if errorlevel 6 set input=r if "%input%"=="q" ( echo,q>x exit ) if "%input%"=="r" ( echo,q>x ping -n 2 127.0>nul echo,p>x call open.bat ) if "%input%"=="%notequ%" (goto :a) if not defined de%input% (goto :a) set notequ=!_%input%! echo %input%>x goto :a

第11楼　523066680	发表于 2008-10-07 17:24
银牌会员　发帖 1,133　积分 2,362
大哥顺便把choice发上来哈感谢您的支持

第12楼　HAT	发表于 2008-10-07 17:54
版主　发帖 5,017　积分 9,023
Re 11楼本版搜索choice.exe http://upload.cn-dos.net/img/454.zip

第13楼　toms	发表于 2008-10-09 23:53
新手上路　发帖 5　积分 10
..有意思..学习了

第14楼　succubus	发表于 2008-10-10 18:26
新手上路　发帖 1　积分 2
真有意思，学习了

第15楼　JamesYou	发表于 2008-10-10 18:53
初级用户　发帖 36　积分 52
为什么我一运行就是提示“r（从来）”？