中国DOS联盟

现在装的是一键GHOST硬盘版，他会在第一个硬盘的最后一个分区里创建一个　~1这样一个文件夹，如果FAT32格式的话显示系统文件也看不到！
请教一下各位大虾怎么创建这个文件夹？？？？
小弟在此先谢过了！！

利用IBM一键恢复R＆R的话就很好弄，编一个批处理，里面包含ghost.exe。
按下F11后就可以选择备份还是恢复。下面是我的一键恢复系统的批处理文件。

@ECHO OFF
set EXPAND=YES
SET DIRCMD=/OGN /4 /P
set CDROM=R
set CDUSB=W
set LglDrv=27 * 26 Z 25 Y 24 X 23 W 22 V 21 U 20 T 19 S 18 R 17 Q 16 P 15
set LglDrv=%LglDrv% O 14 N 13 M 12 L 11 K 10 J 9 I 8 H 7 G 6 F 5 E 4 D 3 C
rem set RAMD=X
cls
call setramd.bat %LglDrv%
cls
rem xmsdsk 4096 %ramd%: /y /t >NUL
set temp=%RAMD%:\temp
set tmp=%RAMD%:\temp
PATH=%RAMD%:\;%CDROM%:\;%CDUSB%:\
copy command.com %RAMD%:\ > NUL
set comspec=%RAMD%:\command.com
copy extract.exe %RAMD%:\ > NUL

:ERROR
IF EXIST ebd.cab GOTO EXT
echo Please insert MS-DOS 7.10 Startup Disk 2
echo.
pause
GOTO ERROR

:EXT
%RAMD%:\extract /y /e /l %RAMD%: ebd.cab > NUL
echo The diagnostic tools were successfully loaded to drive %RAMD%.
@echo off
LH %RAMD%:\TW.EXE /np >NUL

if "%config%"=="RR" goto RR
if "%config%"=="DOS" goto DOS

:RR
c:
cls
echo.
echo.
echo. 欢迎使用一键恢复系统(Made by Kaven Lee)
echo. ================================================
echo.
echo.
echo.
echo 1、 恢复您的操作系统和所有应用程序
echo 2、 恢复您的文件
echo 3、 备份您的操作系统和所有应用程序
echo 4、 备份您的文件
echo 5、 进入 DOS 系统
echo 6、 重启系统
echo.
echo.
echo.
echo.
CHOICE /C:123456 /t:6,15 请选择您要进行的作业
If errorlevel=6 goto REBOOT
If errorlevel=5 goto DOS1
if errorlevel=4 goto BACKUPFI
If errorlevel=3 goto BACKUP
If errorlevel=2 goto RECFILES
If errorlevel=1 goto RECOVERY

:RECOVERY
@ECHO OFF
cls
echo.
echo.
echo 计算机将恢复您的系统到上一次正常使用时的状态, 请稍候......
echo ==========================================================
@echo off
wait 2
gdisk 1 /-hide /p:3
ghost -clone,mode=pload,src=c:\windows\win.gho:1,dst=1:1 -sure
ghost -clone,mode=pload,src=c:\windows\prog.gho:1,dst=1:3 -sure -rb
goto END

:RECFILES
@ECHO OFF
cls
echo.
echo.
echo 计算机将恢复您的文件到上一次备份时的状态, 请稍候......
echo ==========================================================
@echo off
wait 2
gdisk 1 /-hide /p:3
ghost -clone,mode=pload,src=c:\windows\files.gho:1,dst=1:4 -sure -rb
goto END


:BACKUP
@echo off
cls
echo.
echo.
echo 计算机正在准备备份您正在使用的系统, 请稍候......
echo ================================================
WAIT 2
gdisk 1 /-hide /p:3
ghost -clone,mode=pdump,src=1:1,dst=c:\windows\win.gho -z9 -auto -sure
ghost -clone,mode=pdump,src=1:3,dst=c:\windows\prog.gho -z9 -auto -sure
ghost -clone,mode=pdump,src=1:4,dst=c:\windows\files.gho -z9 -auto -sure -rb
goto END

:BACKUPFI
@echo off
cls
echo.
echo.
echo 计算机正在准备备份您的文件, 请稍候......
echo ==========================================
wait 2
gdisk 1 /-hide /p:3
ghost -clone,mode=pdump,src=1:4,dst=c:\windows\files.gho -z9 -auto -sure -rb
goto END

:DOS
c:
cls
echo.
echo.
echo. 欢迎使用DOS操作系统,请选择:
echo. =============================
echo.
echo.
echo.
echo. 1、 进入DOS
echo. 2、 重启系统
echo. 3、 关闭系统
echo.
echo.
echo.

CHOICE /C:123 /t:3,15 请选择:
If errorlevel=3 goto SHUTDOWN
If errorlevel=2 goto REBOOT
If errorlevel=1 goto DOS1

:DOS1
LH %ramd%:\Shsucdx.exe /D:?IDE-CD %CDROM% /D:?FWR-CD %CDROM% /D:?USB-CD %CDUSB%
copy ZENO.EXE %RAMD%:\ > NUL
copy MENU\*.* %RAMD%:\ > NUL
copy DOSKEY.COM %RAMD%:\ > NUL
copy MOUSE.EXE %RAMD%:\ > NUL
LH %RAMD%:\ZENO.EXE /Q > NUL
LH %RAMD%:\DOSKEY.COM > NUL
LH %RAMD%:\KILLER.EXE > NUL
LH %RAMD%:\ESCAPE.EXE > NUL
LH %RAMD%:\MOUSE.EXE /W > NUL
LH %RAMD%:\Key.com WB PY LX > NUL
call %RAMD%:\M.bat
c:\fshare
goto END

:REBOOT
@echo off
cls
echo.
echo.
echo 现在系统将重新启动, 请稍候......
echo ================================
@echo off
wait 5
shutdown r
goto END

:SHUTDOWN
@echo off
cls
echo.
echo.
echo 现在系统将关闭, 请稍候......
echo ============================
@echo off
wait 5
shutdown s
goto END

:END
C:

怎么不行？

2楼的大虾，我照你的做了，怎么不行哦

哦，忘了告诉大家，这个只是批处理的程序。其他的还要做如下工作：
（1）除了C：盘为主分区外，还要在C：盘后面再分一个主分区出来，即D：盘（注意，必须是主分区，不能是逻辑分区）。并将Label设为：IBM_SERVICE。
（2）用PQ将C：盘隐藏，D：盘激活为活动盘。
（3）用软盘或U盘或光盘重启计算机，并将系统传给C：盘（实际上是D：盘，因为刚才已经将C：盘隐藏）
（4）运行IBM一键恢复的软件
然后再将2楼的批处理保存为autoexec.bat就行了。

我没法上传IBM的R＆R，请各位在网上搜索一下，直接下载吧。