China DOS Union

I want to make the background color and text color of the cmd window change in a cycle one by one (I want to choose a good effect configuration from it). How to write it with for?
After each color change, choose whether to continue the experiment and output the background and text color codes of the current window:
The current background and text color, for example, output 0a
%a% %b% respectively store
Background color and text color, that is like this: select two combinations from 0, 1, 2, 3...9, a, b, c, d, e, f one by one and give them to a, b respectively until all combinations are selected, then use
color %a%%b%
to for loop to choose whether to continue the experiment and display the current configuration

[ Last edited by gskys123 on 2007-1-15 at 12:03 PM ]

Version 1:

@echo off

setlocal enabledelayedexpansion

set str=0123456789abcdef



for /l %%i in (0,1,15) do (

    for /l %%j in (0,1,15) do (

        if %%i neq %%j (

            cls

            echo Current color code is: color !str:~%%i,1!!str:~%%j,1!

            color !str:~%%i,1!!str:~%%j,1!

            pause

        )

    )

)

Version 2:

@echo off

for %%i in (0 1 2 3 4 5 6 7 8 9 a b c d e f) do (

    for %%j in (0 1 2 3 4 5 6 7 8 9 a b c d e f) do (

        if %%i neq %%j (

            cls

            echo Current color code is: color %%i%%j

            color %%i%%j

            pause

        )

    )

)

[ Last edited by namejm on 2007-1-15 at 12:23 AM ]

Test the code of namejm, and find: no color such as :10 12 13 14

At that time, I only thought about the situation where numbers come before letters and ignored other situations, making a low-level mistake. Sweat. The second floor has been updated.

Thanks namejm!! ;)
This way, my understanding of the usage of for has deepened a bit!
Thank you!!