中国DOS联盟论坛

中国DOS联盟

-- 联合DOS 推动DOS 发展DOS --
联盟域名：www.cn-dos.net　论坛域名：www.cn-dos.net/forum
游客 | 登录 | 注册 | 会员 | 搜索 | 中国DOS联盟
中国DOS联盟论坛
现在时间是 2026-08-09 09:11 		共 47,811 主题排行 / 349,895 发帖 / 今日 0 篇 / 48,253 会员排行
DOS批处理 & 脚本技术（批处理室） » 这个批处理错在哪里了？
可打印版本 　679 / 5
第1楼　shayulei 发表于 2008-08-07 15:55
中级用户　发帖 74　积分 301
这个批处理错在哪里了？
@echo on
for /f "Tokens=1-3" %%i in ('diskpart /s z:\diskpart\Testc.txt ^| find "*" ') do set /a SystemPart=%%k
if %SystemPart% gtr 0 (
if %systemPart% lss 20 (
::生成boot.ini
echo [boot loader] > d:\boot.ini
echo timeout=30 >> d:\boot.ini
echo default=multi(0)disk(0)rdisk(0)partition(%SystemPart%)\WINDOWS >> d:\boot.ini
echo [operating systems] >> d:\boot.ini
echo multi(0)disk(0)rdisk(0)partition(%systemPart%)\WINDOWS="Microsoft Windows XP Professional" /noexecute=optin /fastdetect /detecthal >> d:\boot.ini
::生成bootxp.ini
echo [boot loader] > d:\bootxp.ini
echo timeout=30 >> d:\bootxp.ini
echo default=multi(0)disk(0)rdisk(0)partition(%SystemPart%)\WINDOWS >> d:\bootxp.ini
echo [operating systems] >> d:\bootxp.ini
echo multi(0)disk(0)rdisk(0)partition(%systemPart%)\WINDOWS="Microsoft Windows XP Professional" /noexecute=optin /fastdetect >> d:\bootxp.ini
)else (echo 测试系统盘出错，请手处理boot.ini & goto :EOF)
)
:end

运行到echo default=multi(0)disk(0)rdisk(0)partition(%SystemPart%)\WINDOWS >> d:\boot.ini
就报 “不应有disk(0“
是什么意思，如果我把IF去掉，这个批处理就没有问题。
第2楼　knoppix7 发表于 2008-08-07 15:56
银牌会员　发帖 634　积分 1,287　来自 cmd.exe
括号内注释不能用::
要用REM
第3楼　shayulei 发表于 2008-08-07 16:00
中级用户　发帖 74　积分 301
神奇啊，我双击运行这个批处理就不会报错，我在命令行窗口中运行，他就报错，怎么回事？
第4楼　HAT 发表于 2008-08-07 16:02
版主　发帖 5,017　积分 9,023
你在最后添加一行
pause
双击运行也不报错？
第5楼　shayulei 发表于 2008-08-07 16:10
中级用户　发帖 74　积分 301
我把注释删了，还是报错
Z:\>createboot

Z:\>for /F "Tokens=1-3" %i in ('diskpart /s z:\diskpart\Testc.txt | find "*" ')
do set /a SystemPart=%k

Z:\>set /a SystemPart=1
此时不应有 disk(0。

Z:\> echo default=multi(0)disk(0)rdisk(0)partition(1)\WINDOWS >> d:\b
oot.ini

Z:\>
第6楼　shayulei 发表于 2008-08-07 16:20
中级用户　发帖 74　积分 301
是（）的问题，现在改成这样了
@echo off

attrib -h -s -r c:\boot.ini
attrib -h -s -r c:\bootxp.ini

for /f "Tokens=1-3" %%i in ('diskpart /s z:\diskpart\Testc.txt ^| find "*" ') do set /a SystemPart=%%k
if %SystemPart% LSS 1 GOTO error
if %systemPart% GTR 10 goto error

::生成boot.ini
echo [boot loader] > d:\boot.ini
echo timeout=30 >> d:\boot.ini
echo default=multi(0)disk(0)rdisk(0)partition(%SystemPart%)\WINDOWS >> d:\boot.ini
echo [operating systems] >> d:\boot.ini
echo multi(0)disk(0)rdisk(0)partition(%systemPart%)\WINDOWS="Microsoft Windows XP Professional" /noexecute=optin /fastdetect /detecthal >> d:\boot.ini

::生成bootxp.ini
echo [boot loader] > d:\bootxp.ini
echo timeout=30 >> d:\bootxp.ini
echo default=multi(0)disk(0)rdisk(0)partition(%SystemPart%)\WINDOWS >> d:\bootxp.ini
echo [operating systems] >> d:\bootxp.ini
echo multi(0)disk(0)rdisk(0)partition(%systemPart%)\WINDOWS="Microsoft Windows XP Professional" /noexecute=optin /fastdetect >> d:\bootxp.ini

goto :EOF
:error
echo 测试系统盘出错，请手处理boot.ini & goto :EOF

:end
[ 联系联盟系统管理团队 - 中国DOS联盟 - 标准版 ]
Sponsored by ifanr Inc | © 2001–2023