China DOS Union

Recently, a task has come down, requiring the production of a CD that can boot both WIN/DOS. To have a bootable CD, there first needs to be a dual-bootable floppy disk. Now I will teach everyone how to make a dual-bootable floppy disk.

1. Copy the three system files of WIN98, IO.SYS, MSDOS.SYS, COMMAND.COM, to the floppy disk. Then, rename the system files IO.SYS, MSDOS.SYS of DOS622 to IO.DOS, MSDOS.DOS respectively and copy them to the floppy disk. Rename COMMAND.COM of DOS622 to COMMDOS.COM and copy it to the floppy disk.

2. Copy the following files to the floppy disk:
(1) An optical drive driver program that you think is universal to the floppy disk (I used ECS_IDE.SYS for Elite 100-speed)
(2) HIMEM.SYS of WIN98
(3) RAMDRIVE.SYS and CHOICE.COM of WIN98 (look for them in the 98 directory using the "Find" command)
(4) SETRAMD.BAT and FINDRAMD.EXE of WIN98 (look for them in the 98 directory using the "Find" command)
(5) A file that can decompress under DOS environment (I used RAR.EXE)
(6) A compressed package made by yourself. The size after decompression of the compressed package cannot exceed the size of the virtual disk, and it should contain MSCDEX.EXE, DOSKEY.COM. None of the EXE and COM files in the package should have restrictions on the DOS version. (For how to solve the DOS version restrictions, please refer to another post I posted at the same time.)
(7) A word processing program that can be edited in DOS. (I used QEDIT.EXE)

3. Edit a CONFIG.SYS, AUTOEXEC.BAT, and MSDOS.SYS file. (My files are attached below)

4. Use a hex editor to edit the IO.DOS file, find the string "COMMAND.COM", and change all found instances to "COMMDOS.COM"

5. If the system still cannot be booted after doing this, execute the "SYS C: A:" command in the 98 environment and then copy the MSDOS.SYS file from 98 to the floppy disk, and re-edit the MSDOS.SYS file.

6. If still unable to boot the system after following step 5, please send me a letter and let me help you analyze the reason.

Appendix:
1. File list of the floppy disk:
IO SYS 224,150 06-19-98 20:01 IO.SYS
MSDOS SYS 1,175 09-05-99 22:52 MSDOS.SYS
CHOICE COM 1,754 04-25-98 18:35 CHOICE.COM
AUTOEXEC BAT 1,808 09-06-99 23:36 AUTOEXEC.BAT
FINDRAMD EXE 6,855 06-18-98 20:01 FINDRAMD.EXE
COMMDOS COM 54,645 05-31-94 6:22 COMMDOS.COM
EBD RAR 621,686 08-05-99 16:45 EBD.RAR
HIMEM SYS 33,191 07-17-98 13:52 HIMEM.SYS
IO DOS 40,774 09-04-99 20:00 IO.DOS
COMMAND COM 94,282 06-19-98 20:01 COMMAND.COM
MSDOS DOS 38,138 09-04-99 19:34 MSDOS.DOS
Q EXE 52,876 11-30-96 18:45 Q.EXE
RAM SYS 12,663 06-19-98 20:01 RAM.SYS
RAR EXE 104,546 01-02-99 0:27 RAR.EXE
SETRAMD BAT 352 09-05-99 21:05 SETRAMD.BAT
ECS_IDE SYS 22,320 08-09-96 13:28 ECS_IDE.SYS
CONFIG SYS 140 09-05-99 23:16 CONFIG.SYS

2. Content of my CONFIG.SYS file:
DEVICE=A:\HIMEM.SYS /TESTMEM:OFF
FILES=50
DOS=HIGH,UMB
DEVICEHIGH=A:\ECS_IDE.SYS /D:MYCDROM
DEVICEHIGH=A:\RAM.SYS /E 4096
LASTDRIVE=Z

3. Content of my AUTOEXEC.BAT file:
@ECHO OFF
SET DIRCMD=/O:N
SET LGLDRV=22 V 21 U 20 T 19 S 18 R 17 Q 16 P 15 O 14 N 13
SET LGLDRV=%LGLDRV% M 12 L 11 K 10 J 9 I 8 H 7 G 6 F 5 E 4 D 3 C
CALL SETRAMD.BAT %LGLDRV%

