中国DOS联盟论坛

中国DOS联盟

-- 联合DOS 推动DOS 发展DOS --

联盟域名：www.cn-dos.net  论坛域名：www.cn-dos.net/forum
DOS，代表着自由开放与发展，我们努力起来，学习FreeDOS和Linux的自由开放与GNU精神，共同创造和发展美好的自由与GNU GPL世界吧！

游客:  注册 | 登录 | 命令行 | 会员 | 搜索 | 上传 | 帮助 »
中国DOS联盟论坛 » DOS批处理 & 脚本技术（批处理室） » 请问如果在文本中抽取指定字符赋值于变量中
<<   [1] [2] [3]  >>   >
作者:
标题: 请问如果在文本中抽取指定字符赋值于变量中 上一主题 | 下一主题
mp3down
初级用户





积分 43
发帖 14
注册 2006-12-9
状态 离线
『楼 主』:  请问如果在文本中抽取指定字符赋值于变量中

我想,在一个文本文件中,抽取第17行第8-20这一串字符,并将它们赋值于一个变量给接下来的命令用，怎么办？

请各位大侠不要怪我整天问这些太菜的问题，我也觉得有点不好意思。想到不耻下问，这坛子的确令我学到东西，所以就壮胆了。

[ Last edited by namejm on 2006-12-13 at 01:54 PM ]

2006-12-12 06:06
查看资料  发短消息 网志   编辑帖子  回复  引用回复
a9319751
中级用户





积分 439
发帖 170
注册 2006-1-9
状态 离线
『第 2 楼』:  

CODE:  [Copy to clipboard]
setlocal enabledelayedexpansion
for /f "delims=" %%i in (1.txt ) do (
    set /a num+=1
    if !num! equ 17 set var=%%i
    if !num! equ 17 set var=!var:~7,13!
)
echo !var!
pause


   此帖被 +5 点积分       点击查看详情   
评分人：【 ccwan 】分数： +5  时间：2006-12-12 06:23




bat c c++
2006-12-12 06:12
查看资料  发送邮件  发短消息 网志  OICQ (5040366)  编辑帖子  回复  引用回复
youxi01
高级用户




积分 846
发帖 247
注册 2006-10-27
来自 湖南==》广东
状态 离线
『第 3 楼』:  

CODE:  [Copy to clipboard]
@echo off
for /f "skip=16 delims=" %%i in (test.txt) do (
    set "str=%%i"
    call set "str=%%str:~7,12%%"
    goto :exit)
:exit
   echo %str%
pause>nul
或者：
CODE:  [Copy to clipboard]
@echo off
for /f "delims=: tokens=1,2*" %%i in ('findstr /n . test.txt') do (
   if %%i EQU 17 (
        set "str=%%j"
        call set "str=%%str:~7,12%%"
        goto :exit))
:exit
   echo %str%
pause>nul
[ Last edited by youxi01 on 2006-12-12 at 06:22 AM ]

   此帖被 +5 点积分       点击查看详情   
评分人：【 ccwan 】分数： +5  时间：2006-12-12 06:24


2006-12-12 06:19
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
NaturalJ0
银牌会员




积分 1181
发帖 533
注册 2006-8-14
状态 离线
『第 4 楼』:  

setlocal enabledelayedexpansion
for /f "skip=16 delims=" %%i in (filename.txt) do (
set var=%%i
set var=!var:~7,13!
goto :outfor)
:outfor

红色部分你可以自己随便替换。

   此帖被 +5 点积分       点击查看详情   
评分人：【 ccwan 】分数： +5  时间：2006-12-12 06:24


2006-12-12 06:21
查看资料  发短消息 网志   编辑帖子  回复  引用回复
NaturalJ0
银牌会员




积分 1181
发帖 533
注册 2006-8-14
状态 离线
『第 5 楼』:  

哇，我手脚太慢了。 = =b

2006-12-12 06:22
查看资料  发短消息 网志   编辑帖子  回复  引用回复
ccwan
金牌会员




积分 2725
发帖 1160
注册 2006-9-23
来自 河北廊坊
状态 离线
『第 6 楼』:  

我的手够快吧？
鼓励一下热心的朋友们！



三人行，必有吾师焉。   学然后知不足，教然后知困，然后能自强也。
2006-12-12 06:24
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
ccwan
金牌会员




积分 2725
发帖 1160
注册 2006-9-23
来自 河北廊坊
状态 离线
『第 7 楼』:  

还有，楼主注意你的标题！



三人行，必有吾师焉。   学然后知不足，教然后知困，然后能自强也。
2006-12-12 06:53
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
mp3down
初级用户





积分 43
发帖 14
注册 2006-12-9
状态 离线
『第 8 楼』:  

谢谢热心的朋友们，我以后会注意标题了。

2006-12-12 07:08
查看资料  发短消息 网志   编辑帖子  回复  引用回复
namejm
荣誉版主

batch fan


积分 5226
发帖 1737
注册 2006-3-10
来自 成都
状态 离线
『第 9 楼』:  

Re all:

　　用批处理来提取文本内容，要随时注意兼容特殊字符，比如空格，比如连接字符&、||等，因此，youxi01 兄在3F的代码动用了 delims= 和 set "str=%%i" ，这是非常有必要的。

