中国DOS联盟

当n=A时，{1010}，包含数字1的个数为2；
当n=B时，{1011}，包含数字1的个数为3；
当n=C时，{1100}，包含数字1的个数为2；
当n=F时，{1111}，包含数字1的个数为4；
当n=3B9AC9FF时，{1...1}，包含数字1的个数为多少呢？

请给出速度最快的解。

3B9AC9FF时是21
嗯，貌似即使用batch能处理的最大整数0x7FFFFFFF也能在瞬间搞定，比它快也貌似没有意义了-_-

@echo off

set /a rd=0x7FFFFFFF



:loop

set /a "rd1=rd%%2"

set /a "rd=rd/2"

if %rd1% equ 1 set /a n+=1

if %rd% neq 0 goto :loop



echo %n%

pause

[ Last edited by dikex on 2008-11-13 at 02:22 ]

哈哈，有空无事计算100次，得出计算100次平均用时是2.625s，也就是计算1次之用0.02625s
机子配置不同可能有差距

@echo off

echo %time%

:aa

call :cc

set /a c+=1

if %c% lss 100 goto :aa

echo %time%

pause



:cc

set /a rd=0x7FFFFFFF

set n=0

:loop

set /a "rd1=rd%%2"

set /a "rd=rd/2"

if %rd1% equ 1 set /a n+=1

if %rd% neq 0 goto :loop

goto :EOF

这个方法在我的电脑上单次运行需要9毫秒左右
我有另外一个方案可以在1毫秒内给出结果
纯粹是为了好玩
呵呵

洗澡时想到的算法^_^
比那个稍快

@echo off

echo %time%

:aa

call :cc

set /a c+=1

if %c% lss 100 goto :aa

echo %time%

pause



:cc

set /a a=0x7FFFFFFF

set n=0

set b=0

:loop

set /a "b+=(a>>%n%)&1"

set /a n+=1

if %n% lss 31 goto :loop

rem echo %b%

goto :EOF

这样？

Set /P "str=INPUT:"

Set /A "str=(str&0x55555555)+(str>>1&0x55555555)"

Set /A "str=(str&0x33333333)+(str>>2&0x33333333)"

Set /A "str=(str&0x0F0F0F0F)+(str>>4&0x0F0F0F0F)"

Set /A "str=(str&0x00FF00FF)+(str>>8&0x00FF00FF)"

Set /A "str=(str&0x0000FFFF)+(str>>16&0x0000FFFF)"

echo %str%

pause

[ Last edited by everest79 on 2008-11-15 at 01:26 ]

@echo off

set hex=3B9AC9FF

set bin=%bin:3=11%

set bin=%bin:5=11%

set bin=%bin:6=11%

set bin=%bin:7=111%

set bin=%bin:9=11%

set bin=%bin:A=11%

set bin=%bin:B=111%

set bin=%bin:C=11%

set bin=%bin:D=111%

set bin=%bin:E=111%

set bin=%bin:F=1111%

set numOne=%bin:0=%

set "length=31"

:loop

set "numOne=%numOne%#"

set /a length-=1

if "%numOne:~30,1%" neq "#" goto :loop

echo %length%

pause

[ Last edited by HAT on 2008-11-22 at 02:58 ]

这样可行否？

@echo off&setlocal enabledelayedexpansion

    set 1=1&set 2=1&set 3=2&set 4=1&set 5=2&set 6=2&set 7=3&set 8=1

    set 9=2&set a=2&set b=3&set c=2&set d=3&set e=3&set f=4

    set hex=7FFFFFFF

:lp

    if defined hex (

    set/a n+=!%hex:~,1%!

    set hex=%hex:~1%

    goto lp

)

echo.%n%

pause

@echo off
set /a num=0x12345678

:loop
set /a n=num%%2,num=num/2
set /a _%n%+=1
if %num% gtr 0 goto :loop

echo 有%_0%个0
echo 有%_1%个1
pause

[ Last edited by netbenton on 2009-2-27 at 07:18 ]