中国DOS联盟

昨天写完的东西，忘发了。功能简单在线查单词，数据来自金山词霸。
需要 wget 或 curl 支持，如果需要朗读功能的话需要 mplayer 支持。

用法：dict word ...
/F 完全模式查询单词。
word 可指定多个单词。
支持单词朗读功能。

所需软件链接：
mplayer：http://www.mplayerhq.hu
wget ：http://users.ugent.be/~bpuype/wget/
或 curl：http://curl.haxx.se/

1. :::::::::::::::::::::::::::::::::::::::::::::::::
   
2. :: dict.cmd -V0.1 -- 批处理在线查单词
   
3. :: 无奈何@cn-dos.net - 2007-1-2
   
4. :: 用法：dict word ...
   
5. :: 支持文件: - mplayer.exe wget.exe or curl.exe
   
6. :::::::::::::::::::::::::::::::::::::::::::::::::
   
7. @echo off
   
8. setlocal ENABLEDELAYEDEXPANSION
   
9. set mp3file="%TEMP%\dict.mp3"
   
10. rem 依赖文件检查
    
11. :mplay
    
12. call mplayer >nul 2>nul
    
13. if "%ERRORLEVEL%" == "1" set nomplay=1
    
14. 
    
15. :wget
    
16. wget.exe >nul 2>nul
    
17. if not "%ERRORLEVEL%" == "9009" (
    
18. set "command1=wget -q -O - "
    
19. set "command2=wget -q -O %mp3file%"
    
20. goto star
    
21. )
    
22. 
    
23. :curl
    
24. curl.exe >nul 2>nul
    
25. if not "%ERRORLEVEL%" == "9009" (
    
26. set "command1=curl -s "
    
27. set "command2=curl -s -o %mp3file%"
    
28. goto star
    
29. )
    
30. echo.本脚本需要 wget 或 curl 的支持。
    
31. goto :EOF
    
32. 
    
33. :star
    
34. set flag=0
    
35. if "%~1" == "" goto help
    
36. if "%~1" == "?" goto help
    
37. if "%~1" == "/?" goto help
    
38. if "%~1" == "/F" shift &goto full
    
39. if "%~1" == "/f" shift &goto full
    
40. 
    
41. 
    
42. :next
    
43. if "%~1" == "" goto :EOF
    
44. set "word=%~1"
    
45. call :down
    
46. shift
    
47. goto :next
    
48. 
    
49. :full
    
50. if "%~1" == "" goto :EOF
    
51. set mp3=
    
52. del %mp3file% 2>nul
    
53. set "word=%~1"
    
54. call :down
    
55. %command2% "%mp3%"
    
56. echo.--------------------------------
    
57. if "%mp3%" == "" echo.查看详解 退出 &goto :Nselect
    
58. echo.朗读 查看详解 退出
    
59. :Nselect
    
60. set select=
    
61. set /p select=请选择：
    
62. call :Parse
    
63. if "%quit%" == "1" goto :EOF
    
64. shift
    
65. goto :full
    
66. 
    
67. 
    
68. :Parse
    
69. for %%s in (R r F f A a) do if "%%s" == "%select%" goto Switch%select%
    
70. goto :EOF
    
71. 
    
72. :SwitchR
    
73. if "%nomplay%" == "1" echo. 播放影音需要 mplayer 支持。&goto :Nselect
    
74. start /min %ComSpec% /c "mplayer %mp3file%>nul"
    
75. goto :Nselect
    
76. goto :EOF
    
77. 
    
78. :SwitchF
    
79. start http://www.iciba.com/search?s=%word%
    
80. goto :Nselect
    
81. goto :EOF
    
82. 
    
83. :SwitchA
    
84. set quit=1
    
85. goto :EOF
    
86. 
    
87. 
    
88. :down
    
89. set url="http://dict.cn/ws.php?q=%word%"
    
90. echo.
    
91. echo.单词：%word%
    
92. echo.释义：
    
93. for /f "tokens=1,2,3 delims=<>" %%a in ('%command1% %url%') do (
    
94. if "%%a" == "audio" set "mp3=%%b"
    
95. if "%%b" == "Not Found" echo 无此单词^^! &goto :EOF
    
96. if "%%c" == "/def" echo %%b &goto :EOF
    
97. if "%%b" == "/def" echo %%a &set flag=0
    
98. if "!flag!" == "1" echo %%a
    
99. if "%%a" == "def" echo %%b &set flag=1
    
100. )
     
101. goto :EOF
     
102. 
     
103. :help
     
104. echo.批处理在线查单词
     
105. echo.
     
106. echo.用法：dict word ...
     
107. echo.
     
108. echo /F 完全模式查询单词。
     
109. echo word 可指定多个单词。
     
110. goto :EOF
     

无奈何发表于 2007-01-03 12:11

[ Last edited by 无奈何 on 2007-1-4 at 01:16 AM ]

坐下沙发^_^

欣赏～～
内容越来越全面、越来越丰富吸引人了～：）））

一个字=====强！

我不会用，惭愧

不行吖,双击后一闪然后就退出了
我已经下载了wget了,存于WINDOWS吗,我也试了存于system32
结果还是一样

发错了，汗一个！＝_＝|||

[ Last edited by ccwan on 2007-1-4 at 05:55 AM ]

呵呵，以前简单的弄了下，没有去完善，佩服斑竹，要我弄的话是wget+sed

声音文件是.swf吗？

RE dosmania
干嘛要双击运行，这样你只能看到帮助并且一闪而过，在命令行下调用。

RE lxmxn
不需要词库的，在线查。你说的是金山词霸的词典吗？

RE vkill
声音是 mp3 格式的。http://www.iciba.com/ 的是swf 的。

RE 无奈何 斑竹
我觉得读音还是 mplayer 来播放iciba上的好,呵呵,简单

@echo off
:start
set search=
set /p search=请输入要翻译的单词:
set search_x=%search:~0,1%
echo %search%读音:
mplayer http://www.iciba.com/resource/a/en/%search_x%/%search%.swf>nul
goto start

越来越有意思了，看来我要努力学习了阿

好东西啊

佩服！