中国DOS联盟

『楼 主』:

@echo off&setlocal enabledelayedexpansion

:1

set/p var=输入小写字母，多个字母用空格隔开：

if not defined var goto 1

for %%a in (%var%) do echo abc>"%%a a.tmp_"

for /f "delims=" %%a in ('dir/b *.tmp') do (

set name=%%~sna

set nam=!nam!!name:~,1! 

)

echo.&echo %nam%

del *.tmp_

pause>nul

此帖被 +3 点积分     点击查看详情    评分人：【 bat-zw 】 分数： +3  时间：2008-6-28 11:12

@echo off

set str=157924680

for %%a in ("0=零" "1=一" "2=二" "3=三" "4=四" "5=五" "6=六" "7=七" "8=八" "9=九") do call set str=%%str:%%~a%%

echo %str%



set str=abcdehijkl

for %%a in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do call set str=%%str:%%a=%%a%%

echo %str%

Originally posted by pusofalse at 2008-6-28 07:41:
思路，for %~sa增强扩展。。。

@echo off&setlocal enabledelayedexpansion

:1

set/p var=输入小写字母，多个字母用空格隔开：

if not defined var goto 1

for %%a  ... 

@echo off

:1

set/p var=输入小写字母，多个字母用空格隔开：

if not defined var goto 1

for %%a in (%var%) do echo.>"%%a .nul"

for /f "delims=" %%a in ('dir /b *.nul') do set str=%%~sna&call,set /p=%%str:~,1%% <nul

pause>nul&del /q *.nul

@echo off&setlocal enabledelayedexpansion

set "code=aA bB cC dD eE fF gG hH iI jJ kK lL mM nN oO pP qQ rR sS tT uU vV wW xX yY zZ"

:begin

set/p var=输入小写字母，多个字母用空格隔开：

if not defined var goto begin

for %%a in (%var%) do ( 

    for %%i in (%code%) do (

        set str=%%i

        if "!str:~,1!" equ "%%a" set /p=!str:~1! <nul

    )

)

pause>nul