　　不过，批处理还是不能处理所有的特殊情况，比如：如果有以半角分号开头的行，一般的 for 语句会忽略这些行，用 set /a num+=1 来统计行数会出错，换成 for +  findstr /n 就可以避免；但是，for + findstr /n 也不能包打天下，至少，如果某些行以半角冒号打头，则 for /f "tokens=1* delims=:" %%i in ('findstr /n .* test.txt') do echo "%%j" 会把所有行首冒号忽略掉。所以，在处理文本的时候，只能指望这些特殊的情形不一起出现了。不知各位有没有什么好办法来解决。



尺有所短，寸有所长，学好CMD没商量。
考虑问题复杂化，解决问题简洁化。
2006-12-12 09:07
查看资料  发短消息 网志   编辑帖子  回复  引用回复
3742668
荣誉版主





积分 2013
发帖 718
注册 2006-2-18
状态 离线
『第 10 楼』:  

CODE:  [Copy to clipboard]
@echo off
    setlocal enabledelayedexpansion
    set num=
    for /f "delims=" %%i in ('findstr .* a.txt') do (
        set /a num += 1
        set "!num!=%%i"
    )
    for /l %%i in (1,1,%num%) do echo 第%%i行: !%%i!
pause
暂时的变更方案，试试有无bug。

2006-12-12 10:25
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
namejm
荣誉版主

batch fan


积分 5226
发帖 1737
注册 2006-3-10
来自 成都
状态 离线
『第 11 楼』:  

　　3742668 兄10F的代码仍然不能正确处理行首为分号的情况，也不能正确处理行内带感叹号的情况。

　　代码1能正确处理行首为分号或冒号，行上带&、||等特殊字符的文本，但是不能正确提取带感叹号的内容，代码2能解决感叹号的问题，但是需要用引号括起来，基本上解决了我在9F提出的问题，请各位测试：

　　代码1：
CODE:  [Copy to clipboard]
@echo off
set num=0
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('findstr /n .* test.txt') do (
    set /a num+=1
    set "str=%%i"
    echo 第 !num! 行： !str:*:=!
)
pause
　　代码2：
CODE:  [Copy to clipboard]
@echo off
set num=0
::setlocal enabledelayedexpansion
for /f "delims=" %%i in ('findstr /n .* test.txt') do (
    set /a num+=1
    set "str=%%i"
    call :display
)
pause
goto :eof

:display
echo 第 %num% 行： "%str:*:=%"
goto :eof
　　test.txt的内容：
CODE:  [Copy to clipboard]
:abc
::xy
;
;;;ef &
;:;
::;;
||
&
^
!<
!
%
"
""
'
[ Last edited by namejm on 2006-12-11 at 10:13 PM ]



尺有所短，寸有所长，学好CMD没商量。
考虑问题复杂化，解决问题简洁化。
2006-12-12 11:04
查看资料  发短消息 网志   编辑帖子  回复  引用回复
3742668
荣誉版主





积分 2013
发帖 718
注册 2006-2-18
状态 离线
『第 12 楼』:  

try try this:
CODE:  [Copy to clipboard]
@echo off
    setlocal enabledelayedexpansion
    set num=
    for /f "eol= delims=" %%i in ('findstr .* a.txt') do (
        setlocal DISABLEDELAYEDEXPANSION
        set "tmpstr=%%i"
        setlocal enabledelayedexpansion
        set /a num += 1
        set "!num!=!tmpstr!"
    )
    for /l %%i in (1,1,%num%) do echo 第%%i行: !%%i!
    pause
exit /b 0


   此帖被 +5 点积分      点击查看详情   
评分人：【 lxmxn 】分数： +5  时间：2006-12-12 13:47


2006-12-12 11:41
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
namejm
荣誉版主

batch fan


积分 5226
发帖 1737
注册 2006-3-10
来自 成都
状态 离线
『第 13 楼』:  

　　eol= 用得巧，setlocal 用得妙，高，实在是高，嘿嘿。



尺有所短，寸有所长，学好CMD没商量。
考虑问题复杂化，解决问题简洁化。
2006-12-12 12:18
查看资料  发短消息 网志   编辑帖子  回复  引用回复
lxmxn
版主




积分 11386
发帖 4938
注册 2006-7-23
状态 离线
『第 14 楼』:  


　　真是强啊。学习了。。

2006-12-12 13:47
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
lxmxn
版主




积分 11386
发帖 4938
注册 2006-7-23
状态 离线
『第 15 楼』:  


　　还有一个问题，就是如果a.txt里面有空行(直接回车)的话，那么就会出错，批处理提示：

  Quote:
已经达到最大的 setlocal 递归层。

　　不知道这个问题怎么解决？

2006-12-12 13:50
查看资料  发送邮件  发短消息 网志   编辑帖子  回复  引用回复
<<   [1] [2] [3]  >>   >
请注意：您目前尚未注册或登录，请您注册或登录以使用论坛的各项功能，例如发表和回复帖子等。


可打印版本 | 推荐给朋友 | 订阅主题 | 收藏主题



论坛跳转:  



[ 联系联盟系统管理团队 - 中国DOS联盟 ]

Sponsored by ifanr Inc | © 2001-2023