中国DOS联盟

前面有帖子中，写到删除在指定路径下指定日数以前修改的文件的代码如下：

:: DateDel2.bat - 删除指定路径下指定日数以前修改的文件 :: Will Sort - 2005-9-2 - CMD@WinXP :: 注意事项：参数%1指定日数，昨天为1，前天为2，依次类推 :: 参数%1指定文件路径，省略时将处理当前路径 :: 核心算法：Ritchie Lawrence, updated 2002-08-13. Version 1.1 :: 出处：http://www.cn-dos.net/forum/viewthread.php?tid=16676 @echo off & setlocal ENABLEEXTENSIONS call :Date2Day %date:~0,10% sdays set /a sdays-=%1 call :Day2Date %sdays% difdate echo 将删除 %cd% 下 %difdate% 前的修改的以下文件： for /r %2 %%f in (*.*) do if "%%~tf" LEQ "%difdate%" echo "%%f" goto :EOF :Date2Day setlocal ENABLEEXTENSIONS for /f "tokens=1-3 delims=/-, " %%a in ('echo/%1') do ( set yy=%%a & set mm=%%b & set dd=%%c ) set /a dd=100%dd%%%100,mm=100%mm%%%100 set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2 set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633 endlocal&set %2=%j%&goto :EOF :Day2Date setlocal ENABLEEXTENSIONS set /a i=%1,a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5 set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10 (if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%) endlocal&set %2=%yy%-%mm%-%dd%&goto :EOF
但是我运行之后出现这样的提示：
D:\aa>"D:\MSOCache\All Users\90000804-6000-11D3-8CFE-0150048383C9\DateDel2.bat" 找不到操作数。 将删除 D:\aa 下 2007-08-06 前的修改的以下文件： "D:\aa\DateDel2.bat" "D:\aa\DateDel2.bat.bak" "D:\aa\复件 (10) kki20070506sdfsdfs.txt" "D:\aa\复件 (11) kki20070506sdfsdfs.txt" "D:\aa\复件 (12) kki20070506sdfsdfs.txt" "D:\aa\复件 (13) kki20070506sdfsdfs.txt" "D:\aa\复件 (14) kki20070506sdfsdfs.txt" "D:\aa\复件 (15) kki20070506sdfsdfs.txt" "D:\aa\复件 (16) kki20070506sdfsdfs.txt" "D:\aa\复件 (17) kki20070506sdfsdfs.txt" "D:\aa\复件 (18) kki20070506sdfsdfs.txt" "D:\aa\复件 (19) kki20070506sdfsdfs.txt" "D:\aa\复件 (20) kki20070506sdfsdfs.txt" "D:\aa\复件 (21) kki20070506sdfsdfs.txt" "D:\aa\复件 (22) kki20070506sdfsdfs.txt" "D:\aa\复件 (23) kki20070506sdfsdfs.txt" "D:\aa\复件 (24) kki20070506sdfsdfs.txt" "D:\aa\复件 (25) kki20070506sdfsdfs.txt" "D:\aa\复件 (26) kki20070506sdfsdfs.txt" "D:\aa\复件 (27) kki20070506sdfsdfs.txt" "D:\aa\复件 (28) kki20070506sdfsdfs.txt" "D:\aa\复件 (29) kki20070506sdfsdfs.txt" "D:\aa\复件 (3) kki20070506sdfsdfs.txt" "D:\aa\复件 (30) kki20070506sdfsdfs.txt" "D:\aa\复件 (31) kki20070506sdfsdfs.txt" "D:\aa\复件 (32) kki20070506sdfsdfs.txt" "D:\aa\复件 (4) kki20070506sdfsdfs.txt" "D:\aa\复件 (5) kki20070506sdfsdfs.txt" "D:\aa\复件 (6) kki20070506sdfsdfs.txt" "D:\aa\复件 (7) kki20070506sdfsdfs.txt" "D:\aa\复件 (8) kki20070506sdfsdfs.txt" "D:\aa\复件 (9) kki20070506sdfsdfs.txt" "D:\aa\复件 kki20070506sdfsdfs.txt" "D:\aa\复件2) kki20070506sdfsdfs.txt"
请教，这是什么问题？

并且这些文件根本就没有删除掉。。。还在文件夹里面。。。

:: DateDel2.bat - 删除指定路径下指定日数以前修改的文件
:: Will Sort - 2005-9-2 - CMD@WinXP
:: 注意事项：参数%1指定日数，昨天为1，前天为2，依次类推
:: 参数%1指定文件路径，省略时将处理当前路径
:: 核心算法：Ritchie Lawrence, updated 2002-08-13. Version 1.1
:: 出处：http://www.cn-dos.net/forum/viewthread.php?tid=16676

@echo off & setlocal ENABLEEXTENSIONS
call :Date2Day %date:~0,10% sdays
set /a sdays-=%1
call :Day2Date %sdays% difdate
echo 将删除 %cd% 下 %difdate% 前的修改的以下文件：
for /r %2 %%f in (*.*) do if "%%~tf" LEQ "%difdate%" echo "%%f"
goto :EOF

:Date2Day
setlocal ENABLEEXTENSIONS
for /f "tokens=1-3 delims=/-, " %%a in ('echo/%1') do (
set yy=%%a & set mm=%%b & set dd=%%c
)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %2=%j%&goto :EOF

:Day2Date
setlocal ENABLEEXTENSIONS
set /a i=%1,a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%-%mm%-%dd%&goto :EOF

这里是测试用的，要改为 del

谢谢楼上的朋友，还有一个问题请教一下
=======
:: 注意事项：参数%1指定日数，昨天为1，前天为2，依次类推
:: 参数%1指定文件路径，省略时将处理当前路径
=========
这个在程序中的日期和文件路径在哪里可以设置的?

%1为日期
%2为路径
假设我要删除C:\TEST文件夹中5天前的所有文件
应该在命令符提示窗口中这样写：
DateDel2.bat 5 C:\TEST

Originally posted by HAT at 2007-8-7 04:31 PM:
%1为日期
%2为路径
假设我要删除C:\TEST文件夹中5天前的所有文件
应该在命令符提示窗口中这样写：
DateDel2.bat 5 C:\TEST

非常感谢，刚开始学习批处理，很多东西不太懂~~

非常感谢，刚开始学习批处理，很多东西不太懂~~


刚开始学就能写出如此高难的P处理， 佩服！

本人觉的，如要删除N天之前的文件，还是用FORFILES 又简单有容易理解啊，
forfiles -p -m -s -d "cmd/ c del /f/q @FILE" 但不能运行在NT4.0 上啊， 请吿知啊。

[ Last edited by joshualaw on 2007-8-8 at 08:06 PM ]

感谢中。正在查错！