中国DOS联盟

实现以下功能：
在vista系统下如何实现下次启动进入DOS.
反之在dos下如何实现下次启动进入vista系统.

最好是使用 grub，将 grub 安装至 mbr，然后搞一个 menu.lst 就 OK了。

不过在windows vista 下装 光盘版dos 时不能更改mbr 否则 不能达到相互转化的目的 不知道为什么？

深山红叶的 Vista/Windows XP 引导模式切换程序
或2楼的方法：制作菜单－应是最佳方案

【摘自grub4dos教程】
1 grub4dos初级教程－入门篇

1.3 如何安装grub4dos？

1.3.4 通过Windows VISTA/Window 7的启动菜单进入grub4dos

用批处理自动把grub4dos装入Vista启动项（非MBR）。

把grub4dos装入Vista启动项，比装入MBR相对来说要安全。
【对于vista系统，不能通过fdisk /mbr来恢复mbr，这样会造成vista无法启动。】

关于手动把grub4dos装入Vista的启动项的方法，网上有一些介绍。比起winxp修改Boot.ini来，操作要麻烦不少。

主要就是操作过程中要产生一个ID号【如:b88a2da4-0a4e-11dc-813a-00e04c75ef59】,需要手动输入3次，实在是麻烦。

下面的批处理自动完成整个装入操作。

说明：
1，批处理与grldr.mbr在同一目录时，自动复制grldr.mbr文件到系统根目录，否则需自行复制。
2，启动项里添加上grub4dos项后，需把准备好的menu.lst和grldr文件复制到C:\下（也可放到其它分区根目录）。

-------------------------------
安装批处理

@echo off
rem by lianjiang
cls
echo.
echo 请以管理员身份运行。
echo.
pause
set gname=GRUB for DOS
set vid=
set timeout=5
bcdedit >bcdtemp.txt
type bcdtemp.txt | find "\grldr.mbr" >nul && echo. && echo BCD启动项中已有grub4dos的项目，无需再安装。&& pause && goto exit
bcdedit /export "Bcd_Backup" >nul
bcdedit /create /d "%gname%" /application bootsector >vid.ini
for,/f,"tokens=2 delims={",%%i,In (vid.ini) Do (
set vida=%%i
)
for,/f,"tokens=1 delims=}",%%i,In ("%vida%") Do (
set vid={%%i}
)
echo %vid%>vid.ini
bcdedit /set %vid% device partition=%systemdrive% >nul
bcdedit /set %vid% path \grldr.mbr >nul
bcdedit /displayorder %vid% /addlast >nul
bcdedit /timeout %timeout% >nul
if exist grldr.mbr copy grldr.mbr %systemdrive%\ /y && goto exit
echo.
echo 稍后请自行把grldr.mbr拷贝到%systemdrive%\根目录
echo.
pause
:exit
del bcdtemp.txt >nul

-------------------------------

卸载批处理

@echo off
rem by lianjiang
cls
echo.
echo 要求存在用安装批处理安装时自动保存的临时文件。
echo.
echo 请以管理员身份运行。
echo.
pause
set vid=
set timeout=5
if exist Bcd_Backup bcdedit /import "Bcd_Backup" >nul&& goto 1

if not exist vid.ini (
echo.
echo 因相关文件被删，不能自动删除启动项项目，只能手动删除。
echo.
pause
goto exit
)

for,/f,"tokens=1",%%i,In (vid.ini) Do (
set vid=%%i
)
bcdedit /delete %vid% /cleanup >nul
bcdedit /timeout %timeout% >nul
:1
del vid.ini >nul
if exist %systemdrive%\grldr.mbr (
attrib -h -s -r %systemdrive%\grldr.mbr >nul
del %systemdrive%\grldr.mbr >nul
)

:exit
-------------------------------

dos与vista双系统怎样利用ghost制作image~~

本人利用grub 装的双系统
请问如何快速的制作image 保证可用
谢谢！

没看明白什么意思。

谢谢 大家 学习了不少！~·

通过对ghost得研究 现在已经实现功能！~
通过如下批处理实现:Ghost-clone,mode={copy│load│dump},src={drive│file│drive:partition},dst={dri-ve│file│drive:partition}/fro/fx/rb/f32/Z(n)/sure

5楼的同志 很厉害 顶下