中国DOS联盟

Originally posted by lianjiang2004 at 2007-12-22 01:23 PM:
那需要盘符吗？指定分区号不就完了？
用意不明白，呵呵。

Originally posted by lianjiang2004 at 2007-12-22 12:11 PM:
不知道windows下手动修改盘符后，会是一个什么结果。
最关键的，不知你取得盘符后的目的是什么？
特定机子用？还是通用？
windows下的办法，上面你找的办法应该可以了吧？
还在寻求什么答案？

Originally posted by lianjiang2004 at 2007-12-22 01:42 PM:
何况windows下，你数出的E:,dos也不见得就一定是E：。

对于你的这个问题，本人知道的就这么一点点，无能为力了。

WMIC LOGICALDISK WHERE "FILESYSTEM LIKE '%FAT%' AND DRIVETYPE<4" GET NAME,FILESYSTEM,FREESPACE,SIZE

:: LocBak.bat qzwqzw 2007-12-22

:: 定位系统盘与备份盘分区编号与可用盘符

@echo off & setlocal EnableDelayedExpansion

set cmdline=wmic logicaldisk get deviceid,freespace,size ^| find /n "%SystemDrive%"

for /f "tokens=1,3,4 delims= " %%i in ('"%cmdline%"') do (

    set /a syspartid=%%i-1

    set freesize=%%j

    set size=%%k

    set /a usedsize=!size:~-12,-6! - !freesize:~-12,-6!

    set /a usedsize=usedsize*1000*3/1048/4

)

echo 系统盘为: %SystemDrive%, 分区号为: %syspartid%, 镜像占用约为: %usedsize% MB.



wmic logicaldisk where "drivetype=3" get DeviceID,FileSystem,FreeSpace > %systemdrive%\_drives.txt

set driveid=-1

set dosdriveid=-1

for /f "tokens=1,2,3" %%i in ('type %systemdrive%\_drives.txt') do (

    set /a driveid+=1

    set filesystem=%%j

    if "!filesystem:~0,3!"=="FAT" (

        set freesize=%%k

        set /a freesize=!freesize:~-12,-6! * 1000 / 1048

        set /a dosdriveid+=1

        if 1!freesize! geq 1%usedsize% (

            set BackupDrive=%%i

            set BackupDriveID=!driveid!

            set BackupDOSDriveID=!dosdriveid!

        )

    )

)

if "%BackupDrive%"=="" echo 未找到符合要求的备份盘 & exit /b 1

set BackupDOSDrive=CDEFGHIJKLM

set BackupDOSDrive=!BackupDOSDrive:~%BackupDOSDriveid%,1!:

echo 备份盘为: %BackupDrive% （DOS：%BackupDOSDrive%）, 分区号为: %BackupDriveID%, 剩余空间约为: %freesize% MB.