中国DOS联盟

例如已经获取某文件的扩展名为 rar ，如何取得关联程序所在路径（例如：C:\Program Files\WinRAR\WinRAR.exe）？请指教。


根据楼下介绍方法已解决，多谢指点。解决后的代码如下：

@echo off

if "%1"=="" echo 请把文件或文件夹拖到我身上，便可创建快捷方式到桌面上。&&pause>nul&&exit

set "a=%1"

set "name=%~n$a:1%"

set "ext=%~x$a:1%"

if "%ext%"=="" goto FOLDER



for /f "tokens=2 delims==" %%b in ('assoc %ext%') do (

  for /f "tokens=2 delims==" %%c in ('ftype %%b') do set "d=%%c"

)

set "d=%d:"=%"

set "n=%d%"

set "n=%n:~-1%"

if "%n%"=="*" (set "d=%d:~0,-5%") else (set "d=%d:~0,-2%")

set "e=0"



if /i "%ext%"==".vbs" set "e=2"

if /i "%ext%"==".js" set "e=3"

if /i "%ext%"==".doc" set "d=%d:~0,-5%" && set "e=1"

if /i "%ext%"==".xls" set "e=1"

if /i "%ext%"==".ppt" set "e=1"

if /i "%ext%"==".bat" set "d=%SystemRoot%\system32\SHELL32.dll" && set "e=71"

if /i "%ext%"==".cmd" set "d=%SystemRoot%\system32\SHELL32.dll" && set "e=71"



:URL

echo  >"%userprofile%\桌面\%name%.url"

echo URL="%a%" >>"%userprofile%\桌面\%name%.url"

echo IconIndex=%e% >>"%userprofile%\桌面\%name%.url"

echo IconFile=%d% >>"%userprofile%\桌面\%name%.url"

exit



:FOLDER

set "d=%SystemRoot%\system32\SHELL32.dll"

dir /a:d "%a%"|find.exe "DIR" >nul

if not errorlevel 1 (set "e=3") else (set "e=0")

goto URL

[ Last edited by newxso on 2008-12-3 at 00:39 ]

@echo off
for /f "tokens=2 delims==" %%a in ('assoc .rar') do (
ftype %%a
)
pause