[已结]怎样取汉字的编码 - DOS批处理 & 脚本技术（批处理室） - 中国DOS联盟论坛

中国DOS联盟

-- 联合DOS 推动DOS 发展DOS --

联盟域名：www.cn-dos.net 论坛域名：www.cn-dos.net/forum
DOS，代表着自由开放与发展，我们努力起来，学习FreeDOS和Linux的自由开放与GNU精神，共同创造和发展美好的自由与GNU GPL世界吧！

字 -> code

@echo off
echo 请输入任意汉字
set /p str=
reg add HKCU\Environment\unistr /v str /t reg_expand_sz /d "%str%" /f >nul
reg export HKCU\Environment\unistr tmp.reg >nul
for /f "skip=3 delims=\ " %%a in ('type tmp.reg') do call set str_code_16=%%str_code_16%%%%a
set str_code_16=%str_code_16:*:=%
set str_code_16=%str_code_16:~0,-6%

for %%a in ("%str_code_16:,= "%) do (
	for /f "tokens=1,2" %%i in ("%%a") do (
		for /l %%m in (0x%%~j%%~i,1,0x%%~j%%~i) do call set "str_code_10=%%str_code_10%%&#%%m;"
	)
)
reg delete HKCU\Environment\unistr /f >nul
del tmp.reg

set str_code
::>rrr.txt set str_code
pause

code -> 字

@echo off
if "%~1" == "newcmd" goto newcmd

echo 请输入这种编码f7,8b,93,8f,65,51
set /p Ucode=
>tmp.reg  echo Windows Registry Editor Version 5.00
>>tmp.reg echo.
>>tmp.reg echo [HKEY_CURRENT_USER\Environment]
>>tmp.reg echo "Ustr"=hex(2):%Ucode%,00,00

regedit /s tmp.reg

>nul wmic environment create name="_ddd",variableValue="ddd",username="%username%"
>nul wmic process call create "%~s0 newcmd"
>nul wmic environment where ( name="_ddd" or name="Ustr" ) delete

del tmp.reg
goto :eof


:newcmd
cd /d "%~sdp0"
@echo on
set Ustr
pause