set string=aferefwfwerergrgreaaffwafwa
用bat怎么检查以上字符串中字符a出现的次数（可不能用字符截取功能）
用bat怎么检查以上字符串中字符a出现的次数（可不能用字符截取功能）
中国DOS联盟
联盟域名：www.cn-dos.net 论坛域名：www.cn-dos.net/forum
DOS，代表着自由开放与发展，我们努力起来，学习FreeDOS和Linux的自由开放与GNU精神，共同创造和发展美好的自由与GNU GPL世界吧！
中国DOS联盟论坛 » DOS批处理 & 脚本技术（批处理室） » 如何检查一字符串中相同字符的个数
查看 1,218 回复 13
楼 主
如何检查一字符串中相同字符的个数
发表于 2008-04-12 19:13 · 中国 江苏 苏州 电信
第 2 楼
发表于 2008-04-12 20:43 · 中国 江苏 常州 溧阳市 电信
@echo off
set "str=aferefwfwerergrgreaaffwafwa"
:lp
if defined str (
if "%str:~0,1%"=="a" set/a n+=1
set str=%str:~1%
goto lp
)
echo %n%
pause
P处理
本帖最近评分记录
（共 1 条）
点击查看详情
| 评分人 | 分数 | 时间 |
|---|---|---|
| huahua0919 | +8 | 2008-04-12 20:52 |
简单!简单!再简单!
第 3 楼
我也来一个：
发表于 2008-04-12 20:49 · 中国 湖南 株洲 电信
思路是计算两段字符长度差：
[ Last edited by zw19750516 on 2008-4-12 at 08:53 PM ]
@echo off&setlocal enabledelayedexpansion
set str=aferefwfwerergrgreaaffwafwa
set var=%str:a=%
for /l %%i in (1,1,100) do if "!str:~%%i,1!"=="" set num1=%%i&goto :1
:1
for /l %%i in (1,1,100) do if "!var:~%%i,1!"=="" set num2=%%i&goto :2
:2
set /a num=!num1!-!num2!
echo 变量中有!num!个a
endlocal
pause>nul
[ Last edited by zw19750516 on 2008-4-12 at 08:53 PM ]
批处理之家新域名：www.bathome.net
第 4 楼
发表于 2008-04-12 20:52 · 中国 湖南 株洲 电信
Originally posted by terse at 2008-4-12 20:43:
@echo off
set "str=aferefwfwerergrgreaaffwafwa"
:lp
if defined str (
if "%str:~0,1%"=="a" set/a n+=1
set str=%str:~1%
goto lp
)
echo %n%
pause
高，利用变量移位，的确是高！！！
批处理之家新域名：www.bathome.net
第 5 楼
发表于 2008-04-12 20:53 · 中国 广西 玉林 博白县 电信
@echo off
set "str=aferefwfwerergrgreaaffwafwa"
set/p= %str% 中有<nul
:loop
set /a %str:~0,1%+=1&set str=%str:~1%&if defined str goto loop
echo a %a% 个
pause
本帖最近评分记录
（共 3 条）
点击查看详情
| 评分人 | 分数 | 时间 |
|---|---|---|
| s11ss | +5 | 2008-04-12 21:03 |
| huahua0919 | +4 | 2008-04-12 21:25 |
| moniuming | +4 | 2008-04-12 22:49 |
第 6 楼
发表于 2008-04-12 20:56 · 中国 江苏 苏州 电信
Originally posted by terse at 2008-4-12 08:43 PM:
@echo off
set "str=aferefwfwerergrgreaaffwafwa"
:lp
if defined str (
if "%str:~0,1%"=="a" set/a n+=1
set str=%str:~1%
goto lp
)
echo %n%
pause
厉害！
我也写过个，效率相当底，terse兄的代码不错~
我加分
zh159的代码意思和terse差不多！
zw19750516的也不错，就是效率和通用性都有所降低！
谢谢大家
”一天不来论坛就感觉退步很多，不管你牛还是不牛“
第 7 楼
发表于 2008-04-12 21:01 · 中国 北京 华为云
set str=%str:~1%
难道这样就不是字符截取了吗？？
难道这样就不是字符截取了吗？？
第 8 楼
发表于 2008-04-12 21:05 · 中国 江苏 苏州 电信
我原先的意思是用字符串截取然后用findstr判断的，故自认为用字符截取会导致效率相当底，忘却用if判断！
我在写代码时遇到这个问题，所以向大家求助！现在可以解决很多问题了
再次感谢大家
我在写代码时遇到这个问题，所以向大家求助！现在可以解决很多问题了
再次感谢大家
第 9 楼
发表于 2008-04-12 21:05 · 中国 北京 鹏博士BGP
Originally posted by zh159 at 2008-4-12 08:53 PM:
@echo off
set "str=aferefwfwerergrgreaaffwafwa"
set/p= %str% 中有<nul
:loop
set /a %str:~0,1%+=1&set str=%str:~1%&if defined str goto loop
echo a %a% 个
pause
zh159兄的更牛，统计出了所有不同字母各自出现的次数。
第 10 楼
发表于 2008-04-12 21:21 · 中国 江苏 苏州 电信
仔细看了zh159兄的代码才发现 原来 set /a 还可以这么用
@echo off
set a=b
set /a a+=1
echo %a%
pause
第 11 楼
发表于 2008-04-12 22:48 · 中国 上海 电信
5楼就是牛
第 12 楼
发表于 2008-04-12 23:15 · 中国 陕西 西安 电信
来迟了，这个早有了，大家怎么就没注意精华帖：
批处理字符出现次数统计：
http://www.cn-dos.net/forum/viewthread.php?tid=25182&fpage=1&highlight=&page=1
这个是无奈何版主的：
这个是zh159终结版的：
批处理字符出现次数统计：
http://www.cn-dos.net/forum/viewthread.php?tid=25182&fpage=1&highlight=&page=1
这个是无奈何版主的：
@echo off
setlocal ENABLEDELAYEDEXPANSION
set str=adadfdfseffserfefsefseetsdg
set /a m=0,n=0,l=0
call :loop
for /f "tokens=1,2 delims==" %%i in ('set 字符：') do (
echo %%i=%%j
if %%j GTR !l! set l=%%j & set m=%%i
)
echo.出现次数最多的%m%=%l%
pause
goto :EOF
:loop
call set m=%%str:~%n%,1%%
if not defined m goto :EOF
set /a "字符：%m%+=1"
set /a n+=1
goto loop这个是zh159终结版的：
@echo off
setlocal EnableDelayedExpansion
set str=adadfdfseffserfefsefseetsdgadadfdfseffserfefsefseetsdga
:loop
set str$=%str$% %str:~0,1%&set str=%str:~1%
if not "%str%" == "" goto loop
for %%n in (%str$%) do (
set /a .%%n+=1
if !.%%n! GTR !maxN! set maxN=!.%%n!&&set max=%%n)
set .
echo 出现次数最多的:%max%=%maxN%
pause
exit
第 13 楼
发表于 2008-04-12 23:51 · 中国 重庆 电信
zh159 兄的代码果然强大，学习。
第 14 楼
发表于 2008-04-13 22:43 · 中国 台湾 中华电信(HiNet)数据中心
set "str=aferefwfwerergrgreaaffwafwa"
set /p word= word ?
set "str=%str:"=%"
set str="%str%"
call set str=%%str:^%word%=--" "--%%
for %%a in (%str%) do set /a num+=1
set /a num-=1
echo %num%
pause
论坛跳转: