文本为:
王一,2
王一,5
张二,4
张二,5
张二,8
刘三,2
求输出结果为：
王一,2 5
张二,4 5 8
刘三,2
[ Last edited by haiyuey on 2009-4-21 at 00:11 ]
王一,2
王一,5
张二,4
张二,5
张二,8
刘三,2
求输出结果为：
王一,2 5
张二,4 5 8
刘三,2
[ Last edited by haiyuey on 2009-4-21 at 00:11 ]
中国DOS联盟
联盟域名：www.cn-dos.net 论坛域名：www.cn-dos.net/forum
DOS，代表着自由开放与发展，我们努力起来，学习FreeDOS和Linux的自由开放与GNU精神，共同创造和发展美好的自由与GNU GPL世界吧！
中国DOS联盟论坛 » DOS批处理 & 脚本技术（批处理室） » 请教一个文本排列问题
查看 1,907 回复 15
楼 主
请教一个文本排列问题
发表于 2009-04-20 23:51 · 中国 江苏 泰州 电信
第 2 楼
发表于 2009-04-21 03:21 · 中国 江苏 泰州 电信
没人知道吗?
第 3 楼
发表于 2009-04-21 03:53
@echo off
setlocal ENABLEDELAYEDEXPANSION
if exist b.txt del b.txt
set m=""
for /f "tokens=1,2 delims=," %%i in (a.txt) do (
if /i not "%%i"=="!m!" (
>>b.txt echo %%i,%%j
set m=%%i
) else (
sed -i "s/^%%i.*/& %%j/" b.txt
sed -i "s/$/\r/" b.txt
set m=%%i
)
)
以上代码我测试是可以的,不过需要你系统里面有sed这个命令,论坛上很好找到的,4.07版本以上应该可以.
第 4 楼
发表于 2009-04-21 04:23 · 中国 江西 赣州 电信
@echo off&setlocal enabledelayedexpansion
set "file=a.txt"
set /p var=<"%file%"
set "var2=%var:*,=%" & set var=!var:,%var:*,=%=!
(for /f "usebackq skip=1 tokens=1,2 delims=," %%a in ("%file%") do (
if "%%a" neq "!var!" (
echo !var!,!var2!
set "var=%%a" & set var2=%%b
) else set var2=!var2! %%b
)
echo !var!,!var2!)>result.txt
start result.txt
本帖最近评分记录
（共 1 条）
点击查看详情
| 评分人 | 分数 | 时间 |
|---|---|---|
| freeants001 | +2 | 2009-04-21 07:29 |
第 5 楼
发表于 2009-04-21 04:29 · 中国 江苏 泰州 电信
三楼这个好像不行,数据换一个排列再执行就没用了!
[ Last edited by haiyuey on 2009-4-21 at 04:35 ]
[ Last edited by haiyuey on 2009-4-21 at 04:35 ]
第 6 楼
发表于 2009-04-21 04:34 · 中国 江苏 泰州 电信
三楼的不行,四楼的应该可以,先谢过,再试下
第 7 楼
发表于 2009-04-21 07:19 · 中国 浙江 温州 龙湾区 电信
名字是连着排列的吗？ 还是打乱的？
第 8 楼
发表于 2009-04-21 07:27 · 中国 广东 东莞 电信
不管是打乱，还是连着的都可以
[ Last edited by netbenton on 2009-4-21 at 05:29 ]
@echo off&setlocal enabledelayedexpansion
for /f "tokens=1,2 delims=, " %%a in (%~n0.txt) do (set "#%%a=!#%%a!%%b ")
for /f "tokens=1,2 delims==#" %%a in ('set #') do (echo %%a,%%b)
pause[ Last edited by netbenton on 2009-4-21 at 05:29 ]
网志
第 9 楼
发表于 2009-04-21 07:29 · 中国 湖北 黄石 电信
set "var2=%var:*,=%"中竟然可以使用通配符,感谢tireless的代码,学了一招,呵呵~~
第 10 楼
发表于 2009-04-21 08:09 · 中国 浙江 温州 龙湾区 电信
终于看懂了8楼老大的代码
set #用的很妙，能把#开头的变量都列出来，再用for 处理。
不知道 cmd最大可以支持多少个变量. 有数量限制吗？
set #用的很妙，能把#开头的变量都列出来，再用for 处理。
不知道 cmd最大可以支持多少个变量. 有数量限制吗？
第 11 楼
Re 10楼
发表于 2009-04-21 08:12 · 中国 江西 赣州 安远县 电信
http://technet.microsoft.com/en-us/library/bb490954.aspx
[ Last edited by tireless on 2009-4-21 at 08:14 ]
The maximum individual environment variable size is 8192bytes.
The maximum total environment variable size for all variables, which includes variable names and the equal sign, is 65,536KB.
[ Last edited by tireless on 2009-4-21 at 08:14 ]
第 12 楼
发表于 2009-04-21 22:16 · 中国 江西 吉安 电信
看了很长时间还是不怎么动下面这2句，还大大门帮忙解释下
set /p var=<"%file%"
这里的VAR=< 里面的这个“<”是转义符的意思吗
意思是把FILE的值附给 VAR吧，然后用SET /P做为输入吗
set "var2=%var:*,=%" & set var=!var:,%var:*,=%=!
"var2=%var:*,=%" 里面的“*和，”的意思是把所有字符和逗号转换成空吗
var=!var:,%var:*,=%=!这句是一个变量替换的嵌套吧
意思是把%var:*,=%替换的值再和， 替换成空吗。看了很多这方便的资料
在实际应用上就不知道怎么下手，不知道我理解的对吗，还请大大门指点，最好举个实例解释下，谢谢了~
set /p var=<"%file%"
这里的VAR=< 里面的这个“<”是转义符的意思吗
意思是把FILE的值附给 VAR吧，然后用SET /P做为输入吗
set "var2=%var:*,=%" & set var=!var:,%var:*,=%=!
"var2=%var:*,=%" 里面的“*和，”的意思是把所有字符和逗号转换成空吗
var=!var:,%var:*,=%=!这句是一个变量替换的嵌套吧
意思是把%var:*,=%替换的值再和， 替换成空吗。看了很多这方便的资料
在实际应用上就不知道怎么下手，不知道我理解的对吗，还请大大门指点，最好举个实例解释下，谢谢了~
第 13 楼
发表于 2009-04-21 22:43 · 中国 辽宁 本溪 联通
set fso=createobject("scripting.filesystemobject")
set file=fso.opentextfile("1.txt")
do while file.atendofstream<>true
n=file.readline:s=split(n,","):a=s(0):b=s(1)
if instr(sn,a)=0 then
n=vbcrlf &n:sn=a:sm=sm & n
else
sm=sm & " " &b
end if
loop
file.close
wsh.echo mid(sm,3)
第 14 楼
发表于 2009-04-22 00:17 · 中国 湖北 黄石 电信
fso=WScript.createobject("scripting.filesystemobject");
sss=fso.opentextfile("a.txt").readall();
re=/((?:\n|^)(+),+)\r\n((?:.*\r\n)*?)(?:\2,(+\r\n))/
while(re.test(sss))sss=sss.replace(re,"$1 $4$3");
fso.createtextfile("a_dest.txt",1,0).write(sss)
第 15 楼
Re 12楼
发表于 2009-04-22 00:40 · 中国 江西 赣州 电信
< 是重定向符号。
set /p var= 默认是从控制台（键盘）接受输入源，这句等同于 set /p var=<con。把 con 换成文件，就是把文件作为输入源了。而变量只允许一行字符，所以只有文件的第一行设为了 var 的值。
%var:*,=% 是把第一个 , 及前面所有字符替换为空。
只有这一种通配符用法，其他的如 %var:,*=%、%var:?,=% 都无效。
!var:,%var:*,=%=!
假设 var=王一,2
%var:*,=% 取得的值是 2，然后 !var:,2=! 取得的值是 王一。
[ Last edited by tireless on 2009-4-22 at 09:13 ]
set /p var= 默认是从控制台（键盘）接受输入源，这句等同于 set /p var=<con。把 con 换成文件，就是把文件作为输入源了。而变量只允许一行字符，所以只有文件的第一行设为了 var 的值。
%var:*,=% 是把第一个 , 及前面所有字符替换为空。
只有这一种通配符用法，其他的如 %var:,*=%、%var:?,=% 都无效。
!var:,%var:*,=%=!
假设 var=王一,2
%var:*,=% 取得的值是 2，然后 !var:,2=! 取得的值是 王一。
[ Last edited by tireless on 2009-4-22 at 09:13 ]
本帖最近评分记录
（共 1 条）
点击查看详情
| 评分人 | 分数 | 时间 |
|---|---|---|
| THENEWLIFE | +2 | 2009-04-22 02:34 |
论坛跳转: