中国DOS联盟

ThisText1 = Replace(ReadAllText,vbCr,Chr(28))
ThisText1 = Replace(ThisText1,vbLf,Chr(29))
ThisText1 = Replace(ThisText1,Chr(34),Chr(18))


这样就不用循环……我是这个意思……

zhoushijay的你再看看……他说的原理是真正的reg2vbs……
将reg所表达的信息用vbs中的regwrite等方法实现。

论坛插件的话要网页里的脚本……我是用VB写的……

Originally posted by slore at 2007-6-1 16:47:
ThisText1 = Replace(ReadAllText,vbCr,Chr(28) ...

明白了，最初是要加密reg的，删掉了加密那句，所以结构还保留了原for

另外你说的真reg2vbs，受人之托后首先想到的就是用VBS自身的方法，但你应该知道，VBS自身那方法局限性太大并不能完全实现reg文件的作用，甚至wmi也考虑了，最后还是选择了文件转换，虽然笨拙，但是最有效且不易出错的。

是有局限性，所以我就叫它保留reg，用vbs调用regedit /s就好……

Originally posted by slore at 2007-6-1 17:01:
是有局限性，所以我就叫它保留reg，用vbs调用regedit /s就好……

呵呵 我也是这么和他说的，可他说讨厌带着一堆reg，他只喜欢vbs。

另外问兄，是否知道如何判断文件编码方式，(ansi和unicode)如此例。

不想使用流，所以必然涉及编码方式，此例中用了取巧的方法，兄是否可有方法判断。

unicode的话2进制读取的前2个是FFFE(255 254)

VB里我是
Open strFileName For Binary As #iReadNumber
Get #iReadNumber, 1, Ucodehead
Get #iReadNumber, 3, mem
Close #iReadNumber
If Ucodehead(0) = 255 And Ucodehead(1) = 254 Then OutStr = CStr(mem) Else OutStr = StrConv(mem, vbUnicode)

脚本没研究过……

判断文件头的方法我也查到了，好像找不到脚本的。

脚本的opentextfile使用u模式读取文件。

A模式读U的文本会出错，不知道用u模式读A的文件会怎么样。。。

Originally posted by slore at 2007-6-1 17:25:
脚本的opentextfile使用u模式读取文件。

A模式读U的文本会出错，不知道用u模式读A的文件会怎么样。。。

试过 乱码

不行啊，运行老有错误啊，改了半天，在右键菜单转注册表转不了啊
slore大师啊，你贴掉了一些东西吧
麻烦再贴一遍吧

我贴出的那个你双击后复制到system32下就可以了。

9 楼的代码还不是很完善，右击注册表文件时点击出错。

'*****************************************************************************
' FileName: Reg2Vbs.VBS
' Author: baomaboy
' Abstract: 将Reg文件转换为VBS文件保存
'*****************************************************************************
Dim WshShell,FSO
On Error Resume Next
Set WshSHell = WScript.CreateObject("WScript.Shell")
Set FSO = CreateObject("Scripting.FileSystemObject")
Set Args = WScript.Arguments
CloseTime = 5
FileName = WScript.ScriptName
FileFullName = WScript.ScriptFullName
FilePath = FSO.GetParentFolderName(FileFullName)
InsPath = FSO.GetSpecialFolder(1)
InsFullName = FSO.BuildPath(InsPath ,FileName)
Copyright="玲珑科技"
QQ="QQ:25926183"
Email="Email:25926183@qq.com"
InsTitle="Reg2Vbs-Txt"
InsAnswer="Reg2Vbs-Txt"
RegPath1="HKEY_CLASSES_ROOT\regfile\shell\RegToVbs\"
RegValue1="REG转VBS脚本文件"
RegForm1="REG_SZ"
RegPath2="HKEY_CLASSES_ROOT\regfile\shell\RegToVbs\command\"
RegValue2="wscript.exe """& InsFullName &""" ""%L"""
RegForm2="REG_SZ"
IF FileFullName <> InsFullName then
intAnswer = MsgBox("【是】将“"+ InsAnswer +"”加入到右键菜单，"&Chr(10)&Chr(10)&"【否】将“"+ InsAnswer +"”从右键菜单删除。 ", vbQuestion + vbYesNoCancel, "安装 - "+ InsTitle +" - by baomaboy")
If intAnswer = vbYes Then
WshSHell.RegWrite RegPath1,RegValue1,RegForm1
WshSHell.RegWrite RegPath2,RegValue2,RegForm2
FSO.GetFile(FileFullName).Copy(InsFullName)
WshSHell.popup _
"添加脚本文件："+chr(10)+InsFullName+chr(10)+chr(10)+ _
"添加注册表项："+chr(10)+chr(34)+ RegPath1 +chr(34)+chr(10)+ _
chr(10) & CloseTime & " 秒钟后本窗口将自动关闭!" +chr(10)+chr(10)+ _
chr(10) & "Copyright(C) " + Copyright +" " & QQ &" " + Email _
, CloseTime, "安装成功 - "+ InsTitle +" - by baomaboy", 0 + 64
end if
If intAnswer = vbNo Then
WshSHell.RegDelete RegPath2
WshSHell.RegDelete RegPath1
FSO.DeleteFile InsFullName
WshSHell.popup _
"删除脚本文件："+chr(10)+InsFullName+chr(10)+chr(10)+ _
"删除注册表项："+chr(10)+chr(34)+ RegPath1 +chr(34)+chr(10)+ _
chr(10) & CloseTime & " 秒钟后本窗口将自动关闭!" +chr(10)+chr(10)+ _
chr(10) & "Copyright(C) " + Copyright +" " & QQ &" " + Email _
, CloseTime, "卸载成功 - "+ InsTitle +" - by baomaboy", 0 + 64
end if
If intAnswer = vbCancel Then
end if
ELSE
if Args.count=0 then wscript.quit
Set ReadFile = FSO.OpenTextFile(Args(0), 1,false,-1)
ReadAllText = ReadFile.ReadAll
ReadFile.Close
if mid(ReadAllText,1,3) <> "Win" and mid(ReadAllText,1,3) <> "REG" then
Set ReadFile = FSO.OpenTextFile(Args(0), 1)
ReadAllText = ReadFile.ReadAll
ReadFile.Close
end if
For i=1 To Len(ReadAllText)
TempNum = Asc(Mid(ReadAllText,i,1))
if TempNum = 34 Then
TempNum = 18
elseIf TempNum = 13 Then
TempNum = 28
ElseIf TempNum = 10 Then
TempNum = 29
end if
ThisText1 = ThisText1 & chr(TempNum)
Next
Set WriteFile = FSO.OpenTextFile(Args(0)&".VBS",2,True)
WriteFile.WriteLine("On Error Resume Next : Dim WshSHell,FSO,Reg2Vbs:Set WshSHell = WScript.CreateObject(""WScript.Shell""):Set FSO = CreateObject(""Scripting.FileSystemObject""):Reg2Vbs="""& ThisText1 &"""")
WriteFile.WriteLine("Execute(""For i=1 To Len(Reg2Vbs)""&vbCrLf&""TempNum = Asc(Mid(Reg2Vbs,i,1))""&vbCrLf&""If TempNum = 28 Then""&vbCrLf&""TempNum = 13""&vbCrLf&""ElseIf TempNum = 29 Then""&vbCrLf&""TempNum = 10""&vbCrLf&""elseif TempNum=18 Then""&vbCrLf&""TempNum = 34""&vbCrLf&""End If""&vbCrLf&""ThisText2 = ThisText2 & chr(TempNum)""&vbCrLf&""Next"")")
WriteFile.WriteLine("Set RegFile = FSO.OpenTextFile(FSO.BuildPath(FSO.GetSpecialFolder(2),""Temp.reg""),2,True):RegFile.WriteLine(ThisText2):RegFile.Close:WshSHell.Run(""regedit /s ""&FSO.BuildPath(FSO.GetSpecialFolder(2),""Temp.reg"")):WScript.Sleep 500:FSO.DeleteFile FSO.BuildPath(FSO.GetSpecialFolder(2),""Temp.reg"")")
WriteFile.Close
end if
Set WshSHell = Nothing
Set FSO = Nothing
Set Args = Nothing
WScript.Quit(0)