China DOS Union

I want to use batch processing to generate a password dictionary. The user enters the password length, and an automatic dictionary file dictionary.txt is generated. If 3 is entered, the content of dictionary.txt is as follows:

000
001
002
...
998
999

If 4 is entered, the content of dictionary.txt is as follows:

0000
0001
0002
....
9998
9999

Hope an expert can give guidance.

[ Last edited by HAT on 2008-11-12 at 21:39 ]

```@echo off
set /p num=input a number:
for /l %%i in (1,1,%num%) do call set max=%%max%%9
call set max=%%max:~0,%num%%%
for /l %%i in (0,1,%max%) do set out=000000000000000000000000%%i&&call echo %%out:~-%num%%%>>dictionary.txt

pause```

Thanks, Brother wudixin96.
I will think about pure alphabet passwords and alphanumeric mixed passwords based on this.
I will come to ask for advice if there is any problem.

Almost forgot to add points
Guilty, guilty
Added it up

Also made one, only supports below 9 digits, just for fun嘛

@echo off &setlocal enabledelayedexpansion

title code by hi.baidu.com/523066680

set /p "n=Enter the number of digits, maximum is 9: "



for /l %%x in (1,1,%n%) do (

  set fo="for %%%%x in (0 1 2 3 4 5 6 7 8 9) do (!fo!"

  set end="!end!)"

  set echo=!echo! %%%%x

)



%fo:"=%

          echo %echo%

%end:"=%

pause

(六) The building speed is so fast, I can't understand.
I practice with a stupid way:
@echo off
cd.>dictionary.txt
set /p in=key a number:
set b=%in%
:ex1
if %b% gtr 0 set /a b-=1&set max=9%max%&goto :ex1
set ba=%max:9=0%
:ex2
if %b% leq %max% set ok=%ba%%b%&call echo %%ok:~-%in%%%>>dictionary.txt&set /a b+=1&goto ex2
type dictionary.txt&pause&goto :eof

In terms of efficiency, it should be the simple n loops on the 6th floor that are the fastest. For the 7th floor, if each number has to go through an if check, the efficiency can be imagined. Inspired by the zero padding on the 7th floor, I also came to practice, and the efficiency should be very close to the 6th floor.

@echo off

setlocal enabledelayedexpansion

set /p n=key a number:

for /l %%i in (%n%,-1,1) do (

    set z=&set min=&set max=

    for /l %%j in (2,1,%%i) do set z=0!z!

    for /l %%j in (%n%,-1,%%i) do (set/a min=max+1&set max=9!max!)

    if !max! equ 9 set/a min=0

    for /l %%j in (!min!,1,!max!) do echo !z!%%j

)

[ Last edited by linee on 2009-1-4 at 18:59 ]

Ha. What the 6th floor said is that two variables are used respectively to record the number of layers of for and the number of closing parentheses.

The characters represented by the %var% expression are then executed as commands.

I regard this as an advantage of batch processing.

1. When the number of embedded sentences is unknown, temporary embedding can be carried out by string processing.
2. A lot of characters are saved, just like above, where multi-layer For sentences are all put in variables.

Refer to an article that has been posted.
http://www.cn-dos.net/forum/viewthread.php?tid=45240

[ Last edited by 523066680 on 2009-8-4 at 08:52 ]

```batch
@echo off&setlocal enabledelayedexpansion&set y=9999999999
set/p n=input a number:
for /l %%i in (1,1,!y:~-%n%!) do (set qq=0000000000%%i
echo !qq:~-%n%!)
pause
```