中国DOS联盟

请问 vtmagic -m9 汉字中缝参数有何意义，没有中缝不是更好看吗，是否是不利于液晶屏的显示？

因为有些显卡或显示器（CRT/LCD）频宽不够，不能显示没有中缝的模式。

Originally posted by 本是 at 2008-9-30 11:23 PM:
因为有些显卡或显示器（CRT/LCD）频宽不够，不能显示没有中缝的模式。

那么再请问弄潮儿的 vtedit (window 中使用)转换文本后，得到一个 .exe 和 .bat 文件，纯 DOS 下先运行 .exe 加载字模，再运行 .bat 会不会出现"因为有些显卡或显示器（CRT/LCD）频宽不够，不能显示没有中缝的模式。"(因为一个图形界面，没有参数供参考的)

再请问:
vtmagic -m9 -c2 -r0 /P 汉字字符串
vtmagic -m9 -c2 -r0 /T 文本文件
的方式显示文本是否比较通用，我将大面积的应用于 GHOST 网克中的动态中文批处理了，因此先请教一下通用的参数。
因为大写的 /P 和 /T 不会产生中间文件 .new 和 .exe ，通常是否可用在某些不能写操作的 A: 盘中(我是指某些非标准 .img 镜像)。

“弄潮儿的 vtedit (window 中使用)”是针对我的以前版本做的编辑环境，与现在的版本不兼容，它的.EXE文件有空间浪费所以体积大些。

转换后纯 DOS 下先运行 .exe 加载字模，再运行 .bat 同样会出现"因为有些显卡或显示器（CRT/LCD）频宽不够，不能显示没有中缝的模式。" 因为这个毛病是硬件的胎里病，软件没有办法解决。这也是VT显示技术的软肋！

再请问:
vtmagic -m9 -c2 -r0 /P 汉字字符串——这是显示命令行字符的
vtmagic -m9 -c2 -r0 /T 文本文件 ——这是显示文本文件里的字符的
不会产生中间文件 .new 和 .exe ，可以用在某些不能写操作的 A: 盘中(我是指某些非标准 .img 镜像)。 但是，只要是通过软件显示汉字，都离不开汉字库！否则巧妇难为无米之炊！！！

经过本是一解释，一方面感觉上次我那个"简体中文 MS-DOS 7.10 加强版"中使用 vtedit 有点上当了。我的终结者一键 GHOST 中的网克部分当退出汉字系统时显示中文的部分就就要全靠 VTMAGIC 了，是为了避免某些加载某些网卡(.DOS的和安装协议)与 CCDOS 招惹一些不必要的麻烦而准备的，感谢您的奉献。不过还是要确定一下下面进行中间调用的批处理 vtm.bat 中的 vtmagic 参数是否是最通用的:

@echo off
if "%1"=="" goto help
if "%1"=="/?" goto help
if "%1"=="/w" goto wbat
if "%1"=="/W" goto wbat
mem /c|find /i "ccdos">nul
if errorlevel 1 goto vtm
for %%a in (p P t T) do if "/%%a"=="%1" goto ccok
echo 错误的参数 %1
goto out

:ccok
for %%a in (p P) do if "/%%a"=="%1" goto cc_echo
if "%2"=="" goto out
if "%3"=="" type %2
if "%3"=="" goto out
type %2>%3
goto out

:cc_echo
echo %2 %3 %4 %5 %6 %7 %8 %9
goto out

:vtm
set _str=
set vtm_str=%1
if "%vtm_str%"=="/t" set vtm_str=/T
if "%vtm_str%"=="/p" set vtm_str=/P
for %%a in (T P) do if "/%%a"=="%vtm_str%" goto vtmok
call vtm.bat /P 错误的参数 %1
goto exit

:vtmok
if "%vtm_str%"=="/P" goto loop
shift
if "%1"=="" goto exit
set _str=%1
set vtm_str=%vtm_str% %_str%
shift
if "%1"=="" goto vtm_show
set _str=%1
goto vtm_t

:loop
shift
set _str=%1
if "%_str%"=="" goto vtm_show
set vtm_str=%vtm_str% %_str%
goto loop

:vtm_show
call vtmagic.com -m9 -c2 -r0 %vtm_str%
echo.
goto exit

:vtm_t
if "%vtm_str%"=="" goto exit
call vtmagic.com -m9 -c2 -r0 %vtm_str%>%_str%
goto exit

:wbat
if "%2"=="" goto exit
echo @echo off>%temp%\_vtm_$.txt
echo set result=%2 %3 %4 %5 %6 %7 %8 %9>>%temp%\_vtm_$.txt
call vtm /t %temp%\_vtm_$.txt %temp%\_vtm_$.bat
call %temp%\_vtm_$.bat
del %temp%\_vtm_$.txt>NUL
del %temp%\_vtm_$.bat>NUL
goto exit

:help
echo 使 DOS 下有无汉字系统都能显示汉字 制作:王小云。>%temp%\_tmp.txt
echo.>>%temp%\_tmp.txt
echo 用法: vtm /p 汉字字符串>>%temp%\_tmp.txt
echo vtm /t 汉字的文本 >>%temp%\_tmp.txt
echo vtm /w 汉字字符串 表示将赋值到环境变量 result 中>>%temp%\_tmp.txt
echo.>>%temp%\_tmp.txt
echo 主程序 vtmagic.com 由本是罗明安大师开发，感谢。>>%temp%\_tmp.txt
echo 运行 vtmagic 获得帮助。>>%temp%\_tmp.txt
call vtm.bat /T %temp%\_tmp.txt
del %temp%\_tmp.txt>NUL

:exit
set _str=
set vtm_str=

:out

[ Last edited by xiaoyunwang on 2008-10-2 at 15:08 ]