中国DOS联盟

我想让 cmd 窗口的背景颜色和文字颜色 逐个 循环 改变（我想从中选择叫好的效果配置），用for 怎么写
每次改变颜色后 选则是否继续 往下实验，并输出当前窗口的背景与文字颜色代号：
当前背景与文字颜色 如输出 0a
%a% %b% 分别存放
背景颜色和文字颜色 ，就是这样：从0，1，2，3...9，a,b,c,d,e,f 这16个中逐个选取其中两个的组合分别给a,b，直到所有的组合都选到,然后用
color %a%%b%
来 for 循环 选择是否继续 实验下一个和显示当前配置

谢谢~！

[ Last edited by gskys123 on 2007-1-15 at 12:03 PM ]

　　版本一：

@echo off

setlocal enabledelayedexpansion

set str=0123456789abcdef



for /l %%i in (0,1,15) do (

    for /l %%j in (0,1,15) do (

        if %%i neq %%j (

            cls

            echo 当前颜色代码是：color !str:~%%i,1!!str:~%%j,1!

            color !str:~%%i,1!!str:~%%j,1!

            pause

        )

    )

)

　　版本二：

@echo off

for %%i in (0 1 2 3 4 5 6 7 8 9 a b c d e f) do (

    for %%j in (0 1 2 3 4 5 6 7 8 9 a b c d e f) do (

        if %%i neq %%j (

            cls

            echo 当前颜色代码是：color %%i%%j

            color %%i%%j

            pause

        )

    )

)

[ Last edited by namejm on 2007-1-15 at 12:23 AM ]

测试 namejm 代码，发现：不出现 比如 :10 12 13 14 颜色

　　当时只想到数字在前字母在后的情况而忽略了其他情况，犯了个低级错误，汗。2楼的已经更新。

多谢 namejm ！！;)
这样一来我对 for 的用法的理解又深了一点！
谢谢！！