中国DOS联盟

P处理能玩到这个境界，实在是牛人啊
收下来慢慢品味

去掉 call 的效果也是一样.

call 有时的作用是很大的.

@echo off
set a=1
echo %a%
call :aa a
echo %a%
goto :EOF

:aa
call set %1=2
goto :EOF

第一句call是本职工作

第二句call是蛇足之笔

set %1=2

与

call set %1=2

结果没有什么不同

在下面的例子中call是有用的

@echo off

set a=1 2 3

echo %a%

call :aa a

echo %a%

goto :EOF



:aa

call set %1=%%%1%% 4 5 6

goto :EOF

[ Last edited by qzwqzw on 2007-1-29 at 02:03 AM ]

请问 qzwqzw :

1.---------------------------
call set %1=%%%1%% 4 5 6

在代码没有测试运行前,如何判断该使用几次%符号.

2.---------------------------
call set %1=%%%1%% 4 5 6 等效于 set %1=%a% 4 5 6

call set是否有必要性.

[ Last edited by qjbm on 2007-1-29 at 02:23 AM ]

强~~~~~~~够牛的虽然没看懂....汗~~

加多一对 %%

call set %1=%%%1%% 4 5 6
↓
call set a=%%a%% 4 5 6
　　↓
set a=%a% 4 5 6

@echo off
set a=1 2 3
echo %a%
call :aa a
echo %a%
goto :EOF

:aa
call set %1=%%%1%% 4 5 6
goto :EOF

领悟不错的话 call的作用在一定程度上是代替的变量延迟

@echo off

setlocal enabledelayedexpansion

set a=1 2 3

echo %a%

call :aa a

echo %a%

pause

goto :EOF



:aa

set %1=!%1! 4 5 6

goto :EOF

---qjbm-----------

Q1：总的原则是需要解析几次就用几层%

比如call set %1=%%%1%% 4 5 6

在call执行之前命令行已被处理成了类似这样的形式

call set a=%a% 4 5 6

在call执行之后set执行之前命令行则变成这样

set a=1 2 3 4 5 6

Q2:当aa段内使用的是不确定的或者动态变化的变量名时call set是有用的

---PPdos----------------------------------

领悟得不错

不过反过来理解更合适些——

变量延迟l的作用在一定程度上是代替的call

因为call的用法出现要早得多

在没有cmd的时候

dos下就是用call来实现类似C语言的传址特性的

厉害，收藏慢慢学~~~~~~

创意很不错.就是不必要的语句有点多.简化一下.

@echo off & setlocal EnableDelayedExpansion

mode con cols=100 lines=40

title COLOR TIME

call :tnb

set spc=                                                                          

set font=█★●◆□◎◇¤⊙〓



:new

setlocal

color e%RANDOM:~-1%

set rdfont=!font:~%RANDOM:~-1%,1!

set/a a=%random%%%50,b=%random%%%35

set nk=!spc:~0,%a%!

for /l %%a in (0,1,%b%) do echo.

if "%time:~0,1%"==" " set time=0%time:~1%



echo %nk%                  %date%

echo %nk% !%time:~0,1%a:█=%rdfont%! !%time:~1,1%a:█=%rdfont%!     !%time:~3,1%a:█=%rdfont%! !%time:~4,1%a:█=%rdfont%!

echo %nk% !%time:~0,1%b:█=%rdfont%! !%time:~1,1%b:█=%rdfont%!     !%time:~3,1%b:█=%rdfont%! !%time:~4,1%b:█=%rdfont%!

echo %nk% !%time:~0,1%c:█=%rdfont%! !%time:~1,1%c:█=%rdfont%!  · !%time:~3,1%c:█=%rdfont%! !%time:~4,1%c:█=%rdfont%!

echo %nk% !%time:~0,1%d:█=%rdfont%! !%time:~1,1%d:█=%rdfont%!     !%time:~3,1%d:█=%rdfont%! !%time:~4,1%d:█=%rdfont%!

echo %nk% !%time:~0,1%e:█=%rdfont%! !%time:~1,1%e:█=%rdfont%!  · !%time:~3,1%e:█=%rdfont%! !%time:~4,1%e:█=%rdfont%!

echo %nk%             www.cn-dos.net DOSCC WINBY.

ping 127.1 -n 3 >NUL

cls

endlocal

goto :new



:tnb

rem 0-9 数字模样。

set 0a=█████

set 0b=█      █

set 0c=█      █

set 0d=█      █

set 0e=█████



set 1a=  ██   

set 1b=    █   

set 1c=    █   

set 1d=    █   

set 1e=    █   



set 2a=    ███

set 2b=        █

set 2c=█████

set 2d=█        

set 2e=█████



set 3a=    ███

set 3b=        █

set 3c=█████

set 3d=        █

set 3e=█████



set 4a=█        

set 4b=█      █

set 4c=█████

set 4d=        █

set 4e=        █



set 5a=███   

set 5b=█        

set 5c=█████

set 5d=        █

set 5e=█████



set 6a=███   

set 6b=█        

set 6c=█████

set 6d=█      █

set 6e=█████



set 7a=█████

set 7b=█      █

set 7c=        █

set 7d=        █

set 7e=        █



set 8a=█████

set 8b=█      █

set 8c=█████

set 8d=█      █

set 8e=█████



set 9a=█████

set 9b=█      █

set 9c=█████

set 9d=        █

set 9e=  ████

太佩服你们了

哈哈。。。。

很久没有来法帖子了

今天看到了很多好的东西了

正在狂学中啊

*_*

大力支持

数字写得不太好看啊`

顶.............
不过我总觉得缺点什么