China DOS Union

　　Given a plain numeric text file, one record per line, with no blank lines, find the sums of all different combinations of this column of numbers (combinations with the same line numbers but different value order are treated as the same combination). The required output format is n1+n2+n3=sum.

　　For example, if the text content is:

1

2

3

4

5

　　Then the required output format is (the order may be shuffled):

1+2=3

1+3=4

1+4=5

1+5=6

2+3=5

2+4=6

2+5=7

3+4=7

3+5=8

4+5=9

1+2+3=6

1+2+4=7

1+2+5=8

1+3+4=8

1+3+5=9

1+4+5=10

2+3+4=9

2+3+5=11

3+4+5=12

1+2+3+4=10

1+2+3+5=11

1+3+4+5=13

2+3+4+5=14

1+2+3+4+5=15

　　1+2+3=6 and 2+1+3=6 are treated as the same combination.

[ Last edited by namejm on 2006-12-29 at 09:55 PM ]

What brother namejm means is that each line in a text file has a number (about twenty numbers in all), and all possible sums of these numbers need to be calculated.

test.txt

1

2

3

The required result after processing with a batch file is:

1+2=3

1+3=4

2+3=5

1+2+3=6

@echo off

SETLOCAL ENABLEDELAYEDEXPANSION

for /f "tokens=1,2 delims=:" %%i in ('findstr /n . 1.txt') do (

set /a n%%i=%%j

set /a nnum=%%i

)

if "nnum" == "1" echo %n1%=%n1% && goto :eof

:num

set sum=

set sumf=

set /a num+=1

set /a num_1=%num%+1

set /a nnum_1=%nnum%-1

for /l %%i in (%num% 1 %nnum%) do (

call set /a sum=!sum!+%%n%%i%%

call set sumf=!sumf!+%%n%%i%%

if "!sumf!" == "+!sum!" (set sumf=!sumf:~1!) ELSE (echo !sumf!=!sum!)

)

for /l %%i in (%num_1% 1 %nnum_1%) do (

call set /a sum=!sum!-%%n%%i%%

call set sumf=!sumf:+%%n%%i%%=!

echo !sumf!=!sum!)

)

if %num% lss %nnum% goto :num

pause

The code is not complete. I don't know how to write the replacement below, hope everyone can point it out.
call set sumf=!sumf:+%%n%%i%%=!

Bump it up! I'd like to know too.

There are quite a few errors in brother a9319751's code. The errors I found include missing combinations, duplicates, incorrect partial calculation results, and so on.

The problem raised by brother namejm is extremely complicated. I still haven't found a good method. The best I can do right now still misses 4 combinations. I know where the problem is, but I can't turn it into an effective batch statement.
I'll post the code first; I'll improve it later when I have time. Hope to see some brother finish this problem.

1. @echo off
   
2. setlocal ENABLEDELAYEDEXPANSION
   
3. set n=0
   
4. set file=%1
   
5. set yinzi=
   
6. for /f "delims=" %%a in (%file%) do (
   
7. set /a n+=1
   
8. call :sub %%a !n!
   
9. )
   
10. goto :EOF
    
11. 
    
12. :sub
    
13. for /f "tokens=1,2* delims=:" %%a in ('more +%2 %file%^|findstr /n .') do (
    
14. call set yinzi%%a=%1
    
15. for /l %%m in (1,1,%%a) do (
    
16. call set yinzi%%m=!!yinzi%%m!! + %%b
    
17. call set /p x=!!yinzi%%m!! = <nul
    
18. call set /a x=!!yinzi%%m!!
    
19. echo !x!
    
20. )
    
21. )
    
22. goto :EOF
    

Posted by 无奈何 2006-12-30 16:25

Output result:

1 + 2 = 3

1 + 2 + 3 = 6

1 + 3 = 4

1 + 2 + 3 + 4 = 10

1 + 3 + 4 = 8

1 + 4 = 5

1 + 2 + 3 + 4 + 5 = 15

1 + 3 + 4 + 5 = 13

1 + 4 + 5 = 10

1 + 5 = 6

2 + 3 = 5

2 + 3 + 4 = 9

2 + 4 = 6

2 + 3 + 4 + 5 = 14

2 + 4 + 5 = 11

2 + 5 = 7

3 + 4 = 7

3 + 4 + 5 = 12

3 + 5 = 8

4 + 5 = 9

Missing items:

1+2+4=7

1+2+5=8

1+3+5=9

2+3+5=11

I'll also post a piece of code whose efficiency isn't very high:

@echo off

setlocal enabledelayedexpansion



