中国DOS联盟

@echo off
color 2f
:start
cls
echo.
echo.
echo.
echo         ==============================================================
echo.
echo                            绿菩提密盘 测试版
echo.
echo                   欢迎使用,请选择选项(1,2,3,4,5,6,7)
echo.
echo                              1.打开密盘
echo                              2.关闭密盘
echo                              3.建立密盘
echo                              4.删除密盘
echo                              5.密盘帮助
echo                              6.关于作者
echo                              7.X键关闭
echo.
echo.                 风里血制作    Email:jie_china@163.com
echo.
echo         ==============================================================
echo.
echo.
set /p choice=
if {%choice%}=={} goto start
if /i %choice%==1 goto open
if /i %choice%==2 goto off
if /i %choice%==3 goto set
if /i %choice%==4 goto del
if /i %choice%==5 goto help
if /i %choice%==6 goto zwj
if /i %choice%==x goto shut
if /i %choice%==kill goto kill
goto start

rem ===========================打开密盘==============================
:open
cls
echo.
echo.
echo.
echo.
echo         请输入密盘所在的分区(输入"C"则打开在C盘建立的密盘)
echo.
echo                        返回主菜单(请按X键)
echo.
set /p drv=
if {%drv%}=={} goto open
if /i %drv%==X goto start
if not exist %drv%: goto nodrv
echo 请输入密码：
set /p pass1=
if {%pass1%}=={} goto pw1
if /i %pass1%==X goto start
if not exist %drv%:\Recycle\S-1-5-21-1060284298-%pass1%-13438020086-500\ goto wm
subst z: %drv%:\Recycle\S-1-5-21-1060284298-%pass1%-13438020086-500 >nul 2>nul
echo.
echo.
cls
echo.
echo.
echo    请稍候...5秒后将自动打开密盘
ping 127.0.0.1 -n 5 >nul 2>nul
start z: >nul 2>nul
cls
echo.
echo.
echo    打开密盘成功,密盘为Z盘,请在"我的电脑里"查看
echo    按任意键返回主菜单
pause >nul
goto start
:wm
cls
echo.
echo.
echo    所在分区不存在密盘,或者密码错误,按任意键返回主菜单
pause >nul
goto start
:pw1
echo 密码不能为空,请输入密码:
set /p pass1=
if {%pass1%}=={} goto pw1
if /i %pass1%==X goto start
if not exist %drv%:\Recycle\S-1-5-21-1060284298-%pass1%-13438020086-500\ goto wm
subst z: %drv%:\Recycle\S-1-5-21-1060284298-%pass1%-13438020086-500 >nul 2>nul
start z: >nul 2>nul
cls
echo.
echo.
echo    建立密盘成功,密盘为Z盘,按任意键返回主菜单
pause >nul
goto start
rem ===========================打开密盘结束===========================


rem ===========================关闭密盘===============================
:off
cls
subst z: /d
echo.
echo.
echo.
echo                关闭密盘成功,按任意键返回主菜单
echo.
echo.
echo.
pause >nul
goto start
rem ===========================关闭密盘结束===========================


