China DOS Union

' *==============================================================================*

' * CMD Command Line Encoding Conversion Tool supports GB2312, UTF-8, Unicode, BIG5... with drag-and-drop and save-as functionality *

' * CodeChange.vbs     BY: yongfa365 http://www.yongfa365.com         2007-10-04 *

' * GB2Ue.vbs          BY: fastslz   http://bbs.cn-dos.net            2007-12-03 *

' *==============================================================================*

aCode = "GB2312"

bCode = "Unicode"

Show = "This script only supports conversion from " & aCode & " to " & bCode & ". Please drag a single file to be converted onto this file!    "

Usage1 = "Syntax 1: GB2Ue.vbs  (Directly replace original file mode)"

Usage2 = "Syntax 2: GB2Ue.vbs    /Y"

Usage3 = "        If the target new file already exists, using the /Y parameter will directly replace it without prompting!  "

Usage4 = "Command Line Encoding Conversion Tool BY: fastslz"



Set objArgs=WScript.Arguments

Set fso=CreateObject("Scripting.FileSystemObject")

if objArgs.Count=0 Then

   MsgBox Show &vbCrLf&vbCrLf& Usage1 &vbCrLf& Usage2 &vbCrLf& Usage3, vbInformation, Usage4

   Wscript.Quit

end if

if not objArgs.Count < 3 Then

       Options="/y"

       ignoring = StrComp(objArgs(2), Options, vbTextCompare)

       if ignoring = 0 Then

          Sourcefile=objArgs(0)

          Getfile=objArgs(1)

          else

          MsgBox "Too many files or parameters. For batch processing via drag-and-drop, please use ANSI2Unicode.vbs     ", vbInformation, "Program Terminated Unexpectedly"

          Wscript.Quit

       end if

       else

       if not objArgs.Count < 2 Then

          Sourcefile=objArgs(0)

          Getfile=objArgs(1)

          if fso.FileExists(objArgs(1)) then

             Choice = MsgBox ("File to process: “" + Sourcefile + "” ==> Target file: “" + Getfile + "”    " & vbCrLf & "Target file already exists. Overwrite existing file? “" + objArgs(1) + "”    ", vbQuestion + vbYesNo, "Overwrite?")

             if Choice = vbYes Then

                Getfile=objArgs(1)

                else

                Wscript.Quit

             end if

          end if

          else

          Sourcefile=objArgs(0)

          Getfile=objArgs(0)

       end if

end if



Call CheckCode (Sourcefile)

Call WriteToFile(Getfile, ReadFile(Sourcefile, aCode), bCode)

Wscript.Quit



Function ReadFile (Sourcefile, CharSet)

    Dim Str

    Set stm = CreateObject("Adodb.Stream")

    stm.Type = 2

    stm.mode = 3

    stm.charset = CharSet

    stm.Open

    stm.loadfromfile Sourcefile

    Str = stm.readtext

    stm.Close

    Set stm = Nothing

    ReadFile = Str

End Function



Function WriteToFile (Getfile, Str, CharSet)

    Set stm = CreateObject("Adodb.Stream")

    stm.Type = 2

    stm.mode = 3

    stm.charset = CharSet

    stm.Open

    stm.WriteText Str

    stm.SaveToFile Getfile,2

    stm.flush

    stm.Close

    Set stm = Nothing

End Function



Function CheckCode (Sourcefile)

    Dim slz

    set slz = CreateObject("Adodb.Stream") 

    slz.Type = 1

    slz.Mode = 3

    slz.Open

    slz.Position = 0

    slz.Loadfromfile Sourcefile

    Bin=slz.read(2)

    if AscB(MidB(Bin,1,1))=&HEF and AscB(MidB(Bin,2,1))=&HBB Then

       Codes="UTF-8"

       elseif AscB(MidB(Bin,1,1))=&HFF and AscB(MidB(Bin,2,1))=&HFE Then

              Codes="Unicode"

              else

              Codes="GB2312"

    end if

    if not aCode = Codes Then

           MsgBox "File to process: “" & Sourcefile & "”" & vbCrLf & "The original encoding of this file is not " & aCode & ". This script only supports conversion from " & aCode & " to " & bCode & "!    ", vbInformation, "Terminated Due to Error"

           WScript.Quit

    end if

    slz.Close

    set slz = Nothing

End Function

Demo

echo "ABCDE &!@#$ ^<>() %% abcde Test!"> "Before Processing.txt"
GB2Ue.vbs "Before Processing.txt" "After Processing.txt" /y
Ue2U8.vbs "After Processing.txt"
U82GB.vbs "After Processing.txt"
GB2U8.vbs "After Processing.txt"
U82Ue.vbs "After Processing.txt"
Ue2GB.vbs "After Processing.txt"
@echo After 6 processing steps, "After Processing.txt" and "Before Processing.txt" still have the same encoding

Encoding Query Tool QueryCode.vbs
http://www.cn-dos.net/forum/viewthread.php?tid=36012&fpage=1&highlight=

[ Last edited by fastslz on 2007-12-9 at 11:24 PM ]

Thanks for sharing, let's study it.

Function WriteToFile (Getfile, Str, CharSet)
Set stm = CreateObject("Adodb.Stream")
stm.Type = 2
stm.mode = 3
stm.charset = CharSet
stm.Open
stm.WriteText Str
stm.SaveToFile Getfile,2
stm.flush
stm.Close
Set stm = Nothing
End Function

It is indeed this section, heh.

Update:
Enhanced usability to prevent unnecessary losses caused by user misoperations, and added a function to verify the correctness of the input file encoding.

Expert, your skills are excellent. I will visit here more often in the future. I haven't used DOS for many years, so I've become quite rusty.

Let's try downloading it~~ I've been looking for similar tools for a long time~ Thank you

Who has time to write a pure DOS version? In the past two days, I tried to browse emails under DOS, and the full page of MIME characters is really worrying.

The function CheckCode can only judge files with BOM

In the UCS encoding, there is a character called "ZERO WIDTH NO-BREAK SPACE" whose encoding is FEFF. And FFFE is a non-existent character in UCS, so it should not appear in actual transmission. The UCS specification suggests that we transmit the character "ZERO WIDTH NO-BREAK SPACE" before transmitting the byte stream. Then if the receiver receives FEFF, it indicates that this byte stream is Big-Endian; if it receives FFFE, it indicates that this byte stream is Little-Endian. Therefore, the character "ZERO WIDTH NO-BREAK SPACE" is also called BOM.

UTF-8 does not need BOM to indicate the byte order, but can use BOM to indicate the encoding method. The UTF-8 encoding of the character "ZERO WIDTH NO-BREAK SPACE" is EF BB BF. So if the receiver receives a byte stream starting with EF BB BF, it knows that this is UTF-8 encoding.

Windows uses BOM to mark the encoding method of text files.

There are many problems with BOM in many places. I don't like this BOM.

When replying to the 9th floor, I was in a hurry and didn't notice that it was actually the expert柳永法(yongfa365). I have benefited a lot from your Blog, and I have also learned a lot from your CodeChange.vbs code.

Originally posted by qzwqzw at 2007-12-20 20:01:
Who has time to write a pure DOS version?

I've been trying to browse emails under DOS these past two days, and the full page of MIME characters is really worrying me.

Pure DOS: P pure CMD? Give a thought.

Good stuff, I've downloaded it, thanks for sharing

Great! This is really a good thing

Thank you. Can the owner help me change the extension of the converted file to htm at the same time? Because my Sony Ericsson mobile phone can view UTF-8 format htm (for reading books).

[ Last edited by 35799 on 2008-3-7 at 01:46 AM ]