China DOS Union

I want to extract the characters from position 8 to 20 of line 17 in a text file and assign them to a variable for subsequent commands.

Please don't blame me for asking such too-simple questions all day, I also feel a bit embarrassed. Thinking of asking regardless of dignity, this forum has indeed made me learn things, so I plucked up the courage.

[ Last edited by namejm on 2006-12-13 at 01:54 PM ]

```
setlocal enabledelayedexpansion
for /f "delims=" %%i in (1.txt ) do (
set /a num+=1
if !num! equ 17 set var=%%i
if !num! equ 17 set var=!var:~7,13!
)
echo !var!
pause
```

@echo off

for /f "skip=16 delims=" %%i in (test.txt) do (

    set "str=%%i"

    call set "str=%%str:~7,12%%"

    goto :exit)

:exit

   echo %str%

pause>nul

or:

@echo off

for /f "delims=: tokens=1,2*" %%i in ('findstr /n . test.txt') do (

   if %%i EQU 17 (

        set "str=%%j"

        call set "str=%%str:~7,12%%"

        goto :exit))

:exit

   echo %str%

pause>nul

[ Last edited by youxi01 on 2006-12-12 at 06:22 AM ]

setlocal enabledelayedexpansion
for /f "skip=16 delims=" %%i in (filename.txt) do (
set var=%%i
set var=!var:~7,13!
goto :outfor)
:outfor

The red parts you can replace at will.

Wow, I'm too slow with my hands and feet. = =b

Am I fast enough with my hands?
Give a little encouragement to the enthusiastic friends!

Also, the poster, please pay attention to your title!

Thank you, kind friends. I will pay attention to the title in the future.

Re all:

　　To extract text content with batch processing, special characters such as spaces, and connection characters like &, ||, etc., should be noted for compatibility at any time. Therefore, Brother youxi01's code in 3F uses delims= and set "str=%%i", which is very necessary.

　　However, batch processing still cannot handle all special cases. For example, if there are lines starting with a half-width semicolon, the general for statement will ignore these lines, and counting the number of lines with set /a num+=1 will be wrong. Using for + findstr /n can avoid this; but for + findstr /n cannot cover all situations. At least, if some lines start with a half-width colon, for /f "tokens=1* delims=:" %%i in ('findstr /n .* test.txt') do echo "%%j" will ignore all colons at the beginning of the line. So, when processing text, we can only hope that these special situations do not occur together. I wonder if you all have any good solutions.

```@echo off
setlocal enabledelayedexpansion
set num=
for /f "delims=" %%i in ('findstr .* a.txt') do (
set /a num += 1
set "!num!=%%i"
)
for /l %%i in (1,1,%num%) do echo 第%%i行: !%%i!
pause
Temporary change plan, try to see if there are bugs.```

Brother 3742668, the code in 10F still can't correctly handle the situation where there's a semicolon at the beginning of a line, nor can it handle the situation where there's an exclamation mark within a line.

Code 1 can correctly handle text with a semicolon or colon at the beginning of a line and special characters like &, ||, etc. in the line, but it can't correctly extract content with an exclamation mark. Code 2 can solve the problem of the exclamation mark, but it needs to be enclosed in quotes. It basically solves the problem I raised in 9F. Please test everyone:

Code 1:

@echo off

set num=0

setlocal enabledelayedexpansion

for /f "delims=" %%i in ('findstr /n .* test.txt') do (

    set /a num+=1

    set "str=%%i"

    echo 第 !num! 行： !str:*:=!

)

pause

Code 2:

@echo off

set num=0

::setlocal enabledelayedexpansion

for /f "delims=" %%i in ('findstr /n .* test.txt') do (

    set /a num+=1

    set "str=%%i"

    call :display

)

pause

goto :eof



:display

echo 第 %num% 行： "%str:*:=%"

goto :eof

The content of test.txt:

:abc

::xy

;

;;;ef &

;:;

::;;

||

&

^

!<

!

%

"

""

'

[ Last edited by namejm on 2006-12-11 at 10:13 PM ]

试试这个：

@echo off

    setlocal enabledelayedexpansion

    set num=

    for /f "eol= delims=" %%i in ('findstr .* a.txt') do (

        setlocal DISABLEDELAYEDEXPANSION

        set "tmpstr=%%i"

        setlocal enabledelayedexpansion

        set /a num += 1

        set "!num!=!tmpstr!"

    )

    for /l %%i in (1,1,%num%) do echo 第%%i行: !%%i!

    pause

exit /b 0

eol= Use it cleverly, setlocal is wonderful, great, really great, heh heh.