中国DOS联盟

@echo off

set code=0123456789abcdef

:enter

cls&set /p num=请输入一个十进制数字：

echo %num%|findstr ""&&goto enter

set var=%num%

:again

set /a ws=%var%%%16

call,set ws=%%code:~%ws%,1%%

set /a var/=16

set str=%ws%%str%

if %var% geq 16 goto again

cls&echo 十进制数%num%转换为16进制数为：%var%%str%

pause>nul

@echo off

rem 最大处理数字是2147483647

setlocal ENABLEDELAYEDEXPANSION

set /p num=num?

set str=0123456789ABCDEF

call :A %num%

echo %T3%

echo %num%

pause

exit



:A

set T1=%1

SET T3=

:B

set/A T2=T1%%16

SET T2=!str:~%t2%,1!

SET/A T1=%T1%/16

SET T3=%T2%%T3%

IF %T1%==0 GOTO :EOF

GOTO B

Originally posted by zw19750516 at 2008-7-5 01:19 PM:

@echo off

set code=0123456789abcdef

:enter

cls&set /p num=请输入一个十进制数字：

echo %num%|findstr ""&&goto enter

set var=%num%

:again

set /a  ... 

@echo off

set code=1 2 3 4 5 6 7 8 9 a b c d e f&set m=1

set /p str=请输入16进制数字：

:lp

set a=%str:~-1%

for %%i in (%code%) do set /a n+=1&if "%%i" equ "%a%" call,set a=%%n%%

set /a num+=m*a

set /a m*=16,n=0

if defined str set str=%str:~,-1%&goto lp

echo %num%&pause>nul

@echo off

set /p b=请输入16进制数字：

set /a a=0x%b%

echo %a%

pause

Originally posted by 26933062 at 2008-7-5 14:42:
16进制转10进制：有更简单的方法。

@echo off

set /p b=请输入16进制数字：

set /a a=0x%b%

echo %a%

pause

Originally posted by terse at 2008-7-6 05:02 PM:
好象以前发过一个
加个变量 就可以实现十进制转任意进制

@echo off&setlocal enabledelayedexpansion

set/p a=请输入要转换的十进制数:

set aa=%a%

set/p b=请输入要转换的几进制?

set str=0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ

:hex

    set/a m=!a!/!b!

    set/a n=!a!%%!b!

    set n=!str:~%n%,1!

    set h=!n!!h!

    if !m! geq !b! set a=!m! &goto hex

    set m=!str:~%m%,1!

    echo !aa!的!b!进制数 !m!!h!

printf "%x" "10"