:START
CLS
VER
ECHO ******************************************
ECHO 1. Start MS-Windows 98 Batch File
ECHO 2. Start MS-DOS 6.22 Batch File
ECHO 3. Run GHOST for setup Windows 98
ECHO ******************************************
CHOICE /C:123 /N Which one(1,2,3)?
IF ERRORLEVEL 3 GOTO GHOST
IF ERRORLEVEL 2 GOTO DOS
IF ERRORLEVEL 1 GOTO WIN
GOTO START

:GHOST
%CDROM%:
CD\GHOST
GHOST.EXE
GOTO START

:DOS
SET VERSION=DOS
COPY A:\COMMDOS.COM %RAMD%:\COMMAND.COM >NUL
COPY A:\*.DOS %RAMD%:\*.SYS >NUL
SET COMSPEC=%RAMD%:\COMMAND.COM
IF NOT %RAMD%==* GOTO CONU
SET COMSPEC=A:\COMMDOS.COM
GOTO CONU

:WIN
SET VERSION=WIN98
COPY A:\COMMAND.COM %RAMD%: >NUL
COPY A:\IO.SYS %RAMD%: >NUL
COPY A:\MSDOS.SYS %RAMD%: >NUL
SET COMSPEC=%RAMD%:\COMMAND.COM
IF NOT %RAMD%==* GOTO CONU
SET COMSPEC=A:\COMMAND.COM

:CONU
PATH=%RAMD%:\;A:\;%CDROM%:\WARE
SET LGLDRV=
COPY Q.EXE %RAMD%: >NUL
COPY RAR.EXE %RAMD%: >NUL
COPY EBD.RAR %RAMD%: >NUL
%RAMD%:
RAR.EXE E -Y EBD.RAR
LH UCMOUSE.COM >NUL
LH DOSKEY.COM /INSERT
LH MSCDEX.EXE /D:MYCDROM /L:%CDROM%
CLS
ECHO Found RAMDRIVE = %RAMD%
ECHO Found CDROM = %CDROM%
GOTO AUTO

:NORAMD
PATH=A:\;%CDROM%:\WARE
SET LGLDRV=
CLS
ECHO Found RAMDRIVE = NONE
ECHO Found CDROM = ?, Name = MYCDROM
ECHO Not load "DOSKEY.COM" & "MSCDEX.EXE"

:AUTO
IF NOT %RAMD%==C GOTO END
%CDROM%:
CD\DM
COPY *.* %RAMD%:\ >NUL
%RAMD%:
ECHO Not found HardDisk !! Run The DM !!

:END
ECHO.
IF %VERSION%==WIN98 ECHO MS-Windows 98 Start......successfully.
IF %VERSION%==DOS ECHO MS-DOS 6.22 Start......successfully.
VER

4. Header of my MSDOS.SYS file:
[Paths]
WinDir=
WinBootDir=
HostWinBootDrv=C

[Options]
BootDelay=3
BootMenuDefault=5
BootMenuDelay=10
BootWarn=0
BootKeys=1
BootMulti=1
BootMenu=1
BootWin=1
BootGUI=0
LoadTop=1
Logo=1
AutoScan=1
BootFailSafe=0
DoubleBuffer=1
DblSpace=0
DrvSpace=0
NetWork=0
WinVer=4.10.1998

5. Content of my SETRAMD.BAT file:
@echo off
set RAMD=
set CDROM=
echo Cheaking your RAM-DRIVE. Please wait...

findramd.exe

if errorlevel 255 goto no_ramdrive
goto do_shift

:loop
if errorlevel %1 goto no_shift

:do_shift
set cdrom=%2
shift
shift
if not %1*==* goto loop
goto no_ramdrive

:no_shift
set ramd=%2
goto success

:no_ramdrive
set RAMD=*
:success

--
Maybe it should be renamed to Tide. Without money and time, I can only limit to surfing the Internet once a month.
You are welcome to write to me, but if you want to receive letters, you can only wait patiently.
"Road is long and far, I will keep searching up and down!"