中国DOS联盟

我写的脚本在运行过程中报无效的过程或参数错误，出错信息如图

脚本如下：
'获取日期
dtmThisDay = Day(Date)
dtmThisMonth = Month(Date)
dtmThisYear = Year(Date)
tmToday = dtmThisMonth & "/" & dtmThisDay & "/" & dtmThisYear
Logfile = dtmThisYear & "年" & dtmThisMonth & "月"


'设置日期
Const CONVERT_TO_LOCAL_TIME = True
Set dtmStartDate = CreateObject("WbemScripting.SWbemDateTime")
Set dtmEndDate = CreateObject("WbemScripting.SWbemDateTime")
DateToCheck = CDate(tmToday)
dtmStartDate.SetVarDate DateToCheck, CONVERT_TO_LOCAL_TIME

'查询日志
strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
& "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colLoggedEvents = objWMIService.ExecQuery _
("Select * from Win32_NTLogEvent Where Logfile = 'system' AND EventCode = 10 AND SourceName = 'print' AND TimeWritten < '"& dtmStartDate & "'")


'写文本文件
Const ForAppending = 8
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile _
("E:\files\PrintLog\" & Logfile & ".txt", ForAppending, True)
For Each objService in colLoggedEvents
objTextFile.WriteLine(objService.ComputerName & vbTab & objService.Message & vbTab & objService.RecordNumber & vbTab & Mid(objService.TimeWritten,1,4) & "/" & Mid(objService.TimeWritten,5,2) & "/" & Mid(objService.TimeWritten,7,2) & vbTab & Mid(objService.TimeWritten,9,2) & ":" & Mid(objService.TimeWritten,11,2) & ":" & Mid(objService.TimeWritten,13,2) & vbTab & objService.User)
Next
objTextFile.Close

tmToday = dtmThisMonth & "/" & dtmThisDay & "/" & dtmThisYear
Logfile = dtmThisYear & "年" & dtmThisMonth & "月"

“/”怎能做文件名？

tmToday是放今天的日期的变量

问题应该出在这条打印记录上：

user1 拥有的文档 218, Microsoft Word - C2O4•2H2O 已通过 HP5200 端口在 HP LaserJet 5200 PCL 6 打印。字节大小: 96459, 打印页数: 1





其中“C2O4•2H2O ” 有很奇怪的字条，请问怎么用VBS处理？

好像有一些似似于全角的字符就会出错，怎么解决？

问题发现，日志里用Unicode 格式的，而VBS输出是ANSI格式的，请问怎么让VBS输出Unicode格式？

chrw试下看.

object.OpenTextFile(filename]])

format
可选项。使用三态值中的一个来指明打开文件的格式。如果忽略，那么文件将以 ASCII 格式打开。format 参数可以是下列设置中的任一种：
TristateTrue -1 True 以 Unicode 格式打开文件。
TristateFalse 0 False 以 ASCII 格式打开文件。
TristateUseDefault -2 使用计算机区域设置中的设置。 使用系统默认值打开文件。

2楼没看清，以为Logfile中包含tmToday

谢谢
Set objTextFile = objFSO.OpenTextFile _
("E:\files\PrintLog\" & Logfile & ".txt", ForAppending, True, -1)