rem============================建立密盘===============================
:set
cls
echo.
echo.
echo.
echo.
echo        请输入要建立保密文件夹的分区(输入"C"则在C盘建立密盘,依次类推.)
echo.
echo                        返回主菜单(请按X键)
echo.
echo.
set /p drv=
if {%drv%}=={} goto set
if /i %drv%==X goto start
if not exist %drv%: goto nodrv
if exist %drv%:\Recycle goto error
echo 请输入密码:
set /p pass2=
if {%pass2%}=={} goto pw2
if /i %pass2% ==X goto start
md %drv%:\Recycle >nul 2>nul
attrib +s +h %drv%:\Recycle >nul 2>nul
echo [.ShellClassInfo]>>C:\tmp
echo CLSID={645FF040-5081-101B-9F08-00AA002F954E}>>C:\tmp
copy c:\tmp %drv%:\Recycle\desktop.ini >nul 2>nul
del c:\tmp >nul 2>nul
attrib +s +h %drv%:\Recycle\desktop.ini
md %drv%:\Recycle\S-1-5-21-1060284298-%pass2%-13438020086-500 >nul 2>nul
echo 建立密盘成功，请记住建立密盘的分区和密码,按任意键返回主菜单
pause >nul
cls
goto start
:pw2
echo 密码不能为空,请输入密码:
set /p pass2=
if {%pass2%}=={} goto pw2
if /i %pass2% ==X goto start
md %drv%:\Recycle >nul 2>nul
attrib +s +h %drv%:\Recycle >nul 2>nul
echo [.ShellClassInfo]>>C:\tmp
echo CLSID={645FF040-5081-101B-9F08-00AA002F954E}>>C:\tmp
copy c:\tmp %drv%:\Recycle\desktop.ini >nul 2>nul
del c:\tmp >nul 2>nul
attrib +s +h %drv%:\Recycle\desktop.ini
md %drv%:\Recycle\S-1-5-21-1060284298-%pass2%-13438020086-500 >nul 2>nul
echo 建立密盘成功，请记住建立密盘的分区和密码,按任意键返回主菜单
pause >nul
goto start
rem ==========================建立密盘部分结束=======================

