China DOS Union

Combined with batch processing, shortcuts can be used to create and modify shortcuts in batches. But in practice, a problem is encountered. That is, if there are paths with spaces in the /P parameter or /W parameter or /I parameter when creating or modifying shortcuts with shortcuts, the creation of the shortcut will fail. And if there are spaces in the path of the shortcut parameter, it itself requires that the path be enclosed in quotes, thus causing a conflict. How to solve this problem? For example, a shortcut with the target "D:\UGS\NX 6.0\MACH\auxiliary\cls2clf.bat", the parameter "D:\UGS\NX 6.0\", the working path "D:\UGS\NX 6.0\MACH\auxiliary\", and the icon "D:\UGS\NX 6.0\UGTO2D\ugto2d.ico,0" will fail when created with shortcuts.

The following is the batch file and the shortcut I packaged. Please test how to solve this problem. The BS in the following program is a character replacement tool to replace any specified characters.

@ECHO OFF

REM When the file path is changed, batch replace (repair) shortcuts. The variable LNKPATH is the path of the shortcut folder to be replaced; OLDPATH is the original file installation path; NEWPATH is the new moved path

REM Suppose that after installing CATIA, the file path is moved or a green CATIA is to be made, then the shortcut path should be changed accordingly



SET LNKPATH="%ALLUSERSPROFILE%\「开始」菜单\程序\【HYSOFT】\UGSNX6绿色精简版"

SET OLDPATH="D:\UGS

SET NEWPATH="D:\PROGRAMS PROFILES\UGS"



SET PATH=%CD%;%CD%\GTOOLS\;%PROGRAMFILES%\WINRAR;%PATH%

IF NOT EXIST ".\GTOOLS\BS.exe" SET ERR=The character replacement tool is missing in the installation support directory, and the installation program cannot continue&&GOTO:ERROR

IF NOT EXIST ".\GTOOLS\SC.exe" SET ERR=The shortcut creation tool is missing in the installation support directory, and the installation program cannot continue&&GOTO:ERROR

FOR /F "DELIMS=" %%I IN ('DIR /B/S "%LNKPATH%\*.LNK"') DO (

     SC /F:"%%I" /A:Q>"%TEMP%\SCUT.TXT"

     BS "%TEMP%\SCUT.TXT" %OLDPATH% %NEWPATH% /I>NUL&CLS

     setlocal enabledelayedexpansion

     FOR /F "TOKENS=1,* DELIMS==" %%A IN (%TEMP%\SCUT.TXT) DO CALL SET %%A=%%B

     IF EXIST "!TargetPath!" SC.EXE /F:"%%I" /A:E /T:"!TargetPath!" /P:"!Arguments!" /W:"!WorkingDirectory!" /I:"!IconLocation!" /D:"鸿越软件"

     endlocal

)

SET ERR=Replacement and repair completed, thank you for using the tool made by Hongyue Software&&GOTO:ERROR

:ERROR

>"%TEMP%\Temp.vbs"   Echo intAnswer = MsgBox("%ERR%" , vbYes, "Hongyue Software kindly reminds you!")

cscript //nologo "%TEMP%\Temp.vbs"

EXIT

[ Last edited by HUNRYBECKY on 2008-8-4 at 08:23 AM ]

No one answered, so I'll bump it up myself.

Hehe, why are all the experts lurking today. Still waiting.

Experts are really good at lurking, and no one has visited yet.

I'll give it a bump myself. I don't know if this question is too simple or for some other reason, but居然 no one has answered...

I don't know if this VBS supports spaces, but in some cases I'd rather create a .lnk file and release it directly using the copy method, package it with iexpress, and execute it with psexec. Scripts can be annoying with a bunch of ABCs sometimes

'Create autoshutdown Desktop icon

Set Shell = CreateObject("WScript.Shell")

DesktopPath = Shell.SpecialFolders("AllUsersDesktop")

Set link = Shell.CreateShortcut(DesktopPath & "\自动关机.lnk")

link.Arguments = "-s -t 0 -f"

link.Description = "Automatically shut down the computer"

'link.HotKey = "CTRL+ALT+SHIFT+E"

link.IconLocation = "%SystemRoot%\system32\shutdown.exe"

