中国DOS联盟

@echo off
for /f %%c in (aa.txt) do (
set b=%%c
echo %b%
)
pause

aa.txt 内容:
aaldk
fff
ss
flk



为什么输出结果是 echo 关闭状态
我也试过 echo %%b等，都没有用啊。。。谁能告诉我啊。

[ Last edited by ccily2701 on 2008-8-22 at 12:07 PM ]

变量延迟
@echo off
for %%c in (aa.txt) do (
set b=%%c
call echo %%b%%
)
pause

很感谢你。。。我试过了。。可以。。
不过少了一个/f的参数

能不能请问一下为什么什么出现这种情况，什么变量延时？

[ Last edited by ccily2701 on 2008-8-15 at 01:43 PM ]

set /?

set LIST=
for %i in (*) do set LIST=%LIST% %i
echo %LIST%

原因是，它不会在目前的目录中建立一个文件列表，而只是将
LIST 变量设成找到的最后一个文件。这也是因为 %LIST% 在
FOR 语句被读取时，只被扩充了一次；而且，那时的 LIST 变量
是空的。因此，我们真正执行的 FOR 循环是:

for %i in (*) do set LIST= %i

这个循环继续将 LIST 设成找到的最后一个文件。

延迟环境变量扩充允许您使用一个不同的字符(惊叹号)在执行
时间扩充环境变量。如果延迟的变量扩充被启用，可以将上面
例子写成以下所示，以达到预期效果:

set VAR=before
if "%VAR%" == "before" (
set VAR=after
if "!VAR!" == "after" @echo If you see this, it worked
)

set LIST=
for %i in (*) do set LIST=!LIST! %i
echo %LIST%

[ Last edited by moniuming on 2008-8-15 at 02:23 PM ]

for 少了/f的参数

@echo off setlocal enabledelayedexpansion for /f %%c in (aa.txt) do ( set b=%%c echo !b! ) pause
变量延迟详解
http://www.cn-dos.net/forum/viewthread.php?tid=28273&fpage=5

什么情况下该使用变量延迟?
http://www.cn-dos.net/forum/viewthread.php?tid=20733&fpage=6

@echo off for /f "delims=" %%c in ('type a.bat') do ( set "b=%%c" call echo %%b%% ) pause
@echo off&setlocal enabledelayedexpansion for /f "delims=" %%c in ('type a.bat') do ( set "b=%%c" echo !b! ) pause

谢谢大家的热心帮忙