rem ============================删除密盘=============================
:del
subst z: /d >nul 2>nul
cls
echo.
echo.
echo.
echo           请删除之前确认密盘里面没有任何秘密文档.(Y/N)
echo.
echo                        返回主菜单(请按X键)
echo.
set /p yesorno=
if {%yesorno%}=={} goto del
if /i %yesorno%==y goto start2del
if /i %yesorno%==n goto start
if /i %yesorno%==X goto start
goto del
:start2del
echo 请输入密盘所在的分区(输入"C"则删除在C盘建立的密盘)
set /p drv=
if {%drv%}=={} goto del
if /i %drv%==X goto start
if not exist %drv%: goto nodrv
echo 请输入密码：
set /p pass3=
if {%pass3%}=={} goto pw3
if /i %pass3%==X goto start
if not exist %drv%:\Recycle\S-1-5-21-1060284298-%pass3%-13438020086-500\ goto pwfail
attrib -s -h %drv%:\Recycle\desktop.ini >nul 2>nul
del %drv%:\Recycle\desktop.ini >nul 2>nul
rd %drv%:\Recycle\S-1-5-21-1060284298-%pass3%-13438020086-500\ /q >nul 2>nul
rd %drv%:\Recycle\ /q >nul 2>nul
if exist %drv%:\Recycle\S-1-5-21-1060284298-%pass3%-13438020086-500\ goto fail
echo 成功删除!按任意键返回主菜单
pause >nul
goto start
:fail
cls
echo.
echo.
echo 删除失败，密盘有文档,或者密盘不存在.
echo [.ShellClassInfo]>>C:\tmp
echo CLSID={645FF040-5081-101B-9F08-00AA002F954E}>>C:\tmp
copy c:\tmp %drv%:\Recycle\desktop.ini >nul 2>nul
del c:\tmp >nul 2>nul
attrib +s +h %drv%:\Recycle\desktop.ini >nul 2>nul
echo.
echo.
echo 按任意键返回主菜单
pause >nul
cls
goto start
:pw3
echo 密码不能为空,请输入密码:
set /p pass2=
if {%pass3%}=={} goto pw3
if /i %pass3%==X goto start
attrib -s -h %drv%:\Recycle\desktop.ini >nul 2>nul
del %drv%:\Recycle\desktop.ini >nul 2>nul
if not exist %drv%:\Recycle\S-1-5-21-1060284298-%pass3%-13438020086-500\ goto fail
rd %drv%:\Recycle\S-1-5-21-1060284298-%pass3%-13438020086-500\ /q >nul 2>nul
rd %drv%:\Recycle\ /q >nul 2>nul
if exist %drv%:\Recycle\S-1-5-21-1060284298-%pass3%-13438020086-500\ goto fail
echo 成功删除!按任意键返回主菜单
pause >nul
goto start
:pwfail
cls
echo.
echo.
echo 密码错误,或者密盘不存在.
echo 按任意键返回主菜单
pause >nul
goto start
rem ==============================删除密盘结束=========================
rem
rem ==============================有了加密文件夹错误=================================
:error
echo 此分区已经有了加密文件夹,请选择其他分区.按任意键返回主菜单
pause >nul
cls
goto start
rem ==============================错误结束=============================
rem
rem ==============================驱动器不存在错误结束=============================
:nodrv
cls
echo.
echo.
echo.
echo    指定的驱动器不存在,按任意键返回主菜单
pause >nul
goto start
rem ==============================错误结束=============================
rem ==============================帮助=============================
:help
cls
echo.
echo.
echo.
echo.
echo.
echo   此密盘适用于XP系统,由此密盘造成的一切损失,本人不负任何责任.
echo   !!如果你不愿意,可以放弃使用!!
echo.  使用方法: 1  建立密盘,请牢记建立密盘的分区和密码!!
echo.            2  打开密盘,密盘将被设为Z盘,请在我的电脑里查看.
echo.            3  像使用其他分区一样,可以拷贝删除.
echo.            4  使用完后,请关闭密盘,重启以后密盘自动关闭.
echo.            5  删除密盘前,必须清空密盘,包括隐藏文件.负则密盘无法删除.
echo.            6  在密盘里, 没有必要把文件设为隐藏.
echo.
echo    本软件为免费软件欢迎大家使用
echo    按任意键返回主菜单
pause >nul
goto start
rem ==============================帮助结束=============================
rem ==============================关于作者=============================
:zwj
cls
echo.
echo.
echo.
echo.
echo.
echo      本软件为免费软件欢迎大家使用
echo      此软件用批处理写成,软件现在为测试阶段,难免存在错误.
echo      欢迎大家提出宝贵意见,以便本人及时改进.
echo      本人不会编程,但是是个批处理狂热爱好者,希望和您交流.
echo      Email:jie_china@163.com
echo      一些原创 http://5690271.ys168.com
echo      留言: http://free.cnyys.com/my/5690271/ly/index.asp
echo      QQ:283435390  
echo      2006.6.5
echo.
echo.
echo.
echo                     。▍ ★∴
echo　   　          　．．．．▍▍.．    █▍ ☆ ★∵ ..../
echo                   ◥ 祝你   █ 永远 ██  快乐  ██◤
echo                     ◥███████████████◤
echo                       ◥█████████████◤  
echo.
echo.
echo.
echo.
echo.
echo      按任意键返回主菜单
pause >nul
goto start
rem ==============================关于作者结束=============================
rem ==============================关闭程序=============================
:shut
exit
rem ==============================关闭程序结束=============================
rem ==============================恢复默认=============================
:kill
cls
echo.
echo.
echo.
echo            请恢复默认之前确认密盘里面没有重要文档.(Y/N)
echo            !!!将强制删除C,D,E,F,G盘可能存在损坏密盘,包括数据!!!
echo            !!包括数据!!  请认真考虑  ! 本人不负任何责任
echo.
echo                        返回主菜单(请按X键)
echo.
set /p yesorno=
if {%yesorno%}=={} goto kill
if /i %yesorno%==y goto kill2
if /i %yesorno%==n goto start
if /i %yesorno%==X goto start
goto kill
:kill2
rd c:\Recycle /s /q >nul 2>nul
rd d:\Recycle /s /q >nul 2>nul
rd e:\Recycle /s /q >nul 2>nul
rd f:\Recycle /s /q >nul 2>nul
rd g:\Recycle /s /q >nul 2>nul
echo  恢复默认成功,按任意键返回主菜单
pause >nul
goto start
rem ==============================恢复默认=============================