中国DOS联盟

set nnn=abcdefghijklmnopurstyvwxyz
问题1,如何依次显示这26个变量?
问题2,其实我本意是建立一批处理,运行后就新建一个文档,命名为a.txt再一次运行就建立b.txt.......c.txt.......d.txt...............
能否将这两个问题分开解答,谢了.

[ Last edited by namejm on 2007-2-3 at 01:28 PM ]

显示这26个变量～：）

@echo off


set "nnn=abcdefghijklmnopurstyvwxyz"
for /L %%. in (0,1,25) do ( Call echo %%nnn:~%%.,1%% )

好方法！

2

@echo off

setlocal EnableDelayedExpansion

set "nnn=abcdefghijklmnopurstyvwxyz"

for /L %%. in (0,1,25) do (

  set svr=!nnn:~%%.,1!

  if not exist "!svr!.txt" cd.>!svr!.txt&&pause

)

想要建立后退出，把“pause”改为“exit”

　　请看如下演示代码：

@echo off

:begin

cls

set "str=abcdefghijklmnopurstyvwxyz"

if not exist num.txt (echo 1)>num.txt&goto pick-up

for /f %%i in (num.txt) do set num=%%i



:pick-up

call set "str=%%str:~%num%,1%%"

set /a num+=1

echo "%str%"

if %num% equ 26 set num=0

(echo %num%)>num.txt

pause

goto begin

都太好了,谢谢大家.

我服了，怎么管理员给管理员加分啊？
有这个必要吗？

请问是那个管理员给那个管理员加分了？

@echo off
setlocal enabledelayedexpansion

set num=0
set "str=abcdefghijklmnopurstyvwxyz"

:loop

echo !str:~%num%,1!
set /a num+=1
ping -n 1 127.1>nul

if %num% equ 26 goto :eof

goto loop