中国DOS联盟

请教各位朋友，我用以下命令在CMD下执行不能得到正确结果
set a="%windir%\System32\notepad.exe"="%windir%\System32\notepad.exe:*:Enabled:notepad.exe"&&set a=%a:\=\\%&&echo %a%

而分开执行就可以
set a="%windir%\System32\notepad.exe"="%windir%\System32\notepad.exe:*:Enabled:notepad.exe"
set a=%a:\=\\%
echo %a%

请问各位朋友，如何实现&&与%号混用，谢谢！

[ Last edited by hbby on 2009-12-11 at 14:21 ]

你的写法是对的，问题不是出在 && 和 % 号混用，而是变量的值，如果改成延迟变量就好了。
由于之前没有定义 a 的值，因此在你那长长的一行上等号右边的 %a% 的值都是空的，改成下面这样：

@echo off

setlocal enabledelayedexpansion

set a="%windir%\System32\notepad.exe"="%windir%\System32\notepad.exe:*:Enabled:notepad.exe" && set a=!a:\=\\! && echo !a!

pause>nul

感谢qinchun36朋友的帮助，我按照你的写法写成一行，在CMD下执行还是不行，望赐教，谢谢！因为我只需要一行的表达方式
setlocal enabledelayedexpansion&&set a="%windir%\System32\notepad.exe"="%windir%\System32\notepad.exe:*:Enabled:notepad.exe" && set a=!a:\=\\! && echo !a!

请问版主,能想个办法帮忙解决下吗?谢谢

如果要在开始----运行中运行,请直接使用:

cmd /q /v:on /e:on /k set a="%windir%\System32\notepad.exe"="%windir%\System32\notepad.exe:*:Enabled:notepad.exe"&&set a=!a:\=\\!&&echo !a!

/k
执行 string 指定的命令并继续。
/q
关闭回显。
/e:on
启用命令扩展。
/v:on
启用延迟的环境变量扩展。

特别说明:
1,/k参数在实际使用中,必须在其他开关的最后面.
2,在本例中,/q /e:on 两个参数不是必须的
3,运行对话框中一次所能接受的字符长度是有限的


至于你说的：

Originally posted by hbby at 2009-12-8 14:52:
感谢qinchun36朋友的帮助，我按照你的写法写成一行，在CMD下执行还是不行，望赐教，谢谢！因为我只需要一行的表达方式
setlocal enabledelayedexpansion&&set a="%windir%\System32\notepad.exe"="%windir%\System32\notepad.exe:*:Enabled:notepad.exe"&&set a=!a:\=\\!&&echo !a!

setlocal enabledelayedexpansion启用的变量延迟只有在本行命令执行完，即下一行命令开始时，才开始。所以setlocal enabledelayedexpansion&&后面连接的命令运行时，变量延迟依然没有被启用！

[ Last edited by Hanyeguxing on 2009-12-10 at 21:05 ]

问题解决了,谢谢大家的帮忙