多个弹珠同时跳动 - 中国DOS联盟论坛 - 中国DOS联盟之联合DOS论坛

@echo off&setlocal enabledelayedexpansion
mode con: cols=81 lines=30&color 1f
for /l %%i in (1 1 39) do set "spa=  !spa!"

::在这个变量定义弹珠个数
set curs=a1 a2 a3 a4 a5 a6 a7
::随机定位
for %%a in (%curs%) do (
	set /a %%as=1,%%ah=1
	set /a %%av=!random!%%40*2,%%ai=!random!%%30
)

:loop
(
for %%a in (%curs%) do (
	set/a %%ai+=%%as,%%av+=%%ah,#v=%%av+2
	for /f "tokens=1,2,3" %%b in ("!%%av! !#v! ec!%%ai!") do (
		if defined %%d (set ec!%%ai!=!%%d:~,%%b!●!%%d:~%%c!) else (set ec!%%ai!=!spa:~,%%b!●!spa:~%%c!)
	)
)
cls&for /l %%i in (0 1 28) do echo;!ec%%i!
set/p=!ec29!<nul
for %%a in (%curs%) do (
  set ec!%%ai!=
  if !%%av! geq 78 set %%ah=-2
  if !%%av! leq 0 set %%ah=2
  if !%%ai! leq 0 set %%as=1
  if !%%ai! geq 29 set %%as=-1
)
for /l %%i in (1 1 120) do ver>nul

goto :loop
)

[ Last edited by netbenton on 2009-6-1 at 09:52 ]

第1楼　netbenton	发表于 2009-06-01 10:51
银牌会员　发帖 752　积分 1,916　来自广西
[动画特效]多个弹珠同时跳动 @echo off&setlocal enabledelayedexpansion mode con: cols=81 lines=30&color 1f for /l %%i in (1 1 39) do set "spa= !spa!" ::在这个变量定义弹珠个数 set curs=a1 a2 a3 a4 a5 a6 a7 ::随机定位 for %%a in (%curs%) do ( set /a %%as=1,%%ah=1 set /a %%av=!random!%%402,%%ai=!random!%%30 ) :loop ( for %%a in (%curs%) do ( set/a %%ai+=%%as,%%av+=%%ah,#v=%%av+2 for /f "tokens=1,2,3" %%b in ("!%%av! !#v! ec!%%ai!") do ( if defined %%d (set ec!%%ai!=!%%d:~,%%b!●!%%d:~%%c!) else (set ec!%%ai!=!spa:~,%%b!●!spa:~%%c!) ) ) cls&for /l %%i in (0 1 28) do echo;!ec%%i! set/p=!ec29!<nul for %%a in (%curs%) do ( set ec!%%ai!= if !%%av! geq 78 set %%ah=-2 if !%%av! leq 0 set %%ah=2 if !%%ai! leq 0 set %%as=1 if !%%ai! geq 29 set %%as=-1 ) for /l %%i in (1 1 120) do ver>nul goto :loop ) [ Last edited by netbenton on 2009-6-1 at 09:52* ]

第2楼　kennyfan	发表于 2009-06-01 11:42
中级用户　发帖 112　积分 259
谢谢分享,又一新的特破!

第3楼　tianzizhi	发表于 2009-06-01 13:15
高级用户　发帖 214　积分 623
水平高，实在是高！

第4楼　rubble	发表于 2009-06-21 22:54
初级用户　发帖 15　积分 23
没有做不到，只有想不到！没有做不到，只有想不到！

第5楼　songkingman	发表于 2009-06-24 01:15
新手上路　发帖 6　积分 11
GOOD

第6楼　chenall	发表于 2009-06-24 04:02
银牌会员　发帖 469　积分 1,276　来自福建泉州
好强,这也行..

第7楼　moniuming	发表于 2009-06-24 08:37
银牌会员　发帖 574　积分 1,335　来自广西
太强悍了,加分!!!