中国DOS联盟

取得最后一行字符我已经知道了：
for /f "tokens=1* delims=:" %%i in ('findstr /n .* "file.txt"') do set var=%%j
echo %var%


那么如何取得最后一行字符(也就是%var%)的长度呢？就是有多少个字符数？
最好不要用:的标签去循环，谢谢。

Last edited by zmt1982 on 2007-8-2 at 01:48 PM ]

http://www.cn-dos.net/forum/viewthread.php?tid=28731

谢谢
上面的帖子我搜索过，不是我要的
他统计的是单词的个数
我要的是字符的个数，并且包括特殊字符。

本来用set+goto是可以实现的，

但楼主指明不能用goto，那暂时想不出了，

等高手吧

因为我一个批处理里面，也许要取得分别几个文件的字符
如果每一个文件都要写一个goto
那么这个批处理文件就会很长很乱。

那用VBS或JS吧，人家有函数帮忙

其实说实话吧。我在写一个软件自动升级的批处理

echo ╔══════════════════════╗
echo ║ *-_-* 你的软件版本%var% ║
echo ║ 最新的软件版本%serv_var% ║
echo ║ 正在启动升级程序，请勿手动关闭此窗口... ║
echo ╚══════════════════════╝

版本的字符是不一样的，有时候厂有时候短，所以我想判断 版本字符的长度，来在后面加相应的空格，这样才能让后面的 ║对齐。

可以用制表符

这个就好办多了


不管字符多长，都加一段“空格”上去，（可以多加点），然后再用set从第一位开始取，取固定长度就行了啊。

问题解决，还是用了goto，没办法，不知道有没有更简单的办法：


var和serv_var分别是本地和服务器的版本变量
已经通过其他方法获取了。

:::::::::::本地版本变量的长度:::::::::::
set str=%var%
set "str=%str:"= %"

:next
if not "%str%"=="" (
set /a num+=1
set "str=%str:~1%"
goto next
)

:::::::::::服务器版本变量的长度:::::::::::
set serv_str=%serv_var%
set "serv_str=%serv_str:"= %"

:next1
if not "%serv_str%"=="" (
set /a serv_num+=1
set "serv_str=%serv_str:~1%"
goto next1
)

::下面的27表示下面框内从“你的软件”后面开始到║的全部的字符（空格）个数

set space=
set num=%num%
set /a num=27-%num%
set serv_num=%serv_num%
set /a serv_num=27-%serv_num%
call set space1=%%space:~0,%num%%%
call set serv_space=%%space:~0,%serv_num%%%

if "%var%"=="%serv_var%" goto No_Upload || goto Go_Upload

:Go_Upload
echo ╔══════════════════════╗
echo ║ *-_-* 你的软件%var%%space1%║
echo ║ 最新的软件%serv_var%%serv_space%║
echo ║ 正在启动升级程序，请勿手动关闭此窗口... ║
echo ╚══════════════════════╝
echo.

set "serv_str=%serv_str:"= %"
set "serv_str=%serv_str% "
set "serv_str=%serv_str:~0,27%"

个人认为还不如这样呢

很多goto都是没必要的
（%var%、%serv_var%后面有27个空格）

if "%var%"=="%serv_var%" goto No_Upload



set "var=%var%                           "

set "var=%var:~0,27%"

set "serv_var=%serv_var%                           "

set "serv_var=%serv_var:~0,27%"



echo    ╔══════════════════════╗

echo    ║ *-_-*   你的软件%var%║

echo    ║       最新的软件%serv_var%║

echo    ║  正在启动升级程序，请勿手动关闭此窗口...   ║

echo    ╚══════════════════════╝

echo. 

至于这两句，是不是变量里面包含引号？
set "str=%str:"= %"
set "serv_str=%serv_str:"= %"

是怕有特殊字符。因为版本号一般是类似： 20.11.22

测试了一下，你的代码果然可以用
厉害。

就是不明白是什么意思。

Last edited by zmt1982 on 2007-8-2 at 05:31 PM ]

用for也可以

@echo off

set "var=1234567"

setlocal ENABLEDELAYEDEXPANSION

for /l %%i in (1 1 100) do (

set num=!var:~%%i!

if "!num!"=="" echo 变量var有 %%i 个字符&goto lis

)

:lis

pause

Last edited by 26933062 on 2007-8-6 at 03:57 PM ]

要取最后一行的话，为何不这样写呢？

for /f "tokens=1* delims=" %%i in ('findstr .* "file.txt"') do set var=%%i

echo %var%