for /f %%i in (test.txt) do (

   set flag=%%i



REM ===========================

REM Delete duplicate lines;

Rem ===========================

   if not defined !flag! (

      set %%i=A



REM ===========================

REM Get the number of file lines;

Rem ===========================



      set /a CYC_num_+=1

      set str=%%i !str!))



REM ===========================

REM Set the loop count for the next for loop;

Rem ===========================

set /a CYC_num=%CYC_num_%-3







call :test str

for /l %%i in (1 1 %CYC_num%) do call :test Res

pause>nul

:test 

for /f "delims== tokens=2" %%i in ('set %1') do (

   set tem=%%i

   for %%a in (%%i) do (

      set flag=!tem:%%a =!

      if not defined !flag! (

          set var=

          set num=

          set /a a+=1

          set Res!a!=!tem:%%a =!

          call :Get_SUM %%Res!a!%%

          set !flag!=A

      )

   )

)

goto :eof



:Get_SUM

    if not "%1"=="" (

        set var=%1+!var!

        set /a num+=%1

        shift

        goto :Get_SUM) 

     echo !var:~0,-1!=!num!

Explanation: the numbers in the text file test.txt need to occupy at least three non-duplicate lines!

Originally posted by 无奈何 at 2006-12-31 05:38 AM:
There are quite a few errors in brother a9319751's code. The errors I found include missing combinations, duplicates, incorrect partial calculation results, and so on.

The problem raised by brother namejm is extremely complicated. I still haven't found a good method..

I'm very interested in this problem. Could you explain the train of thought?
Other experts can explain it too,
thanks in advance here.

For this kind of problem, using a recursive algorithm makes the idea much clearer

Although multi-level loops can also do it, they are very hard to write and read

Below is an example of recursion

@echo off

setlocal enabledelayedexpansion



for /f %%n in (test.txt) do (

    set /a i+=1

    set gn!i!=%%n

)

set gn

pause



for /l %%j in (1,1,%i%) do call :rec %%j

pause

goto :eof



:rec

setlocal



call set tmp=%%gn%1%%

set /a sum+=%tmp%

set /a lvl+=1

if %lvl% gtr 1 (

    set exp=%exp%+%tmp%

    set /a idx+=1

    echo !idx!:!exp!=%sum%

) else (set exp=%tmp%)



set /a nxt=%1+1

for /l %%j in (%nxt%,1,%i%) do call :rec %%j



endlocal & set idx=%idx%

goto :eof

[ Last edited by qzwqzw on 2006-12-31 at 01:48 PM ]

Impressive! Not only does it produce the result, it can also show exactly how many combinations there are.

The code from several of you is truly brilliant, containing wisdom and a solid accumulation of knowledge. It's an example for me to learn from.

As the title says. The contents of my test.txt are:
１
２
３
The result is:
gn1=1
gn2=2
gn3=3
Press any key to continue. . .
1:1+2=3
2:1+2+3=6
3:1+3=4
4:2+3=5
Press any key to continue. . .
Not sure if it's...

9th floor qzwqzw

I can only add two points, I'll take your code home and study it carefully...

I can't see where the duplicate combinations are excluded?

--------------------
I'll look at it slowly first,
for now I completely understand everything before the first pause.....
---------------------
But I get stuck at :rec.............

Can someone tell me what that %1 is about????
------------------------------------
Now I know what += means........ turns out it's similar to C....
------------------------------------
......
After turning ECHO ON
I went through the code line by line against the result.....
I still don't quite understand :rec....
-------------------------
Looking again, I must understand it this time~ I didn't learn recursion well when I studied C, this time I have to really work at it.......
----------------------
Got it...... I understand it now!

[ Last edited by tghksj on 2007-1-1 at 11:58 AM ]

I added the points to the wrong person!!!!

After a few days of holiday, quite a few good things turned up....

The recursion in the 9th-floor post is indeed ingenious, but considering efficiency it's best to avoid FOR nesting and CALL recursion.

Does not support duplicate numbers.

@echo off&setlocal enabledelayedexpansion

set n=1

for /f %%n in (test.txt) do (

    set /a i+=1

    set str!i!=%%n

)

set str

pause&echo.



:loop

set/a n+=1

if not defined str%n% goto end

for /f "tokens=1* delims==" %%a in ('set result 2^>nul') do (

set/a x+=1

set result!x!=%%b+!str%n%!

)

set/a f=n-1

if not defined flag!str%n%! for /l %%j in (1,1,%f%) do (

set/a x+=1

set result!x!=!str%%j!+!str%n%!

)

set/a flag!str%n%!+=1

goto :loop



:end

for /f "tokens=1* delims==" %%a in ('set result 2^>nul') do (

set/a id+=1

set/a %%a=%%b

echo !id!:%%b=!%%a!

)

pause&goto :eof