中国DOS联盟

问题是这样的，有一个文本文件，里而的内容如下
/lib/AdaptiveMQ.jar
/lib/AdaptiveMQ.jar
/lib/FIX.jar
我怎么才能把它放到另外一个文件中，其内容为：
/lib/AdaptiveMQ.jar ;/lib/AdaptiveMQ.jar ;/lib/FIX.jar

这几天也在编一些批处理，学习了一些简单的

@echo off
setlocal EnableDelayedExpansion
set N=1
for /f %%a in (原文本.txt) do (set New!N!=%%a
set /a N=!N! + 1)

echo %New1% ;%New2% ;%New3%>新文本.txt

其中的 %New1%～%NewN% 根据行数增加递增

如果我不知道原文本有多少行呢？怎么做急用，谢了

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in (原文件.txt) do (
if not defined a (set a=%%a) else (set a=!a!;%%a)
)
echo %a%>生成文件.txt

可以确定的是，如果文件长度过于太大绝对不成，因为cmd中SET设置变量是有一定要求的，也请高人想想这个批处理怎么写.....................楼主可以试试上面的代码，如果不成就说明文件长度过大

好的谢谢了

测试完了告诉我一下结果

[ Last edited by bagpipe on 2006-7-19 at 15:07 ]

　　呵呵，bagpipe又出手了。

　　if not defined a (set a=%%a) else (set a=!a!;%%a)这句中的defined是什么意思？头一次看到这种用法，能不能把这条代码解释一下？

恩，搞定了，好久没用过dos了，都忘的差不多了，多谢 bagpipe的帮忙

Originally posted by namejm at 2006-7-19 15:05:
　　呵呵，bagpipe又出手了。

　　if not defined a (set a=%%a) else (set a=!a!;%%a)这句中的defined是什么意思？头一次看到这种用法，能不能把这条代码解释一䠮..

意思就是说. 如果没有定议 a 就 执行 set a=%%a
如果定议了就 执行 else 后的语句!

@echo off
setlocal EnableDelayedExpansion
set N=1
for /f "delims=" %%a in (原文件.txt) do (set New!N!=%%a
set /a N=!N! + 1)
set /a N=%N%-1

echo echo %%New1%%>Temp.bat
if %N% LEQ 1 goto End
set M=2

:len
for /f "delims=" %%a in (Temp.bat) do set X=%%a
echo %X% ;%%New%M%%%^>新文件.txt>Temp.bat
set /a M=%M%+1
if %M% GTR %N% goto End
goto len

:End
call Temp.bat
del Temp.bat

试过400行的没问题，500行就出错了，好像是for不下去了，根本未执行到Temp.bat，效率比bagpipe的差，不过SET设置变量没有bagpipe的大

[ Last edited by zxcv on 2006-7-19 at 18:54 ]

在批处理的实际应用中，建议不要使用太多的变量。
for /f "delims=" %i in (源文件.txt) do @set /p "var=%i;" <nul >>目标文件.txt
在命令提示符下运行。若要写到脚本中，更改%i为%%i。对于文本中出现引号的情况没有做出错处理。

还是3742668版主的厉害，我和bagpipe的500行就挂了，3742668版主的1200行还没问题

没想到SET /P还能够连续对接文本内容，自愧不如..............

@sed -e :a -e "N;$!ba;s/ *\n/ ;/g;s/*$//" test.txt

参考了无奈何斑竹的有关代码加以修改，3600行以上也可以。

[ Last edited by amao on 2007-2-3 at 02:58 PM ]