中国DOS联盟

在这里的大部分友人，学习或接触脚本

是为了给生活或工作带来效率。

这也是大部分脚本开发者的目的。

而有更好快捷高效的方法不用，而退而求其次，是否有些舍本求末？

我是因为它好玩,简洁才学.不像其他高级语言还类了什么的,烦不烦,完成一个简单任务编译的文件妈的快1M了.
还有它很方便,会用记事本就可以了.

@echo off
for /f "delims=" %%i in ('findstr /i "\.asp" a.txt') do (
set "var=%%i"
setlocal enabledelayedexpansion
set var=!var:"=!
set var=!var:#=!
set var=!var:"=!
set var=!var:^>=!
set var=!var:^<=!
set var=!var:/==!
set var=!var:.asp=#!
call :loop
endlocal
)
cd.>asp.txt
for /f "eol= delims=" %%i in (b.txt) do (
findstr /xc:"%%i" asp.txt >nul 2>nul||echo %%i>>asp.txt
)
del b.txt
start asp.txt
exit
:loop
for /f "delims=#" %%a in ("!var!") do call :lis "%%a"
goto :eof
:lis
for /f "tokens=1* delims==" %%a in ("%~1") do (
if not "%%b"=="" (call :lis "%%b") else >>b.txt echo %%a.asp
)
goto :eof

谢谢各位仁兄的慷慨相助 互联网因为你们才变得精彩
以上我加入了剔除重复行的代码，实现了剔除重复行的
功能，不知道用什么方法能实现输出 a.asp|b.asp|c.asp...的结果

@echo off&setlocal enabledelayedexpansion
for /f "tokens=* delims=:" %%a in ('findstr /n ".asp" a.txt') do (

set var=%%a
set var=!var:/= !
set var=!var:"= !
set var=!var:?= !
set var=!var::= !
set var=!var:^>= !
set var=!var:^<= !

for %%i in (!var!) do (

set aaa=%%i
set aaa=!aaa:~-4!
if !aaa!==.asp set bbb=!bbb!^|%%i

)
)

set bbb=!bbb:~1!
echo =================================================================
echo !bbb!
echo =================================================================
pause