中国DOS联盟

将D盘DATA下所有最近两天修改的文件，COPY到E盘一个以当天日期命名的目录中

已知:

1、新建一个以当前日期命名的目录
mkdir E:\%date:~0,10%

2、将D盘DATA下所有最近两天修改的文件COPY到新建的目录中

？？？？请教各位DOS高手，如何判断哪些文件是最近两天修改过的文件？？？

？？？？如何将这些文件COPY到新建的目录中？？？

[ Last edited by HAT on 2009-2-10 at 22:26 ]

datex 计算日期
直接用RAR 命令打包最省事

讲一下思路
1. dir /a /s /o-d "d:\data">>test.txt ::将data文件夹下面的文件及子文件夹信息全部保存到test.txt文件

2. findstr "[0-9]*\/[0-9]*\/[0-9]*" test.txt>>a.txt ::将带有日期格式的行存入a.txt文件

3. for /f "delims=" %%i in (a.txt) do (
for /f "tokens=4 delims= " %%j in ("%%i") do (
if "%%j" NEQ "<DIR>" echo %%i>>test1.txt
)
)
::这里就是将a.txt里面包含文件的行取出来，去除一些不是文件的或文件夹。

4. 在test1.txt里面取日期格式，**/**/****,然后调用比较日期的bat函数，这个好像函数库里面有。去查查吧。

Originally posted by yishanju at 2009-2-10 17:08:
datex 计算日期
直接用RAR 命令打包最省事

非常感谢2楼的热心朋友！谢谢！用RAR命令打包真的很省事，可是其中的目录好像打包不了，只能打包文件。

rar a -r -ta%date% %date% d:\


搞定了！

刚写好，贴子就结了。还是帖出来吧，留着没用

@echo off
::转存d:\data\前两修改的文件到e:\aa\今天日期为名的目录，
::如果目标目录不存在则自动新建。
set date=
set ms= 31 28 31 30 31 30 31 31 30 31 30 31
set/a d=1%date:~8,2%-102,m=1%date:~5,2%-100,y=%date:~0,4%
set/a vy=y%%4,vm=(m+10)%%12*3
if %vy%==0 set ms=%ms:28=29%
call set vm=%%ms:~%vm%,3%%
if %d% lss 1 set /a d=d+vm,m-=1
if %m% lss 1 set /a m=m+12,y-=1
if %m% lss 10 set m=0%m%
if %d% lss 10 set d=0%d%
set date-2=%y%-%m%-%d%
::上面取得前两天的日期
::bat 处理日期太麻烦了！涉及到月份不同，和闰年问题。

for %%a in (d:\data\*.*) do if %%~ta geq %date-2% xcopy /y %%a E:\aa\%date:~0,10%\