link.TargetPath = "%SystemRoot%\system32\shutdown.exe"

link.WindowStyle = 7

link.WorkingDirectory = "%systemroot%"

link.Save



Const ALL_USERS_DESKTOP = &H19&



Set objShell = CreateObject("Shell.Application")

Set objFolder = objShell.NameSpace(ALL_USERS_DESKTOP)



Set objFolderItem = objFolder.ParseName("自动关机.lnk")

Set objShortcut = objFolderItem.GetLink



objShortcut.SetIconLocation "%systemroot%\System32\SHELL32.dll", 27

objShortcut.Save

Thanks dato, this VBS script also can't achieve special paths with parameters. The COPY method can't achieve what I requested because I automatically replace the corresponding paths according to the software installation directory. Because some software needs to create a large number of shortcuts. If I first use RAR to compress and then automatically unpack to the corresponding path, if the extraction directory is the same as the source installation directory, then automatically skip; if not the same, then use the SHORTCUT command to automatically replace the corresponding path.

I've tried using WINRAR to pack, but I still can't create this special parameter shortcut. Really disappointed.

The problem has been completely solved. After searching frantically on foreign websites, I found that shortcut has a special escape character \, heh. To keep the double quotes ", you just need to add \ in front of it. Since I found that some shortcut paths also have a \ symbol later, such as "D:\UGS\", these might cause conflicts, so the batch processing below made corresponding treatments to avoid this situation. After testing, it can completely and correctly handle shortcuts with many complex parameters.

@ECHO OFF

REM Batch replacement (repair) of shortcuts when the file path is changed. The variable LNKPATH is the path of the shortcut folder to be replaced; OLDPATH is the original file installation path; NEWPATH is the new move path

REM Suppose that after installing CATIA, the file path is moved or a green CATIA is to be made, then the shortcut path should be changed accordingly



SET LNKPATH="D:\UGS\GTOOLS\SCUT"

SET OLDPATH="D:\UGS"

SET NEWPATH="D:\Program Files\UGS"



SET PATH=%CD%;%CD%\GTOOLS\;%PROGRAMFILES%\WINRAR;%PATH%

IF NOT EXIST ".\GTOOLS\BS.exe" SET ERR=The character replacement tool is missing in the installation support directory, and the installation program cannot continue&&GOTO:ERROR

IF NOT EXIST ".\GTOOLS\SC.exe" SET ERR=The shortcut creation tool is missing in the installation support directory, and the installation program cannot continue&&GOTO:ERROR

FOR /F "DELIMS=" %%I IN ('DIR /B/S "%LNKPATH%\*.LNK"') DO (

     SC /F:"%%I" /A:Q>"%TEMP%\SCUT.TXT"

     BS "%TEMP%\SCUT.TXT" %OLDPATH% %NEWPATH% /I

     BS "%TEMP%\SCUT.TXT" """ "\\"" /I>NUL&CLS

     BS "%TEMP%\SCUT.TXT" "\\\\" "\\" /I>NUL&CLS

     setlocal enabledelayedexpansion

     FOR /F "TOKENS=1,* DELIMS==" %%A IN (%TEMP%\SCUT.TXT) DO CALL SET %%A=%%B

     IF DEFINED Arguments IF "!Arguments:~-1!"=="\" (SET Arguments=!Arguments!\)

     IF DEFINED WorkingDirectory IF "!WorkingDirectory:~-1!"=="\" (SET WorkingDirectory=!WorkingDirectory!\) ELSE (SET WorkingDirectory=!WorkingDirectory!\\)

     SC.EXE /F:"%%I" /A:E /T:"!TargetPath!" /P:"!Arguments!" /W:"!WorkingDirectory!" /I:"!IconLocation!" /D:"Hongyue Software" >NUL

     endlocal

)

SET ERR=Replacement and repair are completed. Thank you for using the tool made by Hongyue Software&&GOTO:ERROR

:ERROR

>"%TEMP%\Temp.vbs"   Echo intAnswer = MsgBox("%ERR%" , vbYes, "Hongyue Software Warm Reminder You!")

cscript //nologo "%TEMP%\Temp.vbs"

IF EXIST "%TEMP%" DEL /F/S/Q/A "%TEMP%\*.*">NUL

EXIT