China DOS Union

@echo off&setlocal enabledelayedexpansion

set key1=HKCU\Keyboard Layout\Preload

set key2=HKLM\SYSTEM\CurrentControlSet\Control\Keyboard Layouts

:begin

cls

for /f "tokens=1-4" %%a in ('reg query "%key1%"^|findstr "REG_SZ"^|sort') do (

  for /f "tokens=1,3*" %%d in ('reg query "%key2%\%%c"^|findstr "Text"') do (

    set /a n+=1

    echo %%a %%c %%f

  )

)

echo.

set /p num=Please enter the serial number before the input method you want to delete:

for /l %%a in (%n% -1 1) do (

  if "%%a"=="%num%" set var=A

)

if "%var%"=="A" goto delime

cls

echo Incorrect input, press any key to re - enter a serial number!

pause>nul

goto begin



:delime

cls

echo Operating, please wait...

(reg export "%key1%" Restore original settings.reg

reg delete "%key1%" /f /v "%num%"

for /f "tokens=1,2*" %%i in ('reg query "%key1%"^|findstr "REG_SZ"') do (

   set /a m+=1

   reg add "!key1!" /f /v !m! /d "%%k"

))>nul

cls

echo Input method deleted successfully! The remaining input methods (take effect after logging off or restarting):

echo.

for /f "tokens=1-4" %%a in ('reg query "%key1%"^|findstr "REG_SZ"^|sort') do (

  for /f "tokens=1,3*" %%d in ('reg query "%key2%\%%c"^|findstr "Text"') do (

    echo %%a %%c %%f

  )

)

ping 127.1 -n ^6>nul

@echo off

set "b="

set "ime=e0010804"

for /f "tokens=1" %%a in ('reg query "HKCU\Keyboard Layout\Preload"^|find /i "%ime%"') do set "b=%%a"

if not "%b%"=="" (reg delete "HKCU\Keyboard Layout\Preload" /f /v "%b%" >nul

) else (

echo No input method with ID "%ime%" is found!&&ping 0 /n ^5>nul&exit)



for /f "tokens=1,2*" %%c in ('reg query "HKCU\Keyboard Layout\Preload"^|find "REG_SZ"') do (

  set /a n+=1

  call reg add "HKCU\Keyboard Layout\Preload" /f /v "%%n%%" /t REG_SZ /d "%%e" >nul

)

echo Successfully deleted the input method with code "%ime%"! It takes effect only after logging off or restarting.&&ping 0 /n ^5>nul&exit