中国DOS联盟

set motFn=

for /f "eol=[ usebackq" %%i in (`type %confFn%`) do (
set a=%%i
setlocal EnableDelayedExpansion
if "!a:~0,4!"=="motF" set motFn=!a:~5!&echo !a:~5! //此处echo得预期结果
endlocal
)

echo %motFn% //此处echo则得 %motFn%变量为空??

因为在endlocal命令后所有前面的变量赋值都将取消，所以%monFn%会为空。
把if "!a:~0,4!"=="motF" set motFn=!a:~5!&echo !a:~5!改为if "!a:~0,4!"=="motF" set motFn=!a:~5!&echo !motFn!就是的啊。

我要在for后面使用for中设置的变量的值，要怎么做呢?谢谢

用call或用goto调出来啊

if "!a:~0,4!"=="motF" set motFn=!a:~5!&echo !a:~5!改为if "!a:~0,4!"=="motF" set motFn=!a:~5!&call :lp !!motFn!!
或
if "!a:~0,4!"=="motF" set motFn=!a:~5!&echo !a:~5!改为if "!a:~0,4!"=="motF" set motFn=!a:~5!&goto lp

我实际的代码如下

set motFn=
set gcFn=
set obFn=

for /f "eol=[ usebackq" %%i in (`type %confFn%`) do (
set a=%%i
setlocal EnableDelayedExpansion
if "!a:~0,4!"=="motF" set motFn=!a:~5!
if "!a:~0,4!"=="gctF" set gcFn=!a:~5!
if "!a:~0,4!"=="binF" set obFn=!a:~5!
endlocal
)
if "%motFn%"=="" (echo ~FAIL~~,.~ Did NOT specify motF&goto :conf)
if "%gcFn%"=="" (echo ~FAIL~~,.~ Did NOT specify gctF&goto :conf)
if "%obFn%"=="" (echo ~FAIL~~,.~ Did NOT specify binF&goto :conf)

就是要在一条for语句中给三个变量赋值，楼上的方法只能给一个变量赋值

set motFn=
set gcFn=
set obFn=

for /f "eol=[ usebackq" %%i in (`type %confFn%`) do (
set a=%%i
setlocal EnableDelayedExpansion
if "!a:~0,4!"=="motF" set motFn=!a:~5!&call :lp1
if "!a:~0,4!"=="gctF" set gcFn=!a:~5!&call :lp2
if "!a:~0,4!"=="binF" set obFn=!a:~5!&call :lp3
endlocal
)
:lp1
if "%motFn%"=="" (echo ~FAIL~~,.~ Did NOT specify motF&goto :conf)
goto :eof
:lp2
if "%gcFn%"=="" (echo ~FAIL~~,.~ Did NOT specify gctF&goto :conf)
goto :eof
:lp3
if "%obFn%"=="" (echo ~FAIL~~,.~ Did NOT specify binF&goto :conf)
goto :eof

或者干脆去掉endlocal这句，把后面的%改成!

endlocal在for语句递归层小于33的时候可以不加，但当递归层达到33以上时就必须加上了，运行下面的代码你就会明白了：

@echo off

for /l %%i in (1,1,33) do (

    set a=%%i

    setlocal enabledelayedexpansion

    echo !a!

)

pause

我觉得可以CALL出的：
@echo off
for /f "eol=[ usebackq" %%i in (`type %confFn%`) do call:lp %%i
echo %motFn% %gcFn% %obFn%
pause
goto :eof
:lp
set a=%1
if "%a:~0,4%"=="motF" set motFn=%a:~5%
if "%a:~0,4%"=="gctF" set gcFn=%a:~5%
if "%a:~0,4%"=="binF" set obFn=